Diagramm mit mehreren Datenreihen

Forumthread: Diagramm mit mehreren Datenreihen

12.11.2024 17:03:14

Benjamin

Hallo Forum-Mitglieder,

ich möchte per VBA ein Punktediagramm mit geraden Linien und Datendarstellung erstellen, welches aus vielen Datenreihen besteht. Die Anzahl der Datenreihen im Diagramm soll abhängig von der vorhandenen Datenmenge sein. Die x-Werte stehen in A1:B1, y-Werte in C1:D1. Die zweite Datenreihe in der Zeile 2 bei gleichen Spalten (A2:B2; C2:D2). Alle weiteren Datenreihen fortlaufend der Zeilen, welche Daten enthalten. Wenn wie im Beispiel in Zeile 6 keine weiteren Daten enthalten sind, soll das Diagramm erstellt werden und das Programm enden.
Ein Beispiel findet ihr unter nachfolgendem Link:
https://www.herber.de/bbs/user/173550.xlsx
Könnt ihr mir vielleicht hierbei helfen? Ich selber bekomme das nicht hin.
Vielen Dank im Voraus.

Viele Grüße
Benjamin

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Diagramm mit mehreren Datenreihen

12.11.2024 18:14:54

Beverly
AW: Diagramm mit mehreren Datenreihen

14.11.2024 11:52:27

Benjamin
AW: Diagramm mit mehreren Datenreihen

14.11.2024 14:28:08

Beverly
AW: Diagramm mit mehreren Datenreihen

14.11.2024 18:58:11

Benjamin

AW: Diagramm mit mehreren Datenreihen

12.11.2024 18:14:54

Beverly

Hi Benjamin,

Sub DiaErstellen()

    Dim lngLetzte As Long

    Dim lngZeile As Long

    Dim chrDiagramm As Chart

    ' vorhandenes Diagramm löschen

    If ActiveSheet.ChartObjects.Count > 0 Then ActiveSheet.ChartObjects.Delete

    lngLetzte = Cells(Rows.Count, 1).End(xlUp).Row

    ' Diagramm neu erstellen

    Set chrDiagramm = ActiveSheet.ChartObjects.Add(Range("F1").Left, Range("F1").Top, 400, 250).Chart

    With chrDiagramm

        .HasTitle = False

        .HasLegend = False

        .ChartType = xlXYScatterLines

        For lngZeile = 1 To lngLetzte

            With .SeriesCollection.NewSeries

                .XValues = Range(Cells(lngZeile, 1), Cells(lngZeile, 2))

                .Values = Range(Cells(lngZeile, 3), Cells(lngZeile, 4))

                .MarkerStyle = 8

            End With

        Next lngZeile

        With .Axes(xlCategory)

            .MaximumScale = 1

            .MinimumScale = 0

            .MajorUnit = 0.0833333333

            .TickLabels.NumberFormat = "hh:mm"

        End With

    End With

End Sub

Bis später
Karin

Link zur Homepage: https://excel-inn.de/

AW: Diagramm mit mehreren Datenreihen

14.11.2024 11:52:27

Benjamin

Vielen Dank Karin!

Entschuldige die späte Antwort. Es funktioniert super.
Kannst du mir vielleicht noch dabei helfen, wie ich dem Diagramm einen Namen geben kann?
Also nicht "Diagramm1" sondern "Übersicht".

Vielen Dank und herzliche Grüße
Benjamin

AW: Diagramm mit mehreren Datenreihen

14.11.2024 14:28:08

Beverly

Hi Benjamin,

dazu musst du nur folgende Zeile ergänzen



    With chrDiagramm

        '***************

        ' Ergänzung

        .Parent.Name = "Übersicht"

        '*************

        .HasTitle = False

Bis später
Karin

Link zur Homepage: https://excel-inn.de/

AW: Diagramm mit mehreren Datenreihen

14.11.2024 18:58:11

Benjamin

Vielen vielen Dank Karin

Diagramm mit mehreren Datenreihen

Forumthread: Diagramm mit mehreren Datenreihen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread