Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

25.11.2025 18:08:47

Dalberto

Hallo,
ich beabsichtige eine Familienstammbaum zu erstellen in dem die Zellen das Foto der Person zeigen.
Auf "Klick" in die Zelle sollte sie auf Bildschirmgröße vergrößert werden.

Danke,
DW

AW: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

25.11.2025 18:42:40

UweD

HAllo

Bin nicht sicher, was du meinst..

Zoom ist bis max 400 % möglich

versuch mal

- Einmal Rechtsclick auf den Tabellenblattreiter
- Code anzeigen
- Diesen Code rechts reinkopieren

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)

    If Not Intersect(Target, Range("A1:A10")) Is Nothing Then

        If Target > "" Then

            ActiveWindow.Zoom = Application.Min(Application.Width, 400)

        Else

            ActiveWindow.Zoom = 100

        End If

        Cancel = True

    Else

        ActiveWindow.Zoom = 100

    

    End If

End Sub

Wenn du nun in einer Zelle (A1:A10 Bereich anpassen) einen Rechstclick machst, läuft das Makro ab
Andere Zellen und Zelle Leer setzt auf 100 zurück

LG UweD

AW: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

25.11.2025 19:42:34

xlKing

Hallo Dalberto,

irgendwas stimmt hier nicht. In den Excelversionen bis 2003 können Zellen noch keine Fotos zeigen. Das funktioniert erst seit Office 365. Du kannst auch keine einzelnen Zellen vergrößern, sondern nur ganze Zeilen und Spalten, wobei diese auf eine Maximalgröße begrenzt sind. So füllt die maximale Zeilenhöhe nur etwa die Hälfte heutiger Bildschirme.

Was du aber in deiner Version machen kannst ist, das Foto auf ganz normale Weise als Shape einzufügen und diesem dann per Rechtsklick ein Makro zuzuweisen, in welchem du Maße und Position anpasst. Das Makro wird dann bei Klick auf das Foto ausgeführt. Ein weitere Klick verkleinert es dann wieder.

Dim Schalter As Boolean

Dim l As Single, t As Single, w As Single, h As Single

Sub Vergroessern()

  Schalter = Not Schalter

  Application.DisplayFullScreen = Schalter

  ActiveWindow.DisplayHeadings = Not Schalter

  If Schalter Then

    With ActiveSheet.Shapes(Application.Caller)

      l = .Left

      t = .Top

      w = .Width

      h = .Height

      .Left = ActiveWindow.Left

      .Top = ActiveWindow.Top

      .Width = ActiveWindow.UsableWidth

      .Height = ActiveWindow.UsableHeight

    End With

  Else

    With ActiveSheet.Shapes(Application.Caller)

      .Left = l

      .Top = t

      .Width = w

      .Height = h

    End With

  End If

End Sub

Gruß Mr. K.

AW: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

25.11.2025 20:52:29

xlKing

Hab den Code grade noch mal erweitert. Wenn du wirklich (fast) den ganzen Bildschirm ausfüllen, also das Bild auch strecken und stauchen willst, dann nimm diesen.

Dim Schalter As Boolean

Dim l As Single, t As Single, w As Single, h As Single, s As Long, c As Long

Sub Vergroessern()

  Schalter = Not Schalter

  Application.DisplayFullScreen = Schalter

  ActiveWindow.DisplayHeadings = Not Schalter

  If Schalter Then

    With ActiveSheet.Shapes(Application.Caller)

      l = .Left

      t = .Top

      w = .Width

      h = .Height

      .LockAspectRatio = msoFalse

      .Left = ActiveWindow.Left

      .Top = ActiveWindow.Top

      .Height = ActiveWindow.UsableHeight

      .Width = ActiveWindow.UsableWidth

      s = ActiveWindow.ScrollRow

      c = ActiveWindow.ScrollColumn

      ActiveWindow.ScrollRow = 1

      ActiveWindow.ScrollColumn = 1

    End With

  Else

    With ActiveSheet.Shapes(Application.Caller)

      .Left = l

      .Top = t

      .Width = w

      .Height = h

      ActiveWindow.ScrollRow = s

      ActiveWindow.ScrollColumn = c

    End With

  End If

End Sub

Gruß Mr. K.

AW: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

26.11.2025 14:32:34

Dalberto

Vielen Dank für Deine Mühe,
Ich habe die falsch Version angekreuzt, es handelt sich um Excel 2016.
Ich werde Dir Bericht erstatten.

Dieter

Alle guten Dinge sind 3

25.11.2025 21:52:54

xlKing

So, bis auf Taskbar und Titelleiste ist jetzt alles weg und lässt sich auch nicht mehr wegscrollen, bis man wieder auf das Bild klickt. So siehts am saubersten aus. Die Titelleiste würde man zwar mit Windows-API-Funktion auch noch wegkriegen, aber dann zeichnet Windows 11 keine korrekten Ränder mehr. Unter Vista hat das besser funktioniert. Deshalb hab ich auf diese Funktion verzichtet.

Dim Schalter As Boolean

Dim l As Single, t As Single, w As Single, h As Single, s As Long, c As Long

Sub Vergroessern()

  Schalter = Not Schalter

  

  Application.DisplayFullScreen = Schalter

  ActiveWindow.DisplayHeadings = Not Schalter

  ActiveWindow.DisplayHorizontalScrollBar = Not Schalter

  ActiveWindow.DisplayVerticalScrollBar = Not Schalter

  ActiveWindow.DisplayWorkbookTabs = Not Schalter

   

  If Schalter Then

    ActiveSheet.ScrollArea = "A1"

    With ActiveSheet.Shapes(Application.Caller)

      s = ActiveWindow.ScrollRow

      c = ActiveWindow.ScrollColumn

      l = .Left

      t = .Top

      w = .Width

      h = .Height

      ActiveWindow.ScrollRow = 1

      ActiveWindow.ScrollColumn = 1

      .LockAspectRatio = msoFalse

      .Left = ActiveWindow.Left

      .Top = ActiveWindow.Top

      .Height = Application.Height ' ActiveWindow.UsableHeight

      .Width = Application.Width 'ActiveWindow.UsableWidth

    End With

  Else

    ActiveSheet.ScrollArea = ""

    With ActiveSheet.Shapes(Application.Caller)

      .Left = l

      .Top = t

      .Width = w

      .Height = h

      ActiveWindow.ScrollRow = s

      ActiveWindow.ScrollColumn = c

    End With

  End If

    

End Sub

Gruß Mr. K.

Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

Forumthread: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

Forumthread: Inhalt einer Zelle mit Klick auf Bildschirmgröße vergrößern

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread