Zurück aus der Detailanzeige von Pivottabellen

Forumthread: Zurück aus der Detailanzeige von Pivottabellen

Pivottabellen

Hallo,
Pivottabellen haben die angenehme Eigenschaft, dass beim Doppelklick auf eine Zahl ein Neues Registerblatt erstellt wird, in welchem die Detaildaten zu sehen sind.
Ich möchte gern diese Detailblatt gestalten, dh. ein Überschrift einfügen und einen "Ansicht verlassen" Button, da viele User meine Pivottabellen erst mal nicht wissen, wie sie jetzt wieder zurück kommen.
Eigentlich würde ich den Code dafür ja in Worksheet_Activate unterbringen. Ich habe eine keine Idee, wie ich das im neu erstellten Blatt unterbringen könnte.
- Es gibt es ja zunächst noch nicht
- ich kenne ja nicht den Namen den es erhalten wird
Hat jemand eine Idee wie man es lösen könnte ?
Viele Grüße,
GTFuchs

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Benutzer

AW: Zurück aus der Detailanzeige von Pivottabellen

Pivottabellen

AW: Zurück aus der Detailanzeige von Pivottabellen

09.11.2010 01:54:52

Pivottabellen

Hallo GTFuchs,
das funktioniert mit den folgenden drei Makros, die du in den entsprechenden Modulen einfügen und ggf. anpassen muss.
Gruß
Franz

'Modul: DieseArbeitsmappe
Option Explicit
Private Sub Workbook_NewSheet(ByVal Sh As Object)
Dim oShape As Shape
With Sh
If .UsedRange.Rows.Count > 1 Then
'2 neue Zeilen einfügen vor Zeile 1
.Rows(1).Insert
.Rows(1).Insert
With .Cells(1, 1)
.Value = "Neue Überschrift"
.Font.Size = 14
End With
'Schaltfläche einfügen in Zelle D1
With .Cells(1, 4)
Sh.Buttons.Add .Left, .Top, 140, 20.25
End With
Set oShape = .Shapes(.Shapes.Count)
'Schaltfläche bearbeiten
With oShape
.OnAction = "ZurueckZuPivot" 'Name des Makros
.TextFrame.Characters.Text = "zurück zu Pivot-Tabelle"
End With
Range("A1").Select
End If
End With
End Sub
Modul: Tabellenmodul der Tabellenblätter mit Pivottabellen
Option Explicit
Private Sub Worksheet_Activate()
LastPivotBlatt = Me.Name
End Sub
'Modul: allgemeines Modul
Option Explicit
Public LastPivotBlatt As String
Public Sub ZurueckZuPivot()
Dim oSheet As Object
Set oSheet = ActiveSheet
Select Case oSheet.Name
Case "Rechnung", "PivotTab", "Tabelle18" 'Name der Tabellen ggf. anpassen/ergänzen
'keine Aktionen, wenn die Tabellen aktiv sind
Case Else
Sheets(LastPivotBlatt).Activate
Application.DisplayAlerts = False
oSheet.Delete 'Diese Zeile ggf. weglassen
Application.DisplayAlerts = True
LastPivotBlatt = ""
End Select
End Sub

Beliebteste Forumthreads (12 Monate)

Zurück aus der Detailanzeige von Pivottabellen

Forumthread: Zurück aus der Detailanzeige von Pivottabellen

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread