Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 01:07:23

Frag Herber

Hallo zusammen

Wir benötigen Hilfe bei der folgenden Problemstellung. Wir haben im Register Arbeiten sämtliche Mannstunden pro Datum und den entsprechendem Code für die Arbeitsleistungen aufgeführt.

Beispieldatei: https://www.herber.de/bbs/user/179720.xlsx

Jetzt möchten wir im Register Rapport jeweils die Mann- und Maschinenstunden pro Datum zusammenziehen. Das heisst in Zelle A6, Arbeiten gemäss dem entsprechenden Code, A7, das Datum, in B7, das Total der Arbeitsstunden pro Datum in C7, Totalstunden Motormäher, usw..

Wenn wir dies haben, möchten wir das Gesamttotal der Mann- und der entsprechenden Maschinenstunden in das Rechnungsformular übertragen.

Wir hoffen, dass dies einigermassen verständlich ist und ihr uns weiterhelfen könnt. Jetzt schon mal besten Dank für Eure Unterstützung.

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 07:26:59

SF

Hola,
a) wenn im Blatt Arbeiten in jeder Zelle in Spalte A das jeweilige Datum stehen würde wäre das für weitere Formeln sehr viel einfacher
b) in A6 soll der Code, und dann eine Zeile darunter die zugehörigen Infos? Warum der Versatz?
c) im Blatt Arbeiten tauchen nirgendwo Motormäher, Motorsense, Motorsäge, Traktor auf. Wie sollen also die Stunden ermittelt werden?
d) ein händisch eingetragenes Wunschergebnis macht es für Helfer zusätzlich einfacher zu Helfen

Gruß,
steve1da

Sorry, Motormäher etc erst nach dem Abschicken entdeckt owt.

27.11.2025 07:27:46

SF

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 10:47:48

Alwin Weisangler

Hallo,

fülle bitte den Rapport händisch für das Objekt 2 aus und lade dies hoch. Dann kann man sich ein Bild machen, wie man so was brauchbar lösen kann. Du hast O365 angegeben und da lässt sich dies vermutlich mit LET() und/oder LAMBDA() lösen und braucht vielleicht kein VBA.
Was die Rohdaten in Blatt „Arbeiten“ betrifft, achte immer darauf, dass Datensätze vollständig vorhanden sind und nicht wie in der Beispieldatei in Spalte A, Spalte B.
Mit VBA könnte man das zwar mit unnötigem Aufwand weiterverarbeiten, aber keinesfalls in Formeln.
Dann warten wir mal ab, was du uns bereitstellst.

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 11:58:36

Frag Herber

Hallo zusammen
Vorneweg - besten Dank für Eure Antworten. Aufgrund dieser habe ich die Tabelle angepasst und teilweise händisch eingetragen. Das Ergebnis im Rapport habe ich auf Spalten verteilt, ohne Versatz für den Titel.
Das Blatt Arbeiten habe ich auch ergänzt. Bei den Maschinenstunden habe ich nicht alles ausgefüllt. Falls es das Ganze vereinfachen würde oder benötigt wird, könnte ich die Maschinenstunden auch noch "nullern", wenn keine eingesetzt wurden.

Datei: https://www.herber.de/bbs/user/179730.xlsx

Ich hoffe, dass dies weiterhilft. Ansonsten nochmals schreiben und ich passe es nochmals an.
Danke und Gruss

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 12:17:18

Alwin Weisangler

Hallo,

jetzt sieht die Sache schon ganz anders aus. Eine Frage bleibt noch offen bevor es sich lohnt da eine Formel zu bauen.
Soll in Rapport nur ein Objekt, welches ausgewählt werden soll erstellt werden oder gleich alle Objekte.

Wobei alle Objekte eigentlich nicht wirklich sinnig sind, da du ja die Tabelle in Rapport Fix hast. Es wäre dann eine Vorauswahl DropDown? Oder eine irgendwie definierte Bedingung zum Filtern der passenden Daten erforderlich.

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 13:01:00

Frag Herber

Wir müssen die Objekte bzw. die verschiedenen Unterhaltsarten einzeln abrechnen.

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 14:51:53

Alwin Weisangler

Also im Rapport ein ausgewähltes Objekt aus der Liste "Arbeiten". Richtig so?

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 16:53:08

Frag Herber

Im Rapport nach Objekt. Und dann nach den Arbeitsleistungen (Code).

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 16:39:55

Alwin Weisangler

Hallo,

ich habe mal die Tabelle in Rapport soweit mit Auswahl des Objektes in A1 und mit Formeln zurechtgemacht. Ich hoffe, dass ich es richtig verstanden habe.
https://www.herber.de/bbs/user/179733.xlsx

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 16:54:42

Frag Herber

Sorry - die Tabelle erst jetzt gesehen. Werde diese anschauen und mich wieder melden. Jetzt schon mal besten Dank für Deine Arbeit.

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 17:15:42

Frag Herber

Das sieht schon mal super aus. Danke vielmals! Schön wäre, wenn die Arbeitsleistungen auch noch sortiert wären. Da wir in der Rechnung die Arbeitsgattungen einzeln aufführen und zusammenziehen müssen.

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 18:27:34

Alwin Weisangler

Hallo,

Soll nach Datum sortiert werden oder nach "Art des Unterhalts"

nach Datum:


=LET(xA;Arbeiten!A12:F10000;xB;SPALTENWAHL(xA;2;5;1);xC;FILTER(xB;INDEX(xB;;1)=A1);SORTIEREN(EINDEUTIG(xC;FALSCH);3;1))

Nach Art des Unterhalts:


=LET(xA;Arbeiten!A12:F10000;xB;SPALTENWAHL(xA;2;5;1);xC;FILTER(xB;INDEX(xB;;1)=A1);SORTIEREN(EINDEUTIG(xC;FALSCH);2;1))

Das ist eigentlich recht einfach.

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

27.11.2025 19:39:52

Frag Herber

Hallo Uwe

So passt dies für mich. Das ist super! Gewisse Anpassungsarbeiten sollte ich selber hin bekommen. Ich werde den Thread schliessen. Falls ich dann nochmals etwas zusätzliches benötigen würde, melde ich mich wieder. Aber damit können wir erst mal arbeiten.

Vielen Dank! Du hast uns sehr geholfen.

Grüsse aus der Schweiz

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

28.11.2025 10:20:36

Alwin Weisangler

Hallo,

ich habe mir gerade noch mal die Sache angeschaut. Da habe ich leider eine Prüfung in SUMMEWENNS() übersehen.
Korrigiert im Blatt "Rapport" in Zelle D6:


=WENN($C6>0;SUMMEWENNS(Arbeiten!H$12:H$10000;Arbeiten!$B$12:$B$10000;$A6;Arbeiten!$A$12:$A$10000;$C6;Arbeiten!$E$12:$E$10000;$B6);"")

rüberziehen bis Spalte H und runterziehen bis Zeile 25

Man kann es aber auch mit einer LET() lösen. Dazu alle Formeln im Blatt "Rapport" aus Spalte A bis H entfernen und in Zelle A6:


=LET(xA;Arbeiten!A12:L10000;xB;SPALTENWAHL(xA;2;5;1;8;9;10;11;12);xC;FILTER(xB;INDEX(xB;;1)=A1);xZs;SORTIEREN(EINDEUTIG(SPALTENWAHL(xC;1;2;3));2;1);mA;--(INDEX(xC;;1)=MTRANS(INDEX(xZs;;1)));mB;--(INDEX(xC;;2)=MTRANS(INDEX(xZs;;2)));mC;--(INDEX(xC;;3)=MTRANS(INDEX(xZs;;3)));mABC;MTRANS(mA*mB*mC);mBC;MTRANS(mB*mC);vA;WENNFEHLER(WERT(INDEX(xC;;4));0);vB;WENNFEHLER(WERT(INDEX(xC;;5));0);vC;WENNFEHLER(WERT(INDEX(xC;;6));0);vD;WENNFEHLER(WERT(INDEX(xC;;7));0);vE;WENNFEHLER(WERT(INDEX(xC;;8));0);sumsA;MMULT(mBC;vA);sumsB;MMULT(mBC;vB);sumsC;MMULT(mBC;vC);sumsD;MMULT(mBC;vD);sumsE;MMULT(mBC;vE);HSTAPELN(xZs;sumsA;sumsB;sumsC;sumsD;sumsE))

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

28.11.2025 13:19:28

Frag Herber

Hallo Uwe

Deine Formeln funktionieren tiptop. Habe die Let() eingefügt. Danke dafür! Mittlerweile habe ich die Tabelle mit meinen Kollegen angeschaut und wir hätten dazu noch ein, zwei Fragen bzw. Bitten.

Wir hätten vor dem Objekt gerne noch zwei Spalten eingefügt und die Arbeitsleistungen sind eine Zeile nach unten gerutscht. Wäre es möglich das Ganze auf die neuen Gegebenheiten anzupassen? Entschuldige die Umstände. Aber von der Let() habe ich keine Ahnung. Muss mich da mal reinfuchsen. Aber nicht mehr heute... ;-)

Die geänderte Beispieldatei. https://www.herber.de/bbs/user/179744.xlsx

Weiter ist im Blatt Arbeiten in den Zellen D7 und D8 eine Eintragung von Dir. Werden diese benötigt? Ansonsten hätte ich dort gerne noch zwei, drei Objekte erfasst. Mehr als fünf werden es aber sicher nicht.

Und dann noch dies. Gestern hast Du mir die Let() für die Sortierung nach Arbeitsleistung und nach Datum gegeben. Wäre es möglich einen Rapport für die Sortierung nach Arbeit und einen für die Sortierung nach Datum zu machen.

Ich hoffe, dass Du uns nochmals helfen kannst. Das wäre super!

Beste Grüsse

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

28.11.2025 13:43:23

Alwin Weisangler

Hallo,

das kannst du im Formelteil SPALTENWAHL(xA;2;5;1;8;9;10;11;12) ändern in SPALTENWAHL(xA;3;7;1;10;11;12;13;14). Das Blatt "System" hatte ich vergessen aufzuräumen.
Da brauchs nur in Zelle A2 diese Formel für das Dropdown:


=SORTIEREN(EINDEUTIG(FILTER(Arbeiten!C13:C10000;Arbeiten!C13:C10000>"");FALSCH);;1)

https://www.herber.de/bbs/user/179745.xlsx

Gruß Uwe

AW: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

28.11.2025 17:10:09

Frag Herber

Hallo Uwe

Jetzt passt es super! Nochmals vielen Dank für deine prompte und vor allem sehr kompetente Mithilfe. Jetzt werden wir damit arbeiten und dann sehen wir, ob ich mich nochmals für Anpassungen melden muss.

Ich wünsche Dir ein schönes Wochenende.

Beste Grüsse

Zusammenzug von Arbeitsleistungen nach Datum und "Code"

Forumthread: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

17
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Zusammenzug von Arbeitsleistungen nach Datum und "Code"

Forumthread: Zusammenzug von Arbeitsleistungen nach Datum und "Code"

17 Beiträge zum Forumthread Beiträge zu diesem Forumthread

17
Beiträge zum Forumthread

Beiträge zu diesem Forumthread