Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
2012to2016
2012to2016
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Anzeige
Inhaltsverzeichnis

Geht meine Formel auch kürzer?

Forumthread: Geht meine Formel auch kürzer?

Geht meine Formel auch kürzer?
06.05.2025 13:38:45
Christian
Hallo,

nur rein aus neugierde, hab ich es mir zu umständlich gemacht, oder ist das schon die "perfekte" Version 

=TEXT(EDATUM(HEUTE()-WOCHENTAG(HEUTE();2)+2;-360);"JJJJ-MM-TT")&","&TEXT(EDATUM(HEUTE()-WOCHENTAG(HEUTE();2)+1;-216);"JJJJ-MM-TT")


Ziel war es, das Datum von dieser Woche Dienstag zu bestimmen, davon 30 Jahre abzuziehen und es im Format JJJJ-MM-TT auszugeben
dazu das Datum von dieser Woche Montag, im selben Format und 18 Jahre abgezogen.
Die beiden Daten durch ein Komma getrennt.

Danke für eure Ratschläge
Christian
Anzeige

11
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Geht meine Formel auch kürzer?
06.05.2025 13:59:22
BoskoBiati
Hi,
Ungetestet:

=TEXT(EDATUM(HEUTE()-REST(HEUTE();7)+3;-360);"JJJJ-MM-TT")&", "&TEXT(EDATUM(HEUTE()-REST(HEUTE();7)+2);-18*12);"JJJJ-MM-TT")

Gruß

Edgar
AW: Geht meine Formel auch kürzer?
06.05.2025 14:22:27
MCO
Hallo Christian!

Mit LET kann man die parameter auf kürzere Bezeichnungen verallgemeinern.

Hier die Entwicklung der Formel mit immer gleichem Ergebnis. Mit fortschreitender Verklausulierung schwindet natürlich die Lesbarkeit.
Dennoch: kürzer ist kürzer....




-DEF
1=TEXT(EDATUM(HEUTE()-WOCHENTAG(HEUTE();2)+2;-360);"JJJJ-MM-TT")&","&TEXT(EDATUM(HEUTE()-WOCHENTAG(HEUTE();2)+1;-216);"JJJJ-MM-TT")130
2=LET(h;HEUTE();Wo_T;WOCHENTAG(h;2);TEXT(EDATUM(h-Wo_T+2;-360);"JJJJ-MM-TT")&","&TEXT(EDATUM(h-Wo_T+1;-216);"JJJJ-MM-TT"))121
3
4=TEXT(EDATUM(HEUTE()-REST(HEUTE();7)+3;-360);"JJJJ-MM-TT")&","&TEXT(EDATUM(HEUTE()-REST(HEUTE();7)+2;-18*12);"JJJJ-MM-TT")von BoskoBiati122
5=LET(h;HEUTE();Wo_T;REST(h;7);TEXT(EDATUM(h-Wo_T+3;-360);"JJJJ-MM-TT")&","&TEXT(EDATUM(h-Wo_T+2;-216);"JJJJ-MM-TT"))116
6=LET(h;HEUTE();Wo_T;REST(h;7);f;"JJJJ-MM-TT";TEXT(EDATUM(h-Wo_T+3;-360);f)&","&TEXT(EDATUM(h-Wo_T+2;-216);f))109


Gruß, MCO
Anzeige
AW: Geht meine Formel auch kürzer?
06.05.2025 15:26:27
daniel
Hi
verwende LET, um allem, was mehrfach in der Formel vorkommt, einen kurzen Namen zuzuweisen, um dann diesen in der Hauptformel zu verwenden: 

=LET(h;HEUTE();a;h-WOCHENTAG(h;2);b;"JJJJ-MM-TT";TEXT(EDATUM(a+2;-360);b)&","&TEXT(EDATUM(a+1;-216);b))


Gruß Daniel
AW: Geht meine Formel auch kürzer?
06.05.2025 15:48:01
Christian
Hallo Daniel,

funktioniert auch. Danke für deine Mühe
Chris
Anzeige
AW: Geht meine Formel auch kürzer?
06.05.2025 14:32:08
Christian
hallo MCO,

ich hoffe ich verstehe es richtig, in der 2. Formel hast du Heute() in h und Wochentag(...) in Wo_t gespeichert wegen mehrfacher Verweundung

Die 4. Formel ist Edgars Vorschlag mit deinen Variablen und Rest(h;7) als Wo_t

und in der 5. Formel ist noch die Variable f für das Format hinzugekommen

übrigens wieder was gelernt, dass man in Let beim definieren von Variablen bereits weitere Variablen nutzen kann, ist mir neu.

Danke
Christian
Anzeige
AW: Geht meine Formel auch kürzer?
06.05.2025 14:35:23
MCO
Das hast du genau richtig verstanden :-)

Viel Erfolg!

Gruß, MCO
danke owT
06.05.2025 14:44:13
Christian
AW: Geht meine Formel auch kürzer?
06.05.2025 14:20:02
Christian
Hallo Edgar,

danke für deinen Rat. War eine Klammer zuviel (nach +2, aber war ja auch ungetestet), ansonsten alls wunderbar. Werde ab jetzt diese Version nehmen.

Danke
Christian
Anzeige
AW: Geht meine Formel auch kürzer?
06.05.2025 15:56:56
BoskoBiati
Hi,

hier noch eine Version mit LET: 

=LET(xa;HEUTE();xb;REST(xa;7);xc;xa-xb;TEXT(EDATUM(xc+3;-360);"JJJJ-MM-TT, ")&TEXT(EDATUM(xc+2;-216);"JJJJ-MM-TT"))


Gruß

Edgar
AW: Geht meine Formel auch kürzer?
06.05.2025 16:21:30
Christian
funktioniert ebenfalls, danke
AW: Geht meine Formel auch kürzer?
06.05.2025 16:26:00
daniel
auch wenn es fraktional kürzer ist:
ich würde hier die Wochentags-Funktion verwenden anstelle von Rest, um auf den Dienstag und Montag der aktuellen Woche umzurechnen.
die sich dadurch ergebenden +1 (für Montag) und +2 (für Dienstag) sind leicht verständlich und ableitbar, da Montag = 1. Tag der Woche zum Allgemeinwissen gehört.

die sich mit der Rest-Funktion ergebenden Werte +2 und +3 müssten wieder extra erklärt werden, und funktional kürzer wird die Formel mit Rest ja nicht, die Kürzung ergibt sich ja nur dadurch, dass Wochentag ein paar weniger Buchstaben hat.
Die Erklärungen zu Wochentag erhält der Anwender auch automatisch beim Eingeben der Formel, bei Rest als allgemeine mathematische Formel nicht, und um diese zu verstehen, braucht man auch etwas Spezialwissen, bspw welcher Wochentag der 1.1.1900 war und warum dieses Datum relevant ist.

Gruß Daniel
Anzeige

Forumthreads zu verwandten Themen

erweiterte Abfrageschleife
Langmantl

Habe bereits antwort auf eine Einfache Abfrage erhalten, muss es aber komplexer haben.
Problemstellung: Ich habe einen Wochenplan, dort wird habe ich mittels zweiten Tabellenblatt Feiertage und Urlaube definiert. Mittels Userform1 wird in Zelle A5 ein Wunschdatum geschrieben. Auf dem zweite...
03.11.2014 12:10:53
Thread-ID: 1390036
11 Beiträge
Hilfe bei einer Userform
Langmantl

Problemstellung: Ich habe einen Wochenplan, dort wird habe ich mittels zweiten Tabellenblatt Feiertage und Urlaube definiert. Mittels Userform1 wird in Zelle A5 ein Wunschdatum geschrieben. Auf dem zweiten Tabellenblatt, sind die Feiertage und mein Urlaub ebenfalls mit Datum hinterlegt, so dass...
03.11.2014 13:09:55
Thread-ID: 1390070
14 Beiträge
WENN Funktion
Markus
Hallo,
ich hätte gern eine Formel mit der WENN Funktion erstellt.
=WENN(WOCHENTAG(A4;2)=1;"" & TEXT(GANZZAHL((A4-WOCHENTAG(A4;2)-DATUM(JAHR(A4+4-WOCHENTAG(A4;2));1; -10))/7);"0");=WENN(WOCHENTAG(A4;2)=4; dann schaue 4 zellen über mir und mache mit dieser zahl einen SVERWEIS auf Tabelle2...
13.10.2022 16:29:03
Thread-ID: 1902668
10 Beiträge
ddmmyy oder ttmmjj
dieter

Hallo Forum,
mit der unten stehenden Excelformel (die ich hieraus dem Forum habe)
erreiche ich,dass das Datum (steht in J19) und die zahl zweier kalenderwochen (zb. Woche 27 +28) ohne punkt und komma als zahl geschrieben wird.
Beispiel: 10.07.09 und die Wochen 27 +28 werden dann dar...
13.07.2009 15:36:11
Thread-ID: 1087989
1 Beitrag
Datum aus KW
Ulf
Hallo Ihr lieben Helfer,

ich habe die folgende (im Netz gefundene) Formel zur Berechnung der KW im Einsatz und sie funktioniert einwandfrei.
=WENN(KALENDERWOCHE(DATUM(TEXT(HEUTE();"JJJ");1;1);21)=1;WENN(WOCHENTAG(DATUM(TEXT(HEUTE();"JJJ");1;1);11)=1;DATUM(TEXT(HEUTE();"JJJ");1;1)+7*(ISO...
05.09.2023 12:57:49
Thread-ID: 1945078
6 Beiträge
Datumsformat mit holländischem Wochentag
Boris

Liebe Excellenzen,ich möchte gerne ein Datum incl. Wochentag auf niederländisch angezeigt bekommen, und zwar im Format
TT/MM (Wochentag)Dazu benutze ich folgende Formel (wobei das Datum in der "echten" Formel natürlich variabel gehalten ist):=DATUM(2002;1;1) &" ("& WAHL(WOCHENTAG(DATUM(2002;...
05.11.2002 14:15:15
Thread-ID: 177377
7 Beiträge
Anzeige
Text berechenbar machen
Specke

Hallo Experten,
erstmal allen ein Gesundes Neues Jahr und vielen Dank für die Hilfen im letzten Jahr!
Nun zu einem neuen Problem:
Ich habe in einer Projekt-Tabelle das Startdatum (E11) und das geplante Ende (L11) stehen.
Aus diesem beiden Werten und dem heutigen Datum (M2) habe...
02.01.2007 14:44:34
Thread-ID: 833051
2 Beiträge
Anzeige
Formel will nicht wie ich will!
Mister

Hallo und guten Abend,
In meiner Tabelle habe ich eine Wenn, Dann, Sonst Prüfung in Zelle R7
Wenn in Zelle E7 den Text "UR", "SU", "ZU", oder "§6" steht und das Datum in B7 ein Wochentag ist, soll der Wert 0,33333 in R7 erscheinen. An den Wochenenden soll nichts erscheinen auch wenn di...
23.09.2008 21:05:41
Thread-ID: 1011858
3 Beiträge
Anzeige
Problem mit Spaltenfunktion in einer Array-Formel
Alex

Hallo
Ich versuche folgende Array-Formel zum Laufen zu bringen, irgendwie klappt nicht. Ich erhalte immer den #WERT Fehler anstatt Wahr oder Falsch. Die Formel habe ich mit Crtl+Shift+Enter geschlossen.
Elemente der Tabelle:
DatumSpalte: Spalte C10:C57 (Format: Datum)
Lohnmonat_...
13.04.2016 15:17:35
Thread-ID: 1487737
13 Beiträge
Datumsformel
Stoffi69

Hallo Zusammen
Ich habe mir im Internet eine Formel rauskopiert in der ich nur die Kalenderwoche eingeben muss und dann sehe ich gleich das Anfangs und Enddatum der Woche für meinen Dienstplan.
KW 48 28.Nov.2016 - 04.Dez.2016
48 steht in B1
die Formel dazu
=TEXT(DATUM(JAHR(...
01.01.2016 15:19:54
Thread-ID: 1466604
2 Beiträge
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Live-Forum - Die aktuellen Beiträge
Datum
Titel
14.05.2026 13:31:09
Zeichen ausblenden
14.05.2026 09:50:42
Makro für MacOs
13.05.2026 19:14:18
Gleichheitszeichen
13.05.2026 14:24:56
VBA Projekt Passwort automatisch eingeben
13.05.2026 08:49:41
Reale Berechnung ohne Nachkommawerte
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum