letzten 2 Werte aus einer Spalte

21.05.2025 11:46:36

Tom

Hallo,

ich habe in vielen Zeilen Einträge von Werten und darunter immer einen dazugehörigen Wert als Datum.

Bspw. also Messreihe 1: B5 = 175, dann in B6 = 01.03.2025. Dann neuer Wert B7 = 224, B8 = 01.04.2025 usw. Dies jeweils für mehrere Messreihen in mehreren Spalten.
Die Werte sind immer fortlaufend, leere Zellen werden nicht vorkommen.

Nun hätte ich gern in B2 immer den letzten Wert und in B3 das dazugehörige Datum der letzten Eintragung.
Ich habe Bsp mit Index Formeln gefunden, aber nur für den letzten Wert, aber nicht die letzten beiden Werte.

Gibt es hier eine Möglichkeit?

Vielen Dank.
Grüße aus Berlin
Tom

AW: letzten 2 Werte aus einer Spalte

21.05.2025 11:50:58

SF

Hola,

=INDEX(B:B;VERWEIS(2;1/(B5:B10>"");ZEILE(B4:B9)))

=INDEX(B:B;VERWEIS(2;1/(B5:B10>"");ZEILE(B5:B10)))

Gruß,
steve1da

AW: letzten 2 Werte aus einer Spalte

21.05.2025 14:50:17

BoskoBiati

Hi,

in Deiner Version, in B2:

=ÜBERNEHMEN(B5:.B1800;-2)

B1800 kann eine beliebige Zelle in B sein.
Gruß

Edgar

AW: INDEX() bedarf es auch in älteren XL-Versionen nicht ...

21.05.2025 15:01:24

neopa C

Hallo Tom,

... in B2: =VERWEIS(9;1/(B5:B99>"");B4:B99)
und in B3 einfach: =VERWEIS(9^9;B4:B99)

Gruß Werner
.. , - ...
aus C the unseen

AW: bevor meine vorherige Aussage fehlinterpretiert wird ...

21.05.2025 15:21:36

neopa C

Hallo nochmal,

... natürlich bedarf es die Funktion INDEX() in allen Excelversionen sehr oft für viele Formeln, denn sie gehört mit zu den mächtigsten XL.Funktionen.
Nur ist sie für die hier spezif. Anfrage zur Lösung nicht unbedingt notwendig, weil da VERWEIS() allein zur Formellösung ausreichend ist.

Gruß Werner
.. , - ...
aus C the unseen

AW: letzten 2 Werte aus einer Spalte

21.05.2025 15:13:59

Yal

Hallo Tom,

wandle deine Liste in einer Tabelle um: Menü "Einfügen", "Tabelle",
rechtsklicke auf diese Tabelle und wählen "Daten aus Tabelle/Bereich abrufen..."
Du bist in Power Query Editor
Im Menü "Spalten hinzufügen", wähle "Indexspalte", "von 1"
Im selben Menü "benutzerdefinierte Spalte", benenne es "Wertetyp" und gebe die Formel
= if Number.IsOdd([Index]) then "Wert" else "Datum"
ein.
füge eine zweite benutzerdefinierte Spalte mit Name "Eintrag" mit folgende Formel:
= Number.RoundUp([Index] / 2)
Entferne die Spalte Index.
markiere die Spalte "Wertetyp", Menü "Transformieren", "Spalte pivotieren", originale Saplte als Wertespalte auswählen, unten in "erweiterte Optionen", "nicht aggregieren" einstellen.
Entferne die Spalte "Eintrag".
rechtsklicke auf die Spalte "Datum", "Typ ändern", "Datum".
Reihenfolge der Spalten könnte jetzt noch angepasst werden.
Menü "Datei", "Schliessen und laden". Fertig.

Formel sind gut, aber ab eine bestimmte Menge an Daten, ist es nicht mehr die optimale Vorgehensweise.
Wenn deine Daten aus einer Datei kommen, schaue in dem Menü "Daten", "Aus Datei", "aus Text/csv" wie Du die Daten direkt aus der Datei über PQ ins Excel richtig transformiert reinbringen kannst.

VG
Yal

AW: letzten 2 Werte aus einer Spalte

21.05.2025 15:32:36

daniel

Hi

für ein aktuelles Excel 365:

in B2: =ÜBERNEHMEN(B.:.B;-2)

das B.:.B veranlasst Excel, nicht die ganze Spalte B zu verwenden sondern nur den befüllten Teil und davon verwenden wir dann die letzten beiden Zeilen.

für ältere Excelversionen, unter der Annahme dass der unterste Wert auch immer das höchste Datum ist:

B3: =Max(B5:B999999)
B3: =INDEX(B5:B999999;VERGLEICH(B3;B5:B999999;0)-1)

Gruß Daniel

AW: für ältere XL-Versionen so aber nicht, ...

21.05.2025 16:14:37

neopa C

Hallo Daniel,

... denn Deine letzte Formel für B3 erzeugt einen Zirkelbezug. Und für Deine MAX() Formel müßte gewährleistet sein, dass die in B2 auszuwertenden Datenwerte nicht z.B. 46000 oder noch größer sein können.

Gruß Werner
.. , - ...
aus C the unseen

AW: für ältere XL-Versionen so aber nicht, ...

21.05.2025 16:39:16

BoskoBiati

Hi Werner,

ich denke die Formeln sollen in B2 und B3 stehen, und nicht beide in B3!

Gruß

Edgar

AW: für ältere XL-Versionen so aber nicht, ...

21.05.2025 16:41:43

daniel

das mit dem Zirkelbezug stimmt so nicht. Schau dir die verwendeten Adressen nochmal an.
mit den Werten hast du reicht, aber die Beispielwerte liegen ja deutlich unterhalb der Datumswerte.

AW: sieh Dir nocheinmal an, was Du geschrieben hattest ...

22.05.2025 11:27:12

neopa C

Hallo Daniel,

... denn Du hattest die Formel B3 zugewiesen und da ergibt Deine Formel schon einen Zirkelbezug.

Gruß Werner
.. , - ...
aus C the unseen

AW: sieh Dir nocheinmal an, was Du geschrieben hattest ...

22.05.2025 11:30:06

Daniel

Tippfehler
Eine der Formeln muss in B2 und eine in B3.

AW: genau, und außerdem ...

22.05.2025 11:37:05

neopa C

Hallo nochmal,

... würde ich die INDEX() und VERGLEICH()-Formel hier einfach wie folgt schreiben: =INDEX(B:B;VERGLEICH(B3;B3:B999999;0)+1)

Trotzdem empfehle ich den TE die VERWEIS()-Formel, denn diese ergibt auch dann ein korrektes Ergebnis, wenn (aus welchen Grund auch immer) der letzte Datumswert schon einmal in der Spalte gelistet wurde.

Gruß Werner
.. , - ...
aus C the unseen

AW: genau, und außerdem ...

22.05.2025 12:14:02

Daniel

So ist die Formel schon mal Unsinn, weil der Vergleich immer 1 ergibt.
Du meintest es vermutlich so:

=INDEX(B:B;VERGLEICH(B3;B5:B999999;0)+1)

Kann man so machen, ich würde es nicht tun weil:
- Der Wert +1 ist nicht selbsterklärend, denn er ergibt sich sich aus mehreren Faktoren und muss angepasst werden, wenn die Formel für einen anderen Zellbereich umgeschrieben werden soll. Darauf müsstest du hinweisen und beschreiben, wie dieser Wert ermittelt werden muss.
- im Normalfall passt Excel Formeln automatisch an, wenn man Zeilen einfügt oder löscht, so dass der Anwender nach solchen Aktionen sein Formelwerk nicht überarbeiten muss. Aber der Wert "+1" muss vom Anwender verändert werden, wenn oberhalb von Zeile 5 Zeilen eingefügt oder gelöschst werden, sonst bekommst man ein falsches Ergebnis.

Deswegen ist es sinnvoll, beim Index den selben Zeilenbereich zu verwenden, mit dem auch im Vergleich gearbeitet wird, weil der Vergleich die Positionsnummer liefert und nicht die absolute Zeilennummer.
Index mit ganzer Spalte nimmt man dann, wenn man die Absolute Zeilennummer ermittelt, wie beispielsweise bei Aggregat(...Zeile()/...)

Gruß Daniel

AW: nein, das meinte ich nicht ...

22.05.2025 21:12:56

neopa C

Hallo,

... denn in die Formel hatte ich wirklich auch "Tippfehler eingebaut", auf dessen Hintergrund ich jetzt allerdings nicht weiter eingehe,
Ich schrieb und meinte vor allem, daß ich hier zu den VERWEIS()-Formeln rate. Und wenn vor und oder nach Zeile 2 evtl. Zeilen eingefügt/gelöscht werden sollten, ist ein VERWEIS()-Formelansatz, mit einer einfachen geringfügigen Erweiterung gerade noch immer von Vorteil.
Denn dazu muß in der bisher schon aufgezeigten Formel lediglich zwei "$"-Zeichen ergänzt werden, also einfach so:

=VERWEIS(9;1/(B$5:B9999>"");B$4:B9999)

Gruß Werner
.. , - ...
aus C the unseen

AW: nein, das meinte ich nicht ...

23.05.2025 14:34:54

daniel

ist mir jetzt egal, über deinen Lösungsvorschlag wollte ich nicht reden, denn viele Wege führen nach Rom und jeder muss den finden, der für hin passt. Deswegen ist das für mich ein gültiger Lösungsvorschlag, den ich hier nicht kritisieren oder kommentieren wollte.

trotzdem wollte ich darauf hinweisen, dass wenn man INDEX mit VERGLEICH kombiniert, man für den Index den selben Zeilenbereich verwenden sollte wie im Vergleich, weil man dann keine Korrekturwerte benötigt.
das wird häufig falsch gemacht. Man muss hier darauf achten, ob die Suchfunktion die absolute Zeilennummer ermittelt, dann nimmt man im Index die ganze Spalte, ober ob die Suchfunktion die Postitionsnummer innerhalb des Zellbereichs ermittelt, dann sollte man für Index auch diesen Bereich nehmen und nicht die ganze Spalte.

AW: PQ ist sicher eins der mächtigsten XL-Funkt., jedoch ...

21.05.2025 15:26:01

neopa C

Hallo Yal,

... aber zur Lösung vorliegender Anfrage einerseits wie eine Kanone, die einen Spatzen schießen soll. Meinst Du das nicht auch?

Gruß Werner
.. , - ...
aus C the unseen

AW: PQ ist sicher eins der mächtigsten XL-Funkt., jedoch ...

21.05.2025 15:34:19

Yal

Jein,

Ich kann mir nicht vorstellen, dass man die Daten selber in dieser Form erfasst. Es muss von einem fremden System kommen. Daher ist einerseits eine gewisse Menge zu erwarten ("ich habe in vielen Zeilen Einträge von Werten") und auch, dass die Übergabe über eine Datei erfolgt. Besonders beim zweiten Punkt empfiehlt sich PQ.

Darüber hinaus empfehle ich immer Power Query, weil es eine Zwang zur Strukturierung mit sich bringt: je mehr man mit Power Query macht, desto klar strukturierter organisiert man seine Daten.

Ja, für diese Frage ist es übers Ziel hinaus. Auf lange Sicht ist das Üben von starken Lösungen immer zu bevorzugen.

VG
Yal

AW: ein "Zwang zur (guten/sinnvollen) Strukturierung" ...

21.05.2025 16:11:58

neopa C

Hallo Yal,

... wäre sicherlich stets, zumindest aber meist wünschenswert. Da gebe ich Dir völlig Recht. Aber das sollte nicht nur dann gelten, wenn man Daten in Excel mit PQ auswerten soll oder will.

Im vorliegenden Fall, halte ich eine PQ-Auswertung aber auch nur dann als optimal, wenn die auszuwertenden Daten, zuvor stets aus einem Fremdsystem mit PQ übernommen werden (müssen) andernfalls sollte eine einfache Formelauswertung der PQ-Auswetung vorzuziehen sein. Zumal letztere bei Datenänderung einer zusätzlichen Aktualisierung bedarf.

Gruß Werner
.. , - ...
aus C the unseen

AW: letzten 2 Werte aus einer Spalte

21.05.2025 11:59:32

Tom

Hallo,
vielen Dank für die rasante Hilfe!!!
Grüße

letzten 2 Werte aus einer Spalte

Forumthread: letzten 2 Werte aus einer Spalte

19
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

letzten 2 Werte aus einer Spalte

Forumthread: letzten 2 Werte aus einer Spalte

19 Beiträge zum Forumthread Beiträge zu diesem Forumthread

19
Beiträge zum Forumthread

Beiträge zu diesem Forumthread