Anzahl Wert in einer Zelle

27.06.2025 09:46:52

Uwe Baier

Hallo zusammen,

kann man mein folgendes Problem überhaut lösen?
Ich habe schon sämtliche Versuche mit Länge,Anzah,ZähleWenn Funktionen und auch kombiniert versucht und komme leider auf keine Lösung.
Vielleicht habe ich ein Denkfehler und stehe auf der Leitung.

Also, ich will folgenden Wert erhalten:
In der Zeile A1 steht z.B. entweder mit Komma oder Leerzeichen oder kombiniert mit Komma und Leerzeichen getrennte Werte:
Apfel,Birne, Kiwi Apfel, Kiwi Trauben usw. oder 1,5 8 7, 1,4 1

Hier will ich mit einer Formel die Anzahl ermitteln wie oft ein bestimmter Wert z.B Apfel oder die Zahl 1 vorhanden ist.

Gibt es dafür einen Lösungsansatz?

Danke vorab schon mal und Grüße
Uwe

AW: Anzahl Wert in einer Zelle

27.06.2025 09:59:37

UweD

Hallo Uwe (schöner Name)

so??

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Apfel,Birne, Kiwi Apfel, Kiwi Trauben		Apfel	2
2	1,5 8 7, 1,4 1		1	3

Zelle	Formel
D1	=(LÄNGE(A1)-LÄNGE(WECHSELN(A1;C1;"")))/LÄNGE(C1)

LG UweD

AW: Anzahl Wert in einer Zelle

27.06.2025 10:45:33

Daniel

Hi

Mit Excel 365 auch so:

=SUMME(1*(TEXTTEILEN(A1;{" ";","})=C1))

Der Unterschied zur Lösung von Uwe ist folgender:
Stehen in der Auflistung auch Begriffe wie "Apfelsaft" und "Apfelkuchen", dann würde die Formel von Uwe diese bei der Suche nach "Apfel" mitzählen, diese hingegen nicht.

Gruß Daniel

Ein weiterer...

27.06.2025 11:43:48

Case

Moin Uwe, :-)

... Lösungsansatz wäre Power Query: ;-)
https://www.herber.de/bbs/user/177933.xlsx

Servus
Case

Noch Einen...

27.06.2025 12:36:03

UweD

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Apfel,Birne, Kiwi Apfel, Kiwi Trauben		Apfel	2
2	1,5 8 7, 1,4 11 ,111		1	2

Zelle	Formel
D1	=ANZAHL2(LET(a;TEXTTEILEN(A1;{",";" "});FILTER(a;a=C1)))

Die Spalte C muss als Text formatiert sein

LG UweD

AW: Noch Einen...

27.06.2025 12:48:55

daniel

Achtung:

wenn du FILTER+ANZAHL2 als Zählfunktion verwendest, dann musst du beachten, dass ANZAHL2 auch Fehlerwerte mitzählt.
Wenn also der Suchbegriff nicht vorkommt und der Filter leer ist, dann ist das Ergebnis deiner Formel nicht 0, sondern 1, weil der #Calc-Fehler bei leerem Filter auch gezählt wird.
Diesen Fall muss man in der Formel korrigieren.
ANZAHL2 durch AGGREGAT(3;6;...) zu ersetzen funktioniert leider nicht, da AGGREGAT hier Zellbereiche als Eingabe erwartet

so vielleicht:

=SUMME(LET(a;TEXTTEILEN(A1;{",";" "});FILTER(--(a>"");a=C1;0)))

Gruß Daniel

AW: Anzahl Wert in einer Zelle

27.06.2025 10:07:27

Uwe Baier

Mensch Uwe (wirklich ein schöner Name),

vielen Dank funktioniert einwandfrei ich bin begeistert und eigentlich gar nicht so schwer.
Da muss ich noch einiges lernen.

Gruß
Uwe

AW: Anzahl Wert in einer Zelle

27.06.2025 11:27:31

Luschi

Hallo Uwe,

meine Formel sieht so aus: =SUMME(--(TEXTTEILEN(A1;{" ";","})=C1&"")) bzw. =SUMME(--(TEXTTEILEN(A2;{" ";","})=C2&""))

Wenn Du in der Zahlenreihe nach 1 suchst, in der Zahlenreihe selbst steht aber auch die '11' bzw '111', dann rechnen die Formeln vom Namensvetter Uwe und von Daniel falsch.

Gruß von Luschi
aus klein-Paris

AW: Anzahl Wert in einer Zelle

27.06.2025 11:53:50

Uwe Baier

Hi Luschi,

danke super 👍

AW: Anzahl Wert in einer Zelle

27.06.2025 12:31:18

daniel

ist doch jetzt fast die gleiche Formel wie meine
gut abgeschrieben
mit dem "Zahl als Text" hast du natürlich recht, da habe ich nicht dran gedacht.
aber das '111'-Problem bei Suche nach '1' hat deine Formel genauso wie meine.

AW: Anzahl Wert in einer Zelle

30.06.2025 09:42:17

Uwe Baier

Hi Luschi,

danke, habe die Formel verwendet und funktioniert bei mir einwandfrei.
Ich habe nur noch ein Problem, das diese Datei auch ein Kollege verwendet und der hat Office 2021 und da macht er aus =SUMME(--(TEXTTEILEN(A1;{" ";","})=C1&"")) folgendes =SUMME(--(_xlfn.TEXTSPIT(A1;{" ";","})=C1&"")) und bringt ihm ein Fehler #####.

Außerdem haben wir im Verein ein Laptop mit Office 2007 glaube ich und weiß gar nicht wie sich dies dort auswirkt.

Hast Du eine Lösung wo er wirklich nur nach der 1 sucht und bei allen Versionen geht? Kann ruhig auch umständlicher sein, Hauptsache es führt zum Ziel.

Danke vorab schon mal

;-)

Uwe

Die Formel...

30.06.2025 14:03:25

Case

Moin Uwe, :-)

... von Daniel ist das bequemste, was du nutzen kannst - aber dafür benötigt ihr die neueste Excelversion. In Excel 2007 läuft mit den Formeln nix. ;-)

Wenn ihr VBA nutzen könnt, dann kannst du dir mal die Datei im Anhang anschauen: ;-)
https://www.herber.de/bbs/user/177958.xlsb

Wenn du das nutzen willst, musst du das Modul1 in deine Datei kopieren und sie als XLSM oder XLSB speichern. ;-)

Die Ausgaben in Spalte I und L spillen. Das geht in alten Versionen auch nicht. Da musst du die Formel mit STRG+SHIFT+ENTER abschließen. Such mal im Netzt danach. ;-)

In G10 und I10 siehst du wie es Case-Sensitiv arbeitet (also apfel - Apfel). ;-)

Servus
Case

AW: Die Formel...

30.06.2025 14:10:14

Uwe Baier

Hi Case,

danke, hoffe es gibt eine einfachere Lösung.

Gruß
Uwe

AW: Die Formel...

30.06.2025 15:40:51

daniel

Hi
wenn du Excel 2007 hast und eine Formellösung willst, dann solltest du nochmal auf die erste Formel von UweD schauen (das mit dem Zeichen zählen und durch nichts ersetzen)

damit das aber sauber funktioniert (insbesondere das mit dem ("1" zählt nur "1" und nicht auch "123" oder "111" dann 3x) muss man die Texte etwas vorbereiten.
zum einen benötigst du ein einheitliches Trennzeichen (" " oder ",", aber nicht beides gemischt), es müssen zwischen jedem Wort zwei Trennzeichen stehen und am Anfang und Ende muss auch ein Trennzeichen stehen, dh das muss dann in einer Zelle so aussehen:

,Apfel,,Birne,,Kiwi,,Apfel,,Kiwi,,Trauben,
,1,,5,,8,,7,,1,,4,,1,

dh du müsstest in einer Hilfsspalte deine Texte erstmal so hintrimmen, dazu in einer Hilfsspalte (B) diese Formel

=","&Wechseln(Glätten(Wechseln(A1;",";" "));" ";",,")&","

und dann zählen mit der Formel von UweD, ergänzt um die Trennzeichen

=(LÄNGE(B1)-LÄNGE(WECHSELN(B1;","&C1&",";"")))/(LÄNGE(C1)+2)

wenn du die zusätzliche Spalte nicht magst, kannst du die auch weglassen, wenn du stattdesen die Formel von B1 an die entsprechenden Stellen in der Zählformel einsetzt.
Ich würde aber davon abraten und erstmal mit der Hilfsspalte arbeiten, weil die Formel ohne die zusätzliche Spalte so aussieht:

=(LÄNGE(","&Wechseln(Glätten(Wechseln(A1;",";" "));" ";",,")&",")-LÄNGE(WECHSELN(","&Wechseln(Glätten(Wechseln(A1;",";" "));" ";",,")&",";","&C1&",";"")))/(LÄNGE(C1)+2)

Gruß Daniel
ps: und in Zukunft bitte immer gleich bei Version immer die älteste Excelversion angeben, auf der die Anwendung laufen muss (auch wenn du selbst was neueres hast)

AW: Die Formel...

01.07.2025 11:19:15

Uwe Baier

Hi Daniel,

sry das ich jetzt erst Antworte. Bin gestern nicht mehr dazu gekommen.

Du bist der Wahnsinn, vielen vielen Dank und werde daran denken das ich die älteste Version angebe.

Gruß
Uwe

AW: Die Formel...

01.07.2025 12:22:52

UweD

Hallo

Ähnliches Verfahren wie von Daniel aber ohne das Glätten. Dadurch ist die Formel etwas kürzer.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Apfel,Birne, Kiwi Apfel, Kiwi Trauben		Apfel	2
2	1,5 8 7, 14 11		1	1

Zelle	Formel
D1	=(LÄNGE(","&WECHSELN(A1;" ";",")&",")-LÄNGE(WECHSELN(","&WECHSELN(A1;" ";",")&",";","&C1&",";"")))/(LÄNGE(C1)+2)

LG UweD

Anzahl Wert in einer Zelle

Forumthread: Anzahl Wert in einer Zelle

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Anzahl Wert in einer Zelle

Forumthread: Anzahl Wert in einer Zelle

15 Beiträge zum Forumthread Beiträge zu diesem Forumthread

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread