Datum als Info anzeigen

12.05.2025 18:27:48

NicoHendrik

Hallo ihr Experten,

gibt es eine Möglichkeit, das wenn ich eine Zelle von K8 bis NL47 anklicke das Datum für diese Zelle als Info angezeigt wird?

Gruß aus den hohen Norden
Nico

https://www.herber.de/bbs/user/177413.xlsm

AW: Datum als Info anzeigen

12.05.2025 18:48:28

{Boris}

Hi,

da Zellen von Haus aus kein MouseOver oder eine Quickinfo haben, würde ich im Selection-Change das Datum in eine freie Zelle schreiben (z.B. I3 - dort dann Schriftgröße verkleinern).

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

With Cells(6, Target(1, 1).Column)

    If IsDate(.Value) Then

        Range("I3") = .Value

    Else

        Range("I3").ClearContents

    End If

End With

End Sub

VG, Boris

AW: Datum als Info anzeigen

12.05.2025 19:07:20

UweD

Hallo

evtl über Notiz

Vorausgesetzt, du hast noch Keine in dem Bereich, da ich die raus lösche.

Tausche deinen Code

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Target.Calculate

End Sub

in

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim RNG As Range

    Set RNG = Range("K8:NL47")

    If Not Intersect(Target, RNG) Is Nothing Then

        RNG.ClearComments

        With Target

            .AddComment

            .Comment.Visible = True

            .Comment.Text Text:=Format(Cells(6, Target.Column), "DD.MM.YYYY")

        End With

    End If

    Target.Calculate

End Sub

AW: Datum als Info anzeigen

12.05.2025 19:13:51

Piet

Hallo Nico

probiere es bitte mal mit diesem Code, der ist ja schon vrhanden, mit Target.Calculate.

mfg Piet

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim WsShell, Datum As Date, Tag As String

Target.Calculate   'erweitert auf 2 Sekunden Msgbox Anzeige

If Not Intersect(Target, Range("K8:NL47")) Is Nothing Then

    Set WsShell = CreateObject("WScript.Shell")

    Datum = Cells(6, Target.Column)

    Tag = Format(Datum, "ddd")

    WsShell.Popup Tag & "  " & CDate(Datum), 2  '2 Sekunden Anzeige

End If

End Sub

AW: Datum als Info anzeigen

12.05.2025 20:32:32

NicoHendrik

Danke, Piet klappt leider nicht.

Ich werde den Ersten Code von Daniel mit der Textbox verwenden

Gruß
Nico

AW: Datum als Info anzeigen

12.05.2025 19:57:09

daniel

Hi
da stellt sich natürlich die Frage, wie du das angezeigt haben möchtest.
und was soll sein, wenn der Anwender mehrere Zellen markiert? soll dann der Datumsbereich oder immer nur die angelickte Zelle angezeigt werden?

für die einzelne Zelle würde ich das so machen:

1. erstelle eine Textbox aus der Gruppe der ActiveX-Controls und formatiere sie über die Eigenschaften wie gewünscht.
damit der Anwender nicht reinklickt, kannst du die Eigenschaft Enabled = False setzen

2. verwende dann diesen Code im Modul des Tabellenblatts, um die Textbox mit dem Datum zu füllen und neben der angeklickten Zelle zu platzieren.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Target.Calculate



If Intersect(ActiveCell, Range("K8:NL57")) Is Nothing Then

    TextBox1.Visible = False

Else

    With TextBox1

        .Value = Format(Intersect(ActiveCell.EntireColumn, Rows(6)).Value, "DDD, DD.MM.YY")

        .Top = ActiveCell.Offset(1, 0).Top + 5

        .Left = ActiveCell.Left + 10

        .Visible = True

    End With

End If

End Sub

Gruß Daniel

AW: Datum als Info anzeigen

12.05.2025 21:29:57

NicoHendrik

Danke Daniel,

das ist die Lösung.

Wunsch erfüllt

Gruß Nico

AW: Datum als Info anzeigen

12.05.2025 20:19:38

daniel

wenn es dir reicht, dass die Info in der Statuszeile am unteren Tabellenrand angezeigt wird, reicht dir dieser Code im Modul des Tabellenblatts:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Target.Calculate

If Intersect(Target, Range("K8:NL57")) Is Nothing Then

    Application.StatusBar = False

Else

    Application.StatusBar = Format(Intersect(ActiveCell.EntireColumn, Rows(6)).Value, "DDD, DD.MM.YY")

End If

End Sub

Gruß Daniel

AW: Datum als Info anzeigen

12.05.2025 19:12:59

UweD

Hi

falls das Rechteck zu groß ist...

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim RNG As Range

    Set RNG = Range("K8:NL47")

    If Not Intersect(Target, RNG) Is Nothing Then

        RNG.ClearComments

        With Target

            .AddComment

            With .Comment

                .Visible = True

                .Text Text:=Format(Cells(6, Target.Column), "DD.MM.YYYY")

                .Shape.Width = 55    ' Breite in Punkten

                .Shape.Height = 12    ' Höhe in Punkten

            End With

        End With

    End If

    Target.Calculate

End Sub

LG UweD

AW: Datum als Info anzeigen

12.05.2025 20:42:52

NicoHendrik

Hallo Uwe,

wenn ich die erste Zelle anklicke, dann die zweite um zum Beispiel Urlaub mit den Button auszufüllen, geht der Code auf Störung

Gruß Nico

AW: Datum als Info anzeigen

12.05.2025 18:59:49

NicoHendrik

Funktioniert nicht

AW: Datum als Info anzeigen

12.05.2025 19:01:54

{Boris}

Hi

"funktioniert nicht" ist grad nicht so hilfreich. Was genau funktioniert nicht? Lad mal bitte Deine Datei mit dem nicht funktionierenden Versuch hoch.

VG, Boris

AW: Datum als Info anzeigen

12.05.2025 19:20:37

GerdL

Moin,

aber sicher.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)



Target.Calculate

If Not Intersect(Target, Range("K8:NL47")) Is Nothing Then

    With Cells(6, Target(1, 1).Column)

     If IsDate(.Value) Then

        MsgBox .Value

      Else

       

      End If

    End With

End If



End Sub

Gruß Gerd

Datum als Info anzeigen

Forumthread: Datum als Info anzeigen

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Datum als Info anzeigen

Forumthread: Datum als Info anzeigen

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread