Spaltenbezug anpassen

Forumthread: Spaltenbezug anpassen

14.05.2025 11:17:58

Christian

Hallo,

gibt es anstelle der Formel =ANZAHL2(Tabelle1!A:A)=D1*4+2

eine andere Formel, die wenn ich sie nach unten kopiere =ANZAHL2(Tabelle1!B:B)=D2*4+2 berechnet, weiter nach unten dann =ANZAHL2(Tabelle1!C:C)=D3*4+2 noch weiter dann =ANZAHL2(Tabelle1!D:D)=D4*4+2, =ANZAHL2(Tabelle1!E:E)=D5*4+2

Wie geht das?

Danke
Christian

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Spaltenbezug anpassen

14.05.2025 11:34:33

SF
AW: Spaltenbezug anpassen

14.05.2025 11:39:16

Christian
AW: Spaltenbezug anpassen

14.05.2025 11:37:43

{Boris}
AW: Spaltenbezug anpassen

14.05.2025 15:31:12

daniel
AW: Spaltenbezug anpassen

14.05.2025 21:05:05

Christian
AW: Spaltenbezug anpassen

14.05.2025 22:23:26

Daniel
ach so

14.05.2025 22:34:52

Christian
AW: Spaltenbezug anpassen

14.05.2025 11:40:30

Christian
ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:19:20

{Boris}
AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:26:07

Christian
AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:35:39

{Boris}
AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 21:02:01

Christian

AW: Spaltenbezug anpassen

14.05.2025 11:34:33

Hola,
mit Index.

=ANZAHL2(INDEX(Tabelle1!A:Z;;ZEILE(A1)))=D1*4+2

Gruß,
steve1da

AW: Spaltenbezug anpassen

14.05.2025 11:39:16

Christian

Hallo Steve,

wunderbar, danke.

Christian

AW: Spaltenbezug anpassen

14.05.2025 11:37:43

{Boris}

Hi,

aus der Hand:

=ANZAHL2(INDEX(Tabelle1!A:Z;;ZEILEN($1:1)))=D1*4+2

VG Boris

AW: Spaltenbezug anpassen

14.05.2025 15:31:12

daniel

Hi
noch eine andere Lösung:

=MTRANS(NACHSPALTE(Tabelle1!A:C;LAMBDA(x;ANZAHL2(x))))*D1:D3+2

diese gibt dir als Einzelformel das Gesamtergebnis aus (Spill-Funktion)
dh du musst die Formel nicht nach unten ziehen, dafür musst du die Zellbereiche passend angeben (Spalten in Tabelle1, Zeilen für Spalte D).

Gruß Daniel

AW: Spaltenbezug anpassen

14.05.2025 21:05:05

Christian

Hallo Daniel,

das hieße dann aber wenn ich dich richtig verstehe, wenn ich mehrere solcher Tabellen habe, alle mit 300 Spalten aber unterschiedlich vielen Zeilen, ist das keine allgemein gültige Formel mehr oder verstehe ich das falsch..

Gruß
Christian

AW: Spaltenbezug anpassen

14.05.2025 22:23:26

Daniel

Hi

Wenn die Anzahl der Spalten Konstant ist, ist die Formel allgemeingültig, sieuss nur angepasst werden.
Das mit den Zeilen bezieht sich nur auf die Spalte D, da du jeder Spalte der Tabelle einen Wert aus Spalte D zuordnest, musst du hier soviele Zeilen angeben, wie die Tabelle Spalten hat:

Für 300 Spalten:
=MTRANS(NACHSPALTE(Tabelle1!A:KN;LAMBDA(x;ANZAHL2(x))))*D1:D300+2

Für 301 Spalten:
=MTRANS(NACHSPALTE(Tabelle1!A:KO;LAMBDA(x;ANZAHL2(x))))*D1:D301+2

Viele Zeilen dann in der Tabelle1 befüllt sind, ist egal.

ach so

14.05.2025 22:34:52

Christian

nein auch Spalte D sind konstant 300 Einträge, das einzige was variabel ist sind die Anzahl der Zeilen in Tabelle1.

AW: Spaltenbezug anpassen

14.05.2025 11:40:30

Christian

Hallo Boris,

klappt wunderbar, danke. Wusste gar nicht dass es auch eine Zeilen Funktion gibt.

Danke
Christian

ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:19:20

{Boris}

Hi,

das sind sehr nützliche Funktionen, um einen (idR aufsteigenden) Zähler zu erzeugen.

=ZEILE(A1) = 1
Runterkopiert wird daraus
=ZEILE(A2) = 2
usw.

=ZEILEN($1:1) = 1
Runterkopiert wird daraus
=ZEILEN($1:2) = 2
usw.

Das Selbe mit SPALTE und SPALTEN (für horizontales Kopieren).

VG, Boris

AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:26:07

Christian

Hallo Boris, ich kannte natürlich zeile und spalte, auch wofür sie gut sind, allerdings zeilen und spalten war mir unbekannt. Danke für die Erklärung

AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 14:35:39

{Boris}

Hi

ZEILEN bzw. SPALTEN ist etwas "robuster" gegen das Löschen von Zellen/Zeilen/Spalten.

Aus
=ZEILE(A1)
wird #BEZUG!, sobald Spalte A oder Zeile 1 gelöscht wird.
=ZEILEN($1:1) hingegen "überlebt" das Löschen von Spalte A (jedoch nicht das Löschen von Zeile 1).

Daher ist man auf der sicheren Seite, wenn man ZEILEN auf einen definitiv nicht benutzten Bereich anwendet, z.B.:
=ZEILEN($999:1000)
Dann kann man zunächst mal problemlos Zeilen oberhalb 999 löschen.

Das Selbe gilt für SPALTE und SPALTEN.

VG, Boris

AW: ZEILE/ZEILEN/SPALTE/SPALTEN

14.05.2025 21:02:01

Christian

Hallo Boris, das wiederum wusste ich nicht, vielen Dank
Christian

Forumthread: Spaltenbezug anpassen

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread