Werte über VBA auslesen

Forumthread: Werte über VBA auslesen

Burkhard

Hallo,
ich habe hier vor kurzem schon einmal eine Super Hilfe bekommen, kann ich garnicht genug für danken!!!
Nun ist es aber leider schon wieder soweit, da sich meine Vba kenntnisse leider nicht verbessert haben, benötige ich schon wieder eure Hilfe!!!!
Es ist wieder ein ähnliches Problem.
Ich möchte eine Datei erstellen, in der ich die Monatlichen Kosten aus anderen Dateien auslese und auswerte.
Die auszulesenden Dateien sind alle gleich aufgebaut und der Name ist bis auf den Monat auch gleich.
Beide Dateien (Auslese&Zieldatei) habe ich mal angehängt, sowie den Speicherpfad
Die werte die ich auslesen möchte, stehen im Arbeitsblatt "Kosten Gesamt"
Das Arbeitsblatt für die Auswertung hat den Namen "Auswertung WKZkosten Jahr"
Wichtig, beides sollen eigenständige dateien sein.
Auch der Speicherort ist unterschiedlich.
https://www.herber.de/bbs/user/71963.xls
In der Datei ist schon ein Makro, dies ist aus der alten Aktion, aber dieses war so gut geschrieben, das ich es nicht anpassen konnte!
Hoffe konnte mein Problem schon mal gut schildern, bis denne!!
Grüße Burkhard

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Werte über VBA auslesen - Zusatzfragen

19.10.2010 06:50:50

fcs

Hallo Burkhard,
1. Die Inhalte welcher Zellen willst du denn in die Jahresübersicht übernehmen bzw. welche Berechnungsformeln sollen angewendet werden, um die Monatswerte zu berechnen?
Beachte hierbei, dass Werkzeug- und Fremdkosten in den Summenzeilen 34 bis 38 schon zusammengefasst sind. Also für deine gewünschte Auswertung in der Jahresübersicht immer neu berechnet werden müssten.
2. Haben alle 12 Monate, also auch die mit weniger als 31 Tagen die gleiche Anzahl Zeilen im Blatt Kosten gesamt?
D.h., die Summenwerte stehen immer in den Zeilen 34 bis 38
Gruß
Franz

AW: Werte über VBA auslesen - Zusatzfragen

19.10.2010 16:36:59

Burkhard

Hallo Franz,
das stimmt, es würde vollkommen ausreichen, wenn ich die Summe aus C34 in Zeile 10 (Werkzeugkosten) einlese und die Summen aus E34 & F34 jeweils zu den Kosten für Elektriker und Schlosser einlese.
Das würde bedeuten, das die Zeile für Fremdleistung enfallen kann.
Ich habe nachgeschaut, die Gesamtsummen aus den Monaten stehen immer in Zeile34.
Grüße Burkhard

AW: Werte über VBA auslesen - Zusatzfragen

20.10.2010 03:56:24

fcs

Hallo Burkhard,
hier das angepasste Makro zum Erzeugen der entsprechenden Formeln.
Gruß
Franz

Option Explicit
'Verzeichnis der Dateien
Private Const cstrPath As String = _
"C:\Dokumente und Einstellungen\Burkhard Held\Eigene Dateien\Werkzeugkosten"
'Private Const cstrPath As String = _
"C:\Users\Public\Test\Werkzeugkosten"
'Tabelle mit Daten
Private Const cstrSheet As String = "Kosten Gesamt"
Private Sub CommandButton1_Click()
Dim strFormula As String, strFile As String, strPath As String, lngMon As Long
Dim strFormel1 As String
On Error GoTo ErrExit
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
End With
strPath = IIf(Right(cstrPath, 1) = "\", cstrPath, cstrPath & "\")
With Sheets("Auswertung WKZkosten Jahr")
'Alte Werte im Ausgabebereich löschen
.Range(.Cells(10, 2), .Cells(13, 13)).ClearContents
For lngMon = 1 To 12
'Prüfen, ob Monatsdatei im Verzeichnis vorhanden, Suchstring "*_Mon_" und _
Zahlenformat der Monatszahl (wenn immer mit 2 Ziffern) ggf. anpassen
strFile = Dir(strPath & "*_Mon_" & Format(lngMon, "0") & ".xls*", vbNormal)
If strFile  "" Then
'Formelteil mit Verzeichnis, Dateiname und Blattname
'Verdopplung der Hochkommata im Dateinamen in der Formel erforderlich!!
strFormel1 = "'" & strPath & "[" & Replace(strFile, "'", "''") & "]" & cstrSheet & "'!"
'Formeln für einzelne Zellen berechnen und in Blatt eintragen
strFormula = "=SUM(" & strFormel1 & "$C$3:$C$33)"
.Cells(10, lngMon + 1).Formula = strFormula
strFormula = "=SUM(" & strFormel1 & "$D$3:$D$33)"
.Cells(11, lngMon + 1).Formula = strFormula
strFormula = "=" & strFormel1 & "$E$34"
.Cells(12, lngMon + 1).Formula = strFormula
strFormula = "=" & strFormel1 & "$F$34"
.Cells(13, lngMon + 1).Formula = strFormula
End If
Next
.Calculate
'erstellte Formeln durch Werte Ersetzen
.Range(.Cells(10, 2), .Cells(13, 13)).Value = .Range(.Cells(10, 2), .Cells(13, 13)).Value
End With
ErrExit:
With Application
If Err.Number  0 Then
MsgBox "Fehler-Nr.: " & Err.Number & vbLf & Err.Description
End If
.ScreenUpdating = True
.Calculation = xlCalculationAutomatic
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Forumthread: Werte über VBA auslesen

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Werte über VBA auslesen

Forumthread: Werte über VBA auslesen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread