Tagesanwesenheit

Forumthread: Tagesanwesenheit

Tagesanwesenheit

27.11.2025 11:51:30

Frank I.

Moin Gemeinde, ich bin auf der Suche nach Lösungen über dieses Forum gestolpert.
Nach Bemühen der Forumssuche bin ich leider nicht so ganz fündig geworden. Einige hatte schon eine ähnliche Herausforderung, passt aber nicht so ganz zu meiner. Zumindest was ich gefunden hatte.
Zu meiner Herausforderung:
Ich bin dabei eine Anwesenheitsliste neu zu erstellen nachdem die alte im Nirvana verschwunden ist und der Ersteller nicht mehr vorhanden bzw. greifbar ist.
Die Liste (1 Monat je Registerblatt) soll die die Anzahl von 3 verschiedenen Gruppen (Je Gruppe bis zu 13 verschiedene Angaben) Tagesaktuell anzeigen.
Die mögliche Kennzeichnung von "ist da und zählen" beträgt 15 Möglichkeiten. Bitte nicht fragen warum, ist so.
Im Bereich I$11:AM$11 ist der Monat als einzelne Tage aufgeführt und wird mit der Formel =DATUM($A$5;1;1) ermittelt. Zelle $A$5 enthält das entsprechende Jahr.
Im Bereich I$I$13:$AM$67 werden die jeweilige Kennzeichnung eingetragen.
Die Unterscheidung zu welcher Gruppe wer gehört (bis zu 13 verschiedene Angaben) wird im Bereich $A13:$A67 festgelegt.
Die Anwesenheit soll in den Zellen C11, D11 und E11 Tagesaktuelle angezeigt werden.

Soweit mir bekannt ist geht dieses aufgrund der vielen Unterscheidungen (je Gruppe und wann gezählt werden soll) mit einer Formel nicht möglich.
Mit VBA stehe ich auf Kriegsfuß.

Kann mir da jemand helfen???

Gruß

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tagesanwesenheit

27.11.2025 11:59:07

SF
AW: Tagesanwesenheit

27.11.2025 11:59:25

MCO
AW: Tagesanwesenheit

27.11.2025 14:52:36

Frank I.
AW: Tagesanwesenheit

27.11.2025 14:26:52

Frank I.
AW: Tagesanwesenheit

28.11.2025 03:09:27

xlKing
AW: Tagesanwesenheit

28.11.2025 10:31:24

schauan
AW: ... jupp, so ist es ;-) ...

30.11.2025 20:47:18

schauan
Nach meinem Verständnis...

28.11.2025 18:55:25

xlKing
AW: Nach meinem Verständnis...

28.11.2025 20:53:06

Frank I.
AW: Tagesanwesenheit

27.11.2025 18:48:14

schauan

AW: Tagesanwesenheit

27.11.2025 11:59:07

Hola,

Die Liste (1 Monat je Registerblatt)

Schon mal ein schlechter Start.
Alle Daten werden auf einem Blatt erfasst und auf einem anderen Blatt ausgewertet.
Zu Rest kann man nicht viel sagen weil man erst etwas nachbauen müsste was schon existiert. Und dann weiß man nicht was du genau in C11, D11, E11 ausgegeben haben möchtest.
Eine Beispieldatei mit Wunschergebnis wäre hilfreich.
Gruß,
steve1da

AW: Tagesanwesenheit

27.11.2025 11:59:25

MCO

Moin!
Wäre ja schön, wenn du uns ein Muster deiner Tabelle (verfremdet) zur Verfügung stellen würdest. Bei mir jedenfalls wäre das Verständnis größer.

Wenn eine Formel nicht genügt, setze 2 hintereinander: zb. =Wenn(1;"a";"")&Wenn(2;"b";"")&Wenn(3;"c";"")&Wenn(4;"d";"") usw.
Ich warte jetzt erstmal ab, wie deine Tabelle aussieht.

Gruß, MCO

AW: Tagesanwesenheit

27.11.2025 14:52:36

Frank I.

Danke für die Antwort

AW: Tagesanwesenheit

27.11.2025 14:26:52

Frank I.

Danke für die schnellen Antworten.

Auf die Idee mit einer Beispieldatei hätte ich auch selbst kommen können. Hiermit erledigt.
Hoffe es ist jetzt verständlicher.
https://www.herber.de/bbs/user/179732.xlsx

Meine Hauptsächliche Schwierigkeit / Blockade habe ich dabei, wie sage ich meinem Excelchen das er heute die Spalte 27.11. und morgen die Spalte 28.11. auszählen soll.

Danke im voraus

AW: Tagesanwesenheit

28.11.2025 03:09:27

xlKing

Hi,

wenn ich dich richtig verstehe willst du nur eingetragene Texte aber keine Zahlen zählen. Außerdem soll das Gruppenweise nach Tag erfolgen. Basierend auf der Vorarbeit von Schauan, würde ich daher diese Formel empfehlen.

=WENNFEHLER(ZÄHLENWENNS(INDEX($I$13:$AM$27;;VERGLEICH($A$1;$I$11:$AM$11;0));"*";$F$13:$F$27;"A");0)

Einfach hinten das Gruppen-A mit B, C oder D austauschen, wobei du für B+C zwei dieser Formeln addieren musst.

Gruß Mr. K.

AW: Tagesanwesenheit

28.11.2025 10:31:24

schauan

... oder, anhand meiner Vorarbeit kürzer

=ZÄHLENWENN(INDEX($I$13:$AM$27;;TAG(HEUTE()));"A")

=SUMME(ZÄHLENWENN(INDEX($I$13:$AM$27;;TAG(HEUTE()));{"B"."C"}))

=ZÄHLENWENN(INDEX($I$13:$AM$27;;TAG(HEUTE()));"D")

;-)

Anmerkung: TAG(HEUTE()) erzeugt natürlich nur auf der Übersicht des aktuellen Monats korrekte Ergebnisse, deswegen das "Vielleicht" in meiner vorherigen Antwort.
Schaut man in andere Monate als den aktuellen, passt das nicht. Da ist der VERGLEICH zuweilen die sichere Methode (hier auch nicht). Das gilt vor allem für Listen, die mehr als einen Monat darstellen.

So, wie das Blatt aufgebaut ist, gilt das immer für den aktuellen Monat. In A1 steht =HEUTE() und die Daten in Zeile 11 werden daraus ermittelt ;-) Da sollte man also im Dezember nicht mehr rein schauen :-( Da bekommt man am 27.12. die Daten vom 27.11. weil ja auch in Zeile 11 das Datum mit "wächst"
Ich würde in dem Fall besser in einer Zelle den Monat fest definieren, für den dieses Blatt gültig ist - hier 11 - und in I11 dann aus Jahr - steht in A5 - , Monat und 1 den 1.11. zusammensetzen.

Einfach(er) wäre vielleicht auch die Nutzung der Zeilen 5-8 über dem Datum zum zählen ... Im Prinzip sieht man das in meiner verlinkten Tabelle. Die tägliche Anwesenheit habe ich da auch am jeweiligen Tag zusammengezählt, was das Jahr betrifft dann bei den Namen.

Für die Liste des TE würde ich also z.B. in A13 die A, B+C und D von Müller im Monat zählen, in I5:I8 denn entsprechend für alle MA am 01.11. Ob man sich die Daten dann nochmal nach C11 usw. holt, sei dahingestellt. Auf jeden Fall bräuchte man nicht mehr so zählen ;-) Falls da schon was anderes steht, könnte man das vielleicht auch unter der Liste anbringen, also im Beispiel ab Zeile 28

AW: ... jupp, so ist es ;-) ...

30.11.2025 20:47:18

schauan

Also, unter Berücksichtigung der zu zählenden Parameter aus Tabelle 2 wären die Formeln dann so:

=SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;TAG(HEUTE()));Tabelle2!$B$2:$B$17;$F$13:$F$27;"A"))
=SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;TAG(HEUTE()));Tabelle2!$B$2:$B$17;$F$13:$F$27;{"B"."C"}))
=SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;TAG(HEUTE()));Tabelle2!$B$2:$B$17;$F$13:$F$27;"D"))

... und den TAG(HEUTE()) durch VERGLEICH($A$1;$I$11:$AM$11;0)) ersetzen und den WENNFEHLER nutzen wenn das Datum in A1 nicht passend zu den Daten ist ;-)

=WENNFEHLER(SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;VERGLEICH($A$1;$I$11:$AM$11;0));Tabelle2!$B$2:$B$17;$F$13:$F$27;"A"));0)
=WENNFEHLER(SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;VERGLEICH($A$1;$I$11:$AM$11;0));Tabelle2!$B$2:$B$17;$F$13:$F$27;{"B"."C"}));0)
=WENNFEHLER(SUMME(ZÄHLENWENNS(INDEX($I$13:$AM$27;;VERGLEICH($A$1;$I$11:$AM$11;0));Tabelle2!$B$2:$B$17;$F$13:$F$27;"D"));0)

Nach meinem Verständnis...

28.11.2025 18:55:25

xlKing

...sollen nicht die A's des Tages sondern alle Buchstabenkombinationen des Tages, gefiltert nach Gruppe gezählt werden (siehe Blatt2) sowie in Blatt1 die Zellen C12:E12. die den entsprechenden Gruppeneinträgen in Spalte F zugeordnet sind. Damit gibt die von dir gezeigte kürzere Formel ein falsches Ergebnis aus. Deshalb nahm ich Zählenwenns. Um am 27.12 einen Blick in den November zu werfen zu können und sich dabei nicht von falschen Ergebnissen ablenken zu lassen, habe ich hier WennFehler und Vergleich zu Hilfe genommen.

Vielleicht denke ich aber auch zu kompliziert. Sollte meine Formeln nicht das gewünschte Ergebnis erzielen, dann sollte Frank bitte nochmal einen Erläuterungsversuch der Tabelle starten. Diese ist aus meiner Sicht ziemlich unübersichtlich aufgebaut.

Gruß Mr. K.

AW: Nach meinem Verständnis...

28.11.2025 20:53:06

Frank I.

Ich danke allen für Ihre Beiträge, Hilfe und Gedanken.
Ich werde mich mit allem näher Beschäftigen, darf aber in Kürze ins Krankenhaus.
Sollte ich keine Rückmeldung in Kürze geben liegt dieses daran und bitte um Verständnis.

Ich werde mich auch nochmal hinsetzen und versuchen mein Problem besser zu beschreiben.
Danke und allen ein schönes Wochenende.

AW: Tagesanwesenheit

27.11.2025 18:48:14

schauan

Hallöchen,

hier mal ein Link zu einem Kalender auf einem Blatt.
https://www.clever-excel-forum.de/Thread-Kalender-Planung-An-Abwesenheit?pid=257234#pid257234

Für Deine Gruppen kannst Du ja die Namen entsprechend in den Spalten K:AJ "sortieren". Bei Anwesenheit eines MA trägst Du zum jeweiligen Datum einfach nur I ein Daneben, z.B. in BL usw, zählst Du dann die Gruppen aus, also z.B. Gruppe 1 K11:O11, Gruppe 2 P11:Z11, Gruppe 3 AA11:AJ11
Man kann das natürlich erweitern, ich habe da vorerst nur 26 MA drin.

Soweit mir bekannt ist geht dieses aufgrund der vielen Unterscheidungen (je Gruppe und wann gezählt werden soll) mit einer Formel nicht möglich.
Du glaubst nicht, was alles möglich ist.
In die wievielte Spalte man muss, bekommt man z.B. über das Datum raus. Datum beruht auf Ganzzahlen.

Rechenprinzip:
Bezug über ein festes Datum - hier der 1. des Monats
Heute (27.11.1025) - 1.11.2025 = 26
Gestern (26.11.1025) - 1.11.2025 = 25
usw.
Vielleicht geht auch =TAG(heute()) - schaue mal unten das mit dem INDEX an
Du musst bei der Rechnung noch 1 addieren, damit Du an der richtigen Stelle raus kommst.

Deine Daten beginnen in Spalte I = 9
Der 27.11. ist dann in Spalte 9 + 26 = 35 bzw. AI
Anmerkung: Man kann natürlich auch per Formel den 27.11. suchen.

Ob man nun die 35 braucht oder die 27, sei mal dahingestellt.

In einer Tabelle kann man sich mit INDEX bewegen. Wenn Du nun was heute aus Zeile 13 benötigst, wäre das im Prinzip

=INDEX(I13:AM27;1;27) - die 27 musst Du natürlich irgendwie ausrechnen

wenn Du in Spalte I anfängst, oder

=INDEX(A13:AM27;1;35)

wenn Du in Spalte A anfängst. Auch hier wieder - die 35 wäre auszurechnen.

usw.

Man kann mit INDEX auch statt dem Inhalt eine Zelle oder einen Bereich zurückgeben.

=ZÄHLENWENN(INDEX(I13:AM27;;27);"A")

ud bekommst damit für die A heute 4

usw.

Forumthread: Tagesanwesenheit

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread