Method 'SeriesCollection' of object 'Chart' failed

Forumthread: Method 'SeriesCollection' of object 'Chart' failed

André

Hallo zusammen,
der "Method 'SeriesCollection' of object '_Chart' failed" Fehler tritt in folgender Zeile auf, wenn ich für Anfang = InputBox einen Wert größer 2 wähle.

ActiveChart.SeriesCollection(i).Values = "=(Tabelle1!R" & i & "C13,Tabelle1!R" & i & "C15,Tabelle1!R" & i & "C17,Tabelle1!R" & i & "C19,Tabelle1!R" & i & "C21)"

Wie könnte ich das sauber beheben? Bisher lösche ich abhängig vom Anfangs-Input die nicht benötigten Zeilen weg, so dass der Anfang immer bei 1 liegt. Ist aber eine sehr unschöne Lösung, vor allem, wenn man das Skript mehrmals hintereinander ausführen möchte.

Rows(1 & ":" & 1000).Copy Worksheets("Tabelle2").Rows(1 & ":" & 1000)
For AnAnfangSchieben = 1 To Anfang - 1
Rows(1).Delete Shift:=xlUp
Next

Hat jemand einen Tipp, wie ich den Fehler sinnvoller umgehen könnte?
Grüße,
André


Sub createchart()
Dim Ende As Integer
Dim i As Integer
Dim Anfang As Integer
Worksheets("Tabelle1").Activate
Anfang = InputBox("Ab welcher Zeile soll die Auswertung beginnen?", "Zahl eingeben")
Ende = InputBox("Letzte auszuwertende Zeile?", "Zahl eingeben")
Charts.Add
ActiveChart.ChartType = xlLineMarkers
For i = Anfang To Ende
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(i).Values = "=(Tabelle1!R" & i & "C13,Tabelle1!R" & i & "C15, _
Tabelle1!R" & i & "C17,Tabelle1!R" & i & "C19,Tabelle1!R" & i & "C21)"
ActiveChart.SeriesCollection(i).Name = "=Tabelle1!R" & i & "C1"
Next i
ActiveChart.Location Where:=xlLocationAsObject, Name:="Tabelle1"
With ActiveChart
.HasTitle = True
.ChartTitle.Characters.Text = "Reinraumpartikel"
.Axes(xlCategory, xlPrimary).HasTitle = True
.Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "Partikelgröße"
.Axes(xlValue, xlPrimary).HasTitle = True
.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Anzahl"
End With
End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Method 'SeriesCollection' of object 'Chart' failed

05.07.2010 18:27:04

Beverly

Hi André,
kann es sein, dass die Zellen, aus denen du die Datenreihe erstellen willst, keine Werte enthalten? Ansonsten wäre es hilfreich, wenn du die Mappe hochladen würdest.

AW: Method 'SeriesCollection' of object 'Chart' failed

06.07.2010 09:43:38

André

Hallo Karin,
ich glaube nicht, dass es an leeren Zellen liegt, da von Zeile 2 bis X das Diagramm erstellt wird, von Zeile größer 2 bis X allerdings der Fehler auftritt.
Habe Dir die Mappe hochgeladen, danke schonmal!
https://www.herber.de/bbs/user/70450.xls
Gruß,
André

AW: Method 'SeriesCollection' of object 'Chart' failed

06.07.2010 10:22:05

Beverly

Hi André,
deine Schleife war falsch - die Datenreihenzählung beginnt immer mit 1, wenn nun aber a = 10 (z.B.), würde die Schleife mit 10 beginnen, was folglich zu dem Fehler führt.

Sub TestHolger()
Dim chrDiagramm As Chart
Dim c As Integer
Dim i As Integer
Dim a As Integer
With Worksheets("Tabelle1")
a = InputBox("Ab welcher Zeile soll die Auswertung beginnen?", "Zahl eingeben")
c = InputBox("Letzte auszuwertende Zeile?", "Zahl eingeben")
Set chrDiagramm = .ChartObjects.Add(50, 50, 400, 230).Chart
With chrDiagramm
.ChartType = xlLineMarkers
For i = 1 To c - a + 1
.SeriesCollection.NewSeries
.SeriesCollection(i).Values = "=(Tabelle1!R" & i + a - 1 & "C13,Tabelle1!R" & i  _
+ a - 1 & "C15,Tabelle1!R" & i + a - 1 & "C17,Tabelle1!R" & i + a - 1 & "C19,Tabelle1!R" & i + a - 1 & "C21)"
.SeriesCollection(i).Name = "=Tabelle1!R" & i + a - 1 & "C1"
Next i
.HasTitle = True
.ChartTitle.Characters.Text = "Reinraumpartikel"
.Axes(xlCategory, xlPrimary).HasTitle = True
.Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "Partikelgröße"
.Axes(xlValue, xlPrimary).HasTitle = True
.Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Anzahl"
End With
End With
Set chrDiagramm = Nothing
End Sub

AW: Method 'SeriesCollection' of object 'Chart' failed

06.07.2010 10:58:44

André

Hi Karin,
aah ja, sehr einleuchtend. Vielen Dank, das wird mir in Zukunft so Einiges erleichtern.
Beste Grüße,
André

Beliebteste Forumthreads (12 Monate)

Method 'SeriesCollection' of object 'Chart' failed

Forumthread: Method 'SeriesCollection' of object 'Chart' failed

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread