Tabelle Drucken und Speichern, aber...

Forumthread: Tabelle Drucken und Speichern, aber...

Thomas

Hallo,
ich hab ein problem habe auch fast was gefunden aber doch nicht ganz. Suche eine Lösung (Makro), das mir nach dem ich Tabelle XY gedruckt habe eine MsgBox angezeigt wird und frägt ob ich diese Tabelle Speichern möchte (ja/nein). Aber diese Tabelle XY soll auf "C:\XY\XY\.... unter folgendem Namen als PDF gespeichert werden. Name(Zelle L6)_Datum_Zeit_PDF. Die PDF soll mir dann auch angezeigt werden. Das mit der laufenden Nummer hab ich verworfen, sollte ich einen Fehler bei meiner Abrechnung gemacht haben so hab ich Lücken wenn ich die PDF-Datei nachträglich lösche bei der Uhrzeit ist das egal.
Danke schonmal im vorraus
Gruß Thomas

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Tabelle Drucken und Speichern, aber...

22.10.2009 06:47:33

fcs

Hallo Thomas,
unter Excel 2007 kannst du bei Installation aller Programmkomponenten PDF-Dateien direkt exportieren.
Dann kannst du z.B. die folgende noch etwas anzupassende Lösung verwenden.
Falls du die PDF-Dateien per PDF-Drucker erzeugst, dann muss du dich noch schlau machen, wie du den Dateinamen als Paramter von Excel aus an dein PDF-Programm übergen kannst.
Gruß
Franz

'Diese Prozeduren im VBA-Editor unter "DieseArbeitmappe" einfügen
'Erstellt unter Excel 2007, Windows Vista
Sub SpeichernPDF_Export()
'Aktives Blatt ggf. als PDF-Datei speichern und anzeigen
If MsgBox(Prompt:="Aktives Blatt als PDF-Datei exportieren?", _
Buttons:=vbQuestion + vbYesNo, Title:="PDF-Datei erstellen") = vbYes Then
'Pfad für PDF-Dokumente anpassen  !!!
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="C:\Users\Public\Test\" & ActiveSheet.Range("L6").Text _
& Format(Now, "YYYYMMDD hhmmss") & "PDF.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=False, _
IgnorePrintAreas:=False, OpenAfterPublish:=True
End If
End Sub
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim Auswahl As Long
Select Case ActiveSheet.Name
Case "TabelleXYZ", "BlattABC"
'Liste der Blätter die "normal" gedruckt werden sollen
Case Else
Cancel = True 'Dadurch wird der Standard-Ausdruck abgebrochen
Application.EnableEvents = False
Auswahl = MsgBox(Prompt:="Aktives Blatt drucken (Ja), Vorschau (Nein) oder Abbrechen?", _
Buttons:=vbQuestion + vbYesNoCancel, Title:="Blatt drucken")
Select Case Auswahl
Case vbYes
ActiveSheet.PrintOut
Call SpeichernPDF_Export
Case vbNo
ActiveSheet.PrintPreview
Case vbCancel
End Select
Application.EnableEvents = True
End Select
End Sub

AW: Tabelle Drucken und Speichern, aber...

22.10.2009 19:44:54

Thomas

Hallo fcs,
dein Beitrag vom 14.10. hat mir keine Ruhe gelassen, da das der Ansatz für mein weiter kommen war. Mit anpassen bin ich auch nicht ans Ziel gekommen da mir auch das wissen fehlt (anfänger).
Dein jetziger Code funktioniert fast wenn er nicht das Blatt wechseln würde und somit das falsche Tabellenblatt als PDF mir speichert. Folgendes, mit diesem Code Drucke ich mein aktives Tabellenblatt (Abr.) und ein weiteres mit Wasserzeichen (Kopie).

Private Sub CommandButton5_Click()
Dim ArrDruck() As String
Dim i As Integer
ArrDruck = Split("Abr.,Kopie", ",")
For i = 0 To UBound(ArrDruck)
ThisWorkbook.Sheets(ArrDruck(i)).PrintOut copies:=1
Next
End Sub

Nach dem Druck auf den CommandButten soll nun die MsgBox erscheinen und Fragen ob ich das aktive Blatt ( Abr.) als PDF speichern möchte. Die ganze Mappe Speicher ich beim Schließen.
Der Grund warum das Tabellenblatt gewechselt wird liegt wohl darin das ich die Abr. und Die Kopie Drucke?
Danke für die schnelle Antwort.
Gruß Thomas

AW: Tabelle Drucken und Speichern, aber...

23.10.2009 05:24:14

fcs

Hallo Thomas,
wenn du den Druck der Blätter per Button startest, dann kann man die PDF-Ausgabe auch direkt in die Prozedur des Buttons einbauen und die Workbook_BeforePrint-Prozedur unter DieseArbeitsmappe weglassen.
Aus irgendeinem Grunde hat die Workbook_BeforePrint-Ereignis-Prozedur hier ein Problem mit dem Status des aktiven Blattes. Selbst das explizite Aktivieren des Blattes in der Button-Prozedur hat nicht geholfen.
Gruß
Franz

Private Sub CommandButton5_Click()
Dim ArrDruck() As String
Dim i As Integer
ArrDruck = Split("Abr.,Kopie", ",")
For i = 0 To UBound(ArrDruck)
With ThisWorkbook.Sheets(ArrDruck(i))
.PrintOut copies:=1
If .Name = "Abr." Then
'Blatt ggf. als PDF-Datei speichern und anzeigen
If MsgBox(Prompt:="Blatt """ & .Name & """ als PDF-Datei exportieren?", _
Buttons:=vbQuestion + vbYesNo, Title:="PDF-Datei erstellen") = vbYes Then
.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="C:\Users\Public\Test\" & ActiveSheet.Range("L6").Text _
& Format(Now, "YYYYMMDD hhmmss") & "PDF.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=False, _
IgnorePrintAreas:=False, OpenAfterPublish:=True
End If
End If
End With
Next
End Sub

AW: Tabelle Drucken und Speichern, aber...

23.10.2009 17:49:19

Thomas

Hallo fcs,
es geht nun zeigt mir zwar noch immer kurz die Tabelle(Kopie) aber zeigt und speichert mir das aktuelle Tabellenblatt(Abr.) super und ein großes Danke. Ich hab das mit dem Datum und Zeit zum besseren lesen mit Bindestrich angepasst aber wenn ich zwischen L6 und Text einen einfüge gehts schon nichts mehr.
ActiveSheet.Range("L6").Text _
& Format(Now, "YYYY-MM-DD hh-mm-ss") & " PDF.pdf", _
Gibt es da eine möglichkeit und wenn wo?
Mit freundlichen Grüßen Thomas

AW: Tabelle Drucken und Speichern, aber...

24.10.2009 13:19:40

fcs

Hallo Thomas,
"L6" ist eine Zelladresse, da kannst du nicht einfach so etwas "dazu basteln". Den zusätzlichen Bindestrich muss du als zusätlichen Textschnipsel einbauen, oder am Anfang des Datumsformates.

ActiveSheet.Range("L6").Text _
& "-" & Format(Now, "YYYY-MM-DD hh-mm-ss") & "PDF.pdf"
'oder
ActiveSheet.Range("L6").Text _
& Format(Now, "-YYYY-MM-DD hh-mm-ss") & "PDF.pdf"

Das flackern der Anzeige kannst du etwas reduzieren, indem du vor For-Next-Schleife die Bildschirmaktualisierung deaktivierst und danach wieder aktivierst.

  Application.ScreenUpdating = False
For i = 0 To UBound(ArrDruck)
Next
Application.ScreenUpdating = True

Es wird aber immer noch zwischen dem Druck der einzelnen Blätter der Drucken-Hinweis angezeigt.
Gruß
Franz

AW: Tabelle Drucken und Speichern, aber...

24.10.2009 14:09:40

Thomas

Hallo fcs,
auf den Bindestrich vor der Jahreszahl hätte ich selber drauf kommen können/ müssen. Nun hab ich nur noch halb soviel Arbeit. Noch mal ein dankeschön an dich.
Kann mich nun an die Arbeit machen und mein Programm neu schreiben und gestallten weil es durch Verbesserungen etwas an übersichtlichkeit verloren hat. Eine weitere Baustelle hab ich aber auch schon gefunden das ganze noch schneller zu erledigen das mit dem Drucken und Speichern aber erst mal neu machen ist angesagt.
Wünsch dir ein schönes Wochenende.
Gruß Thomas

Beliebteste Forumthreads (12 Monate)

Tabelle Drucken und Speichern, aber...

Forumthread: Tabelle Drucken und Speichern, aber...

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Tabelle Drucken und Speichern, aber...

Forumthread: Tabelle Drucken und Speichern, aber...

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread