Indirekt mit variablen Zellbezug (Teil2)

06.05.2025 13:21:52

Andre´

Hallo alle zusammen,

die Frage bezieht sich auf den Beitrag => https://www.herber.de/forum/messages/2011775.html , wo mir bereits geholfen wurde.
Da mit Excel 2019 ebenfalls gearbeitet wird, bräuchte ich nochmals Unterstützung.
Ist es auch möglich, dass nur die Zahlen in A4 und A5 vorgegeben werden und die INDIREKT-Funktion sich darauf bezieht?

Die Formel:

=INDEX('Daten-Test'!$F7:$J7;MAX(INDEX(('Daten-Test'!$F7:$J7>"")*(MONAT('Daten-Test'!$F$2:$J$2)=MONAT(C$1))*(JAHR('Daten-Test'!$F$2:$J$2)=JAHR(C$1))*SPALTE('Daten-Test'!$F$2:$J$2)-$E$1;0)))

In A4 steht => 7
In A5 steht => 2

Habe schon einiges probiert (ein Bsp. siehe nachfolgend) leider ohne Erfolg.

=INDEX('Daten-Test'!$F&INDIREKT(A4):$J&INDIREKT(A4);MAX(INDEX(('Daten-Test'!$F&INDIREKT(A4):$J&INDIREKT(A4)>"")*(MONAT('Daten-Test'!$F$&INDIREKT(A5):$J$&INDIREKT(A5))=MONAT(C$1))*(JAHR('Daten-Test'!$F$&INDIREKT(A5):$J$&INDIREKT(A5))=JAHR(C$1))*SPALTE('Daten-Test'!$F$&INDIREKT(A5):$J$&INDIREKT(A5))-$E$1;0)))

Wie muss ich die Formel abändern?

Vielen Dank im Voraus!

MFG Andre

AW: Indirekt mit variablen Zellbezug (Teil2)

06.05.2025 16:03:19

BoskoBiati

Hi,

es wäre hilfreich gewesen, wenn Du anhand einer Tabelle zu zeigen, was Du erreichen willst. Glaubst Du, irgendeiner kann ohne Deine Tabelle nachvollziehen, was die Formel machen soll?
Zudem hat man Dir im anderen Thread ganz andere Formeln gezeigt.

Gruß

Edgar

AW: Indirekt mit variablen Zellbezug (Teil2)

06.05.2025 16:18:52

daniel

Hi
INDIREKT ist hier der falsche Ansatz.
Besser ist hier INDEX zu verwenden.
ersetze jedes 'Daten-Test'!$F7:$J7 durch: INDEX('Daten-Test'!$F:$J;A4;0)
und jedes: 'Daten-Test'!$F$2:$J$2 durch INDEX('Daten-Test'!$F:$J;A5;0)

wenn du mit INDIREKT arbeiten willst, muss du den gesamten Zellbezug als Text erstellen, dh du müsstest
dann jedes 'Daten-Test'!$F7:$J7 durch INDIREKT("'Daten-Test'!F"&A4&":J"&A4) ersetzen (für F2:J2 dann analog), wovon ich aber abraten würde.

Gruß Daniel

AW: Indirekt mit variablen Zellbezug (Teil2)

06.05.2025 17:09:05

Andre´

Hallo Daniel,
vielen Dank für die Lösungen!!!
Noch eine Frage, warum würdest du abraten von INDIREKT?

MFG Andre

AW: Indirekt mit variablen Zellbezug (Teil2)

06.05.2025 17:54:31

daniel

Hi
Punkt 1:
um Rechenzeit zu sparen, versucht Excel, eine Formel nur dann neu zu berechnen, wenn es erforderlich ist, dh wenn sich in den Zellen, die die Formel verwendet, eine Änderung ergibt. Hierzu muss Excel allerdings die verwendeten Zellen aus dem Formeltext auslesen können. Bei Indirekt ist das allerdings nicht möglich, da der Zellbereich ja auch berechnet wird und nicht direkt im Formeltext steh. Daher werden alle Formeln, die Indirekt verwenden, immer bei jeder Änderung in Excel neu berechnet. Das kann auf Grund der häufigen Berechnungen dazu führen, das das Arbeiten mit der Datei unkomfortabel wird, weil man ständig auf die Neuberechnung warten muss, vor allem wenn langwierige oder aufwendige Berechnungen damit verknüpft sind.

Punkt 2:
Automatische Anpassungen, die dir das Leben leichter machen, funktionieren nicht mehr.
Bei Indirekt liegen die Bezüge auf Tabellenblatt und Zeilen oder Spalten als Text vor und sind für Excel nicht mehr als Zellbezug erkennbar.
Wenn du beispielsweise das Tabellenblatt "Daten-Test" in "Daten" umbenennst (weil die Testphase vorbei ist), wird Excel alle Zellbezüge, die auf "Daten-Test" referenzieren, automatisch in "Daten" ändern. Bei deinen INDIREKT-Zellbezügen kann es das nicht machen und du musst von Hand "nacharbeiten".
Gleiches auch beim Einfügen oder Löschen von Zeilen oder Spalten. Wenn du zwischen Spalte A und B noch eine Spalte einfügst, wird Excel alle Zellbezüge prüfen und anpassen, dh aus F2:J2 wird dann G2:K2, weil die Daten jetzt dort liegen. Oder du löschst die Spalte H, dann wird F2:J2 zu F2:I2.
All das funktioniert nur mit echten Zellbezügen, aber nicht mit deinen, die du mit Indirekt erstellst, weil hier der Bezug ja als einfacher.

Gruß Daniel

Danke für die ausführliche Beschreibung owt

06.05.2025 18:05:47

Andre´

Indirekt mit variablen Zellbezug (Teil2)

Forumthread: Indirekt mit variablen Zellbezug (Teil2)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Indirekt mit variablen Zellbezug (Teil2)

Forumthread: Indirekt mit variablen Zellbezug (Teil2)

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread