aus CSV-Datei: Zeilen zusammenfassen

Forumthread: aus CSV-Datei: Zeilen zusammenfassen

Sebhe

Hallo in die Runde,
ich generiere jeden Monat eine CSV-Datei auf meiner Webseite.
Sie kann so z.B. aussehen:
Datum;Re-Nr.;Firma;Name;Vorname;Debitor;Erloeskonto;Betrag (Brutto);Text;
010811; 48; ; name1; name1; 11100; 4400; 19,99; name1;
010811; 48; ; name1; name1; 11100; 4400; 14,99; name1;
010811; 48; ; name1; name1; 11100; 4400; 14,99; name1;
010811; 49; ; name2 ; name2 ; 11600; ; 44; name2 ;
010811; 50; ; name3; name3; 10700; ; 42; name3;
010811; 51; ; name4; name4; 11300; 4400; 9,99; name4;
010811; 51; ; name4; name4; 11300; 4400; 24,99; name4;
Nun möchte ich folgendes machen in Excel:
Wenn Re-Nr., Debitor & Erlöskonto gleich
Dann fasse die Zeilen zusammen und addiere den Betrag (Brutto).
Wie kann ich das in Excel umsetzen?
Ich freue mich auf Eure Hilfe!
Danke und viele Grüße
Sebhe

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: aus CSV-Datei: Zeilen zusammenfassen

28.09.2011 16:19:11

Piet

Hallo,
nimm doch eine Pivottabelle!
Gruß
Piet

AW: aus CSV-Datei: Zeilen zusammenfassen

28.09.2011 16:46:17

Tino

Hallo,
wenn Deine Tabelle im Excel so aussieht,
Tabelle1

	A	B	C	D	E	F	G	H	I
1	Datum	Re-Nr.	Firma	Name	Vorname	Debitor	Erloeskonto	Betrag (Brutto)	Text
2	10811	48		name1	name1	11100	4400	19,99	name1
3	10811	48		name1	name1	11100	4400	14,99	name1
4	10811	48		name1	name1	11100	4400	14,99	name1
5	10811	49		name2	name2	11600		44	name2
6	10811	50		name3	name3	10700		42	name3
7	10811	51		name4	name4	11300	4400	9,99	name4
8	10811	51		name4	name4	11300	4400	24,99	name4

kannst mal diesen Code testen. (evtl. noch die Tabelle anpassen)


Sub Makro1()
Dim nMaxRow&, iCalc%
With Application
    iCalc = .Calculation
    .ScreenUpdating = False
    .EnableEvents = False
    .Calculation = xlCalculationManual

    With Sheets("Tabelle1") 'evtl. Tabelle anpassen 
        nMaxRow = .Cells(.Rows.Count, 1).End(xlUp).Row
        If nMaxRow < 2 Then Exit Sub
        
        With .Range("A2", .Cells(nMaxRow, 1)).EntireRow
            'Formel =$B2&"-"&$F2&"-"&$G2 
            .Columns(.Columns.Count - 1).FormulaR1C1 = "=RC2&""-""&RC6&""-""&RC7"
            'Formel =WENN(ZÄHLENWENN(IU2:IU$8;IU2)=1;SUMMEWENN(IU$2:IU$8;IU2;$H$2:$H$8);WAHR) 
            .Columns(.Columns.Count).FormulaR1C1 = _
                "=IF(COUNTIF(RC[-1]:R" & nMaxRow & _
                "C[-1],RC[-1])=1,SUMIF(R2C[-1]:R" & nMaxRow & _
                "C[-1],RC[-1],R2C8:R" & nMaxRow & "C8),TRUE)"
            
            .Columns(8).Value = .Columns(.Columns.Count).Value
            
            On Error Resume Next
            .Columns(.Columns.Count).SpecialCells(xlCellTypeFormulas, 4).EntireRow.Delete
            .Columns(.Columns.Count - 1).Resize(, 2).EntireColumn.Delete
            On Error GoTo 0
        End With
    End With

    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = iCalc
End With
End Sub

Danach sollte die Tabelle so aussehen.
Tabelle1

	A	B	C	D	E	F	G	H	I
1	Datum	Re-Nr.	Firma	Name	Vorname	Debitor	Erloeskonto	Betrag (Brutto)	Text
2	10811	48		name1	name1	11100	4400	49,97	name1
3	10811	49		name2	name2	11600		44	name2
4	10811	50		name3	name3	10700		42	name3
5	10811	51		name4	name4	11300	4400	34,98	name4

Gruß Tino

AW: aus CSV-Datei: Zeilen zusammenfassen

28.09.2011 18:55:45

Sebhe

Vielen Dank. Ich werde es ausprobieren und mich dann bei Euch melden!

Beliebteste Forumthreads (12 Monate)

aus CSV-Datei: Zeilen zusammenfassen

Forumthread: aus CSV-Datei: Zeilen zusammenfassen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread