HERBERS

Excel-Forum (Archiv)

20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender

Rückwärts Blättern

Aktuelles Verzeichnis

Übersicht Verzeichnisse

Nächster Thread

Vorwärts blättern

Inhaltsverzeichnis

Matrixsuche mit Textfragment in Zelle

Forumthread: Matrixsuche mit Textfragment in Zelle
12 Beiträge zu diesem Forumthread
Anzeige

Forumthread: Matrixsuche mit Textfragment in Zelle

27.06.2025 14:41:43

Iris

Hallo,
vielleicht hat ja jemand von euch einen heißen Tipp für mich.
Ich ermittle über eine Matrix einen Wert, der mit eindeutigen Referenzen arbeitet:
Zelle B1 = 1000
Zelle B2 = VST
Zelle A3 = SG500
Die Formel dazu

=SUMME(WENN((Tabelle!$A$4:$AP$4=$A3)*(Tabelle!$A$7:$A$40=B$1)*(Tabelle!$C$7:$C$40=B$2);Tabelle!$A$7:$AP$40;0))

Diese funktioniert auch wunderbar.
Jetzt ändert sicher aber die Anforderung, weil ich nicht mehr "VST" abfragen muss, sondern das Textfragement "VST". Dafür hätte ich die Formel wie folgt angepasst:

=SUMME(WENN((Tabelle!$A$4:$AP$4=$A3)*(Tabelle!$A$7:$A$40=B$1)*(Tabelle!$C$7:$C$40="*"&B$2);Tabelle!$A$7:$AP$40;0))

Die funktioniert nicht.
Auch wenn ich in B2 *VST eingebe bekomme ich kein Ergebnis.
Was mache ich falsch und wie wäre es richtig? Bitte um Hilfe
Iris

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 14:48:14

SF
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:11:29

Iris
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:15:47

SF
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 17:07:19

Michael
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 18:03:46

daniel
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 18:02:36

Michael
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:02:34

Piet
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:16:41

daniel
AW: Matrixsuche mit Textfragment in Zelle

30.06.2025 10:11:57

Iris
Das würde auch...

29.06.2025 00:19:44

Case
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:13:30

Iris
AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:25:45

daniel

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 14:48:14

Hola,
ungetestet weil keine Lust etwas nachzubauen.

=SUMME(WENN((Tabelle!$A$4:$AP$4=$A3)*(Tabelle!$A$7:$A$40=B$1)*(ISTZAHL(SUCHEN("vst";Tabelle!$C$7:$C$40)));Tabelle!$A$7:$AP$40;0))

Gruß,
steve1da

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:11:29

Iris

@steve1da Danke für deinen Hinweis, das Beispielfile muss ich schon bereitstellen ':)
https://www.herber.de/bbs/user/177938.xlsx
Ich bekomme es leider noch nicht hin.

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:15:47

Ich habe doch geschrieben wie man das abfragt, mit Istzahl(suchen(.....)).

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 17:07:19

Michael

Hallo Iris,

die 4.360 in Deiner Beispieldatei dürften doch nur 4.010 sein, oder?
Diese Formel trennt die Suche nach der Spalte (Index) und das Suchen nach den Zeilen (Filter). Und kommt auf 4.010, wie sie auch von Hand per Spaltenfiltern ermittelt werden kann:

=SUMME(FILTER(INDEX(Payroll_basis[[Teil1]:[Teil4]];;VERGLEICH($A3;Tabelle1!$C$1:$F$1;0));(Payroll_basis[P1]=$B$1)*(Payroll_basis[P2]=$B$2)))

Und diese Formel kommt auf 6.023, weil sie in [P2] nach enthält "vst" sucht (Inspiriert von Steve):

=SUMME(FILTER(INDEX(Payroll_basis[[Teil1]:[Teil4]];;VERGLEICH($A3;Tabelle1!$C$1:$F$1;0));(Payroll_basis[P1]=$B$1)*(ISTZAHL(SUCHEN($B$2;Payroll_basis[P2])))))

Sollte mit Deiner Office-Version funktionieren.

VG und ein schönes Wochenende
Michael

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 18:03:46

daniel

Hi

hier nochmal meine Lösung angepasst und getestet mit deiner Beispieldatei:

=SUMME((Tabelle1!$C$1:$F$1=$A3)*(Payroll_basis[P1]=D$1)*(NACHZEILE(Payroll_basis[P2];LAMBDA(x;ZÄHLENWENNS(x;D$2))))*Payroll_basis[[Teil1]:[Teil4]])

wie gesagt, hier kannst du die Joker bei Bedarf gleich mit in die Zeile 2 mit eingeben (also *VST* für suchen mit enthält VST und VST für suchen mit entspricht genau VST

Gruß Daniel

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 18:02:36

Michael

Hallo nochmal,

dass es mehrere Spalten sein können, aus denen die Zahlen zum Summieren kommen können, sah ich natürlich erst kurz nach dem Absenden...

Das wollte ich gerne besser hinkriegen und durchdrang Deine, Steves und Daniels Formeln. Nun funktionieren sie ;-)
Blatt 'Export'!E1:G5
https://www.herber.de/bbs/user/177940.xlsx

VG Michael

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:02:34

Piet

Hallo

probiere bitte mal so: --> (Tabelle!$C$7:$C$40="*"& B$2 &"*")

mfg Piet

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:16:41

daniel

Hi

probiers mal so:

=SUMME(WENN((Tabelle!$A$4:$AP$4=$A3)*(Tabelle!$A$7:$A$40=B$1)*(NACHZEILE(Tabelle!$C$7:$C$40;LAMBDA(x;ZÄHLENWENNS(x;B$2))));Tabelle!$A$7:$AP$40;0))

hier kannst du selber steuern, ob mit "entlhält" oder mit "entspricht" verglichen wird, indem du den Vergleichswert mit oder ohne Jokerzeichen in B2 eingibst ("VST" oder "*VST*")
wenn immer mit "enthält" gesucht werden soll, dann fügst du die Jokerzeichen in der Formel hinzu ...;"*"&B$2&"*")...

Gruß Daniel

AW: Matrixsuche mit Textfragment in Zelle

30.06.2025 10:11:57

Iris

@Daniel
Danke für deine Anweisungen und für die Formeloptionen im File. Ich konnte das übernehmen und es geht sehr gut. In der Referenzzelle nehme ich die Joker und dann die Formel von dir mit Tabellenbezug. Das funktioniert wurderbar. Werde mich auch gleich noch in die FACHZEILE und LAMBDA einlesen, damit ich auch verstehe, was ich da nutze ;)

Danke euch allen für eure Hilfe!

Das würde auch...

29.06.2025 00:19:44

Case

Moin Iris, :-)

... prima in Power Query gehen. ;-)

Servus
Case

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:13:30

Iris

@Piet Leider nein.
Ich verstehe nicht, welchen Bug ich da drin hab...

AW: Matrixsuche mit Textfragment in Zelle

27.06.2025 15:25:45

daniel

Hi
der Vergleich mit "=" kann keine Joker verarbeiten.
der Fehler liegt nicht bei dir, sondern schon in der Lösungsidee.
du kannst auf "enthält" mit IstZahl(Finden(kurzer Text;Langer Text)) oder IstZahl(Suchen(kurzer Text;Langer Text)) prüfen (Finden: Großkleins-schreibung wird mit beachten, Suchen: Großklein-Schreibung wird nicht beachtet)
oder du schaust dir mal meinen Lösungsvorschlag an.

Gruß Daniel

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!