Doppelte Wert suchen und zählen

21.05.2025 23:52:44

Manasse

Ich habe eine Matrix mit Namen. In den einzelnen Spalten taucht jeder Name (der jeweils in den Zeilen stehet) nur einmal auf. Bei den vielen vorhandenen Spalten kann es vorkommen, dass ein Name in mehreren Spalten auftaucht.
Ich suche jetzt eine Möglichkeit festzustellen, wie viele Namen in der Matix mehrfach auftauchen.

Für jede Idee bin ich sehr dankbar !!!
Manasse

PS: Die Krönung (aber nicht unbedingt notwendig) wäre, wenn ich bei der Zählung z.B. einen Namen ausklammern könnte :-)

AW: Doppelte Wert suchen und zählen

22.05.2025 01:19:25

Yal

Hallo Manasse,

Du kannst eine bedingte Formatierung auf Basis einer Zählenwenn bauen:
= (Zählenwenn (A1; $A$1:$D$3)>1)

VG
Yal

AW: Doppelte Wert suchen und zählen

23.05.2025 16:12:50

Manasse

Hallo Yal,
eine bedingte Formatierung hatte ich schon erstellt. Dennoch ganz herzlichen Dank für den Tipp.

Gruß Manasse

AW: in Deiner XL-Version z.B. mit einer Hilfsspalte ...

22.05.2025 11:22:16

neopa C

Hallo Manasse,

... lassen sich die Anzahl der unterschiedlichen doppelten Werte ermitteln. Dazu nachfolgendes Beispiel, wo mit der nach unten ziehend kopierten Formel I2 für einen willkürlich festgelegten Bereich die Dopplungen und mit I1 die Gesamtzahl ermittelt wird.. Wobei darin der Namen: "Nam_xx" aus der Ermittlung herausgehalten wurde.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1								gesamt:	5
2		Nam_01	Nam_05		Nam_18			Doppler:	3
3		Nam_02	Nam_12			Nam_22		Dreier:	2
4		Nam_03		Nam_xx		Nam_05		Vierer:	0
5		Nam_xx		Nam_06		Nam_24
6		Nam_05	Nam_15			Nam_02
7		Nam_06	Nam_16		Nam_26
8		Nam_07	Nam_17		Nam_27
9		Nam_17	Nam_18		Nam_xx	Nam_28
10		Nam_09		Nam_19		Nam_17
11

Zelle	Formel
I1	=SUMME(I2:I9)
I2	=SUMMENPRODUKT(--(ZÄHLENWENNS(B$2:F$99;B$2:F$99;B$2:F$99;">Nam_xx")=ZEILE())/ZEILE())

Zelle	bedingte Formatierung...	Format
B2	1: B2="Nam_xx"	abc
B2	2: (ZÄHLENWENN($B$2:$F$19;B2)=2)*(B2>"")	abc
B2	3: (ZÄHLENWENN($B$2:$F$19;B2)=3)*(B2>"")	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß Werner
.. , - ...
aus C the unseen

AW: Doppelte Wert suchen und zählen

22.05.2025 16:08:00

daniel

Hi

wenn du wissen willst, wie viele Namen mehrfach vorkommen, kannst du diese Formel verwenden (ich habe mit der Matrix A1:F15 gestest, das kannst du ja anpassen:

=SUMMENPRODUKT(REST(1/ZÄHLENWENNS(matrix;matrxi);1))

wenn du einen Namen aus der Betrachtung herausnehmen willst, nimm diese Formel, hier wird der Name "xxx" nicht betrachtet:
beachte, dass du Eingabe hier immer mit STRG+SHIFT+ENTER abschließen musst

=SUMME(WENN(matrix="xxx";0;REST(1/ZÄHLENWENNS(matrix;matrix);1)))

Praxistauglicher ist wahrscheinlich folgendes Vorgehen:

1. erstelle dir eine Liste, in der jeder Name 1x vorkommt, wenn du keine andere Quelle hast, kopiere aus der Matrix jede Spalte in eine Spalte untereinander und wende dann das DATEN - DATENTOOLS - DUPLIKATE ENTFERNEN darauf an.
2. wenn du diese Liste hast, schreibe einfach daneben die Formel =ZählenWenns(Matrix;Zelle mit Namen) und ziehe diese nach unten
3. die Spalte wertest du dann mit =ZählenWenns(Spalte;">1") aus.

damit bekommst du nicht nur die Anzahl der doppelten Namen, sondern du siehst auch gleich, welche es sind.

Gruß Daniel

AW: man kann auch die Namen mit Duplikate listen ...

22.05.2025 21:56:56

neopa C

Hallo Manasse,

... meine Frage dazu wäre allerdings, ob und wenn ja Du diese (nur) für "gesamt" oder getrennt für "Doppler", "Dreier", ... gelistet haben möchtest? Beides wäre auch in Deiner XL-Version mit je nur einer kopierbaren Formel realisierbar (ist aber etwas komplexer).

Gruß Werner
.. , - ...
aus C the unseen

AW: man kann auch die Namen mit Duplikate listen ...

23.05.2025 17:50:46

Manasse

Hi,
danke für Deine Rückmeldung.
Meine Matrix bildet Gruppen (Spalten) in denen jeweils die Gruppen-Teilnehmenden (in den Zeilen) enthalten sind. Nicht alle Zeilen in allen Spalten sind gänzlich gefüllt (also gibt es leere Felder). Dann gibt es auch Teilnehmende, die in mehreren Gruppen sind. Die Namen tauchen dann in der Matrix doppelt oder mehrfach auf. Ferner gibt es auch Spalten die mit „X“ gefüllt sind um etwas kenntlich zu machen.
Nun möchte ich, dass jeder Name nur einmal gezählt wird und auch, dass die „X“ nicht mitgezählt werden. Also nur einen Gesantwert.
Hast Du eine Idee wie das darstellbar ist?

Gruß
Gundwin

AW: man kann auch die Namen mit Duplikate listen ...

23.05.2025 17:53:51

BoskoBiati

Hi,

wie wäre es, wenn Du die Matrix mal anhand einer Mustertabelle zeigen würdest?

Gruß

Edgar

AW: dies steht aber im Widerspruch zum bisherigen, ...

27.05.2025 11:11:39

neopa C

Hallo Gundwin,

... denn bisher wurden nur Formeln (welches übrigens für Deine Datenstruktur auch einfacher und kürzer möglich wäre) zum ermitteln der Anzahl der eindeutigen Namen aufgestellt, welche mehrfach gelistet sind. Gemäß Deiner hier zuletzt genannte Fragestellung liest es sich aber so, als ob Du die Anzahl der gelisteten Personen ermitteln willst.
Was also möchtest Du nun wirklich?

Gruß Werner
.. , - ...
aus C the unseen

AW: dies steht aber im Widerspruch zum bisherigen, ...

27.05.2025 18:02:57

Manasse

Hallo Werner,

danke für die Rückmeldung. Es tut mit leid, wenn ich meine Frage nicht eindeutig gestellt habe :-(. Ich starte noch mal einen eindeutigeren Versuch der Frage.

Ich suche die Anzahl der in der Matrix aufgeführten Namen. Ziel ist dabei:
1. Mehrfach in der Matrix vorhandene Namen sollen nur einmal gezählt werden.
2. Lehrstellen sollen nicht mitgezählt werden.
3. Und in diesem Fall die "x" (also spezielle Einträge, die nicht von Relevanz sind) sollen auch nicht mitgezählt werden.

Ist die Frage so eindeutiger gestellt und verständlicher was ich suche?
Hast Du dazu eine gute Lösung?

Gruß Gundwin

AW: jetzt zwar verständlich, aber noch nicht eindeutig ...

27.05.2025 21:41:47

neopa C

Hallo Gundwin,

... und zwar dies durch Deine Aussage: "... (also spezielle Einträge, die nicht von Relevanz sind) sollen auch nicht mitgezählt werden". Welche evtl. weiteren speziellen Einträge, die nicht von Relevanz sind, können denn noch gelistet sein?

Für den Fall das es (wie in Deiner Beispieldatei) außer den Personennamen nur noch "x"-Werte (und keine weiteren "spezielle Einträge") gelistet sind, kann man die Anzahl der gelisteten Personen z.B. mit folgender Formel ermitteln:

=SUMMENPRODUKT((ZÄHLENWENN(B12:BP32;B12:BP32)=1)+(REST(1/(ZÄHLENWENN(B12:BP32;B12:BP32)-(B12:BP32=0));1)))-1

Gruß Werner
.. , - ...
aus C the unseen

AW: die abschließende -1 noch erklärt ...

27.05.2025 21:51:38

neopa C

Hallo,

... mit meiner Formel werden zunächst die "x"-Werte als Name ausgewertet. Da aber "x" keiner ist, muß vom bis dahin ermittelten Ergebniswert einfach ein "Name" wieder abgezogen werden.

Falls es bei Dir den Sonderfall geben könnte, dass außer den echten Namen kein "x"-Wert im auszuwertenden Bereich stehen könnte, dann müßtest Du in der Formel die -1 durch: -(ZÄHLENWENN(B12:BP32;"x")>1) ersetzen.

Gruß Werner
.. , - ...
aus C the unseen

AW: jetzt zwar verständlich, aber noch nicht eindeutig ...

27.05.2025 22:36:02

Daniel

Wenn auch Personen, die nur einmal vorkommen, gezählt werden sollen, kannst du auch das Rest(...;1) einfach weglassen, dann brauchst du das erste Zählenwenns nicht.

Gruß Daniel

AW: kann ich so nicht nachvollziehen owT

28.05.2025 20:04:17

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: daraus nun einfach folgendes ergänzend abgeleitet, ...

27.05.2025 22:02:12

neopa C

Hallo,

... wenn als "weiteren speziellen Einträge, die nicht von Relevanz sind" neben "x" z.B. noch "y" und/oder "z" sind bzw. sein könnten, dann müßtest Du diesen Formelteil lediglich durch

...+SUMMENPRODUKT(-(ZÄHLENWENN(B12:P32;{"x";"y";"z"})>1))

ersetzen. Die Matrix ; {"x";"y";"z"} könntest Du natürlich auch einfach bei entsprechenden Bedarf erweitern.

Gruß Werner
.. , - ...
aus C the unseen

AW: man kann auch die Namen mit Duplikate listen ...

23.05.2025 23:02:25

Manasse

Hier ein Beispiel von meiner Matrix

https://www.herber.de/bbs/user/177549.xlsx

AW: Leerzelle(n) in der "matrix" führt/en zu #DIV/0! owT

22.05.2025 21:25:50

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: Doppelte Wert suchen und zählen

23.05.2025 17:47:47

Manasse

Hi,
danke für Deine Rückmeldung. Ich habe alles ausprobiert. Nur will es nicht recht klappen.

Meine Matrix bildet Gruppen (Spalten) in denen jeweils die Gruppen-Teilnehmenden (in den Zeilen) enthalten sind. Nicht alle Zeilen in allen Spalten sind gänzlich gefüllt (also gibt es leere Felder). Dann gibt es auch Teilnehmende, die in mehreren Gruppen sind. Die Namen tauchen dann in der Matrix doppelt oder mehrfach auf. Ferner gibt es auch Spalten die mit „X“ gefüllt sind um etwas kenntlich zu machen.
Nun möchte ich, dass jeder Name nur einmal gezählt wird und auch, dass die „X“ nicht mitgezählt werden.

Ich habe Deine Formel versucht zu nutzen um auch die „X“ nicht mitzuzählen, bekomme aber die Fehlermeldungen #DIV/0!

{=SUMME(WENN(B12:BP32="x";0;REST(1/ZÄHLENWENNS(B12:BP32;B12:BP32);1)))}

Hast Du noch eine Idee oder einen Vorschlag?

Gruß
Manasse

AW: Doppelte Wert suchen und zählen

23.05.2025 18:34:56

daniel

Hi
du musst die Leerzellen ebenfalls mit aus der Rechnung rausnehmen.
das Problem ist, das =ZählenWenn(A:A;B1) leider nicht die Leerzellen zählt, wenn B1 leer ist (warum auch immer, Leerzellen sind halt immer ein Sonderfall), sondern das als 0 zählt, was dann natürlich den Div/0-Fehler erzeugt.

{=SUMME(WENN(B12:BP32="";0;WENN(B12:BP32="x";0;REST(1/ZÄHLENWENNS(B12:BP32;B12:BP32);1))))}

Gruß Daniel

AW: Doppelte Wert suchen und zählen

24.05.2025 00:31:09

Manasse

Hi Daniel,
echt cool, alles läuft perfekt!! Ganz herzlichen Dank!

Gruß Gundwin

AW: Doppelte Wert suchen und zählen

23.05.2025 20:14:25

daniel

Hi
noch ne andere Variante.

wenn du sicher bist, dass mehrere "x" vorkommen, kann man die ja auch nachträglich rausrechnen:

=SUMMENPRODUKT(WENNFEHLER(REST(1/ZÄHLENWENNS(matrix;matrix);1);0))-1

wenn du prüfen musst, ob das "x" mehrfach vorkommt, dann:

=SUMMENPRODUKT(WENNFEHLER(REST(1/ZÄHLENWENNS(matrix;matrix);1);0))-(ZÄHLENWENNS(matrix;"x")>1)

ob das WennFehler in deiner Excelversion die Matrixformeleingabe erforderlich macht, müsstest du mal testen.

Gruß Daniel

AW: Leerzelle(n) in der "matrix" führt/en zu #DIV/0! owT

22.05.2025 22:37:09

daniel

die kann man ja rausnehmen.
die formel dazu habe ich auch gezeigt.

AW: Leerzelle(n) in der "matrix" führt/en zu #DIV/0! owT

27.05.2025 15:15:39

daniel

diesen Fehler kann man auch so vermeiden:

=SUMME(WENN(matrix="xxx";0;REST(1/ZÄHLENWENNS(matrix;matrix&"");1)))

dann werden auch echte Leerzellen gezählt.
Allerdings gehen die dann wie ein normaler Name in die Rechnung mit ein und müssten sowieso wie schon an anderer Stelle gezeigt herausgerechnet werden.

AW: es geht aber auch ohne WENN(), {} und ohne &"" owT

27.05.2025 15:26:07

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: es geht aber auch ohne WENN(), {} und ohne &"" owT

27.05.2025 15:34:54

daniel

viele Wege führen nach Rom.

AW: manche "Wege" sind/erscheinen halt einfacher owT

27.05.2025 15:42:46

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: manche "Wege" sind/erscheinen halt einfacher owT

27.05.2025 16:12:02

daniel

was einem einfacher erscheint, ist oft individuell unterschiedlich und hängt u.a. vom Vorwissen, aber auch von der eigenen Denkstruktur ab.

Doppelte Wert suchen und zählen

Forumthread: Doppelte Wert suchen und zählen

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Doppelte Wert suchen und zählen

Forumthread: Doppelte Wert suchen und zählen

26 Beiträge zum Forumthread Beiträge zu diesem Forumthread

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread