TEILERGEBNISSE

Forumthread: TEILERGEBNISSE

TEILERGEBNISSE

Walter

Hallo Freunde,
Ich sehe mal wieder den Wald vor lauter Bäumen nicht.
https://www.herber.de/bbs/user/78097.xls
Ich möchte von jedem Monat die Verbrauchsmenge zählen.
Danke schon mal für die HILFE
Gruss
Walter

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Matrix Summe

27.12.2011 09:00:49

hary

Hallo Walter
matrixformel.
Tabelle1

	E	F	G	H	I
3	9,85			Januar	49,25
4	11,2			Februar
5	7,8			März
6	9,2			April
7	11,2			Mai

verwendete Formeln
Zelle	Formel	Bereich
E3	=MITTELWERT(E4:E400)
I3	{=SUMME(WENN(MONAT(A3:A400)=MONAT(H3);E3:E400))}	$I$3
E4	=WENN(D4="";"";D4-D3)
E5	=WENN(D5="";"";D5-D4)
E6	=WENN(D6="";"";D6-D5)
E7	=WENN(D7="";"";D7-D6)

{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 5.30

gruss hary

AW: TEILERGEBNISSE

27.12.2011 09:02:37

Hajo_Zi

Hallo Walter,
schreibe in Spalt H das richtige Jahr nicht 1900.
Tabelle1

	H	I
3	Januar	31

verwendete Formeln
Zelle	Formel	Bereich
I3	=SUMMENPRODUKT((MONAT($A$3:$A$367)=MONAT(H3))*(JAHR($A$3:$A$367)=JAHR(H3)))

Tabellendarstellung in Foren Version 5.47

SUMMENPRODUKT

27.12.2011 09:13:29

Erich

Hi Walter,
der zu summierende Bereich fängt erst in Zeile 4 an.
SUMMENPRODUKT kann nicht mit Zellen rechnen, in denen Text "" steht. Deshalb solltest du die Formel in Spalte E ändern.
Das falsche Jahr in H3 stört überhaupt nicht.
Hier mal als SUMMENPRODUKT- und als Matrixformel:

	D	E	F	G	H	I	J
2	Zähler	Verbrauch
3	8775,2	Ø 0,11			Januar	39,4	39,4
4	8786,4	11,2			Februar	0	0
5	8794,2	7,8			März	0	0
6	8803,4	9,2			April	0	0
7	8814,6	11,2			Mai	0	0
8		0			Juni	0	0
9		0			Juli	0	0

Formeln der Tabelle

Zelle	Formel
E3	=MITTELWERT(E4:E400)
I3	=SUMMENPRODUKT((MONAT(A$4:A$400)=H3)*E$4:E$400)
J3	{=SUMME((MONAT(A$4:A$400)=MONAT(H3))*E$4:E$400)}
E4	=MAX(;D4-D3)
I4	=SUMMENPRODUKT((MONAT(A$4:A$400)=H4)*E$4:E$400)
J4	{=SUMME((MONAT(A$4:A$400)=MONAT(H4))*E$4:E$400)}
E5	=MAX(;D5-D4)

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

noch eine Variante

27.12.2011 09:22:06

Erich

Hi Walter,
hier hängt die Zuordnung zu einem Monat nicht vom unteren, sondern vom oberen Datum ab:

	H	I	J
3	Januar	39,4	39,4
4	Februar	0	0

Formeln der Tabelle

Zelle	Formel
I3	=SUMMENPRODUKT((MONAT(A$3:A$399)=H3)*E$4:E$400)
J3	{=SUMME((MONAT(A$3:A$399)=MONAT(H3))*E$4:E$400)}
I4	=SUMMENPRODUKT((MONAT(A$3:A$399)=H4)*E$4:E$400)
J4	{=SUMME((MONAT(A$3:A$399)=MONAT(H4))*E$4:E$400)}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Der Verbrauch ist ja immer die Differenz zwischen zwei Tagen. Zu welchem der beiden Tage (und damit zu welchem Monat)
gehört dann der Verbrauch? Das ist eine fachliche, keine Excelfrage.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Korrektur und noch eine Variante

27.12.2011 13:02:50

Erich

Hi Walter,
bei meinen SUMMENPRODUKT-Formeln muss natürlich immer MONAT(H3) statt H3 (oder mit H4) stehen.
Hier noch eine Variante, bei der die Texte ("") in Spalte E stehen bleiben können - damit auch der
MITTELWERT in E3 richtig bleibt:

	D	E	F	G	H	I	J
2	Zähler	Verbrauch					oder
3	8775,2	9,85			Januar	39,4	39,4
4	8786,4	11,2			Februar	0	0

Formeln der Tabelle

Zelle	Formel
E3	=MITTELWERT(E4:E400)
I3	{=SUMME((MONAT(A$4:A$368)=MONAT(H3))*WENN(ISTZAHL(E$4:E$368); E$4:E$368))}
J3	{=SUMME((MONAT(A$3:A$367)=MONAT(H3))*WENN(ISTZAHL(E$4:E$368); E$4:E$368))}
E4	=WENN(D4="";"";D4-D3)
I4	{=SUMME((MONAT(A$4:A$368)=MONAT(H4))*WENN(ISTZAHL(E$4:E$368); E$4:E$368))}
J4	{=SUMME((MONAT(A$3:A$367)=MONAT(H4))*WENN(ISTZAHL(E$4:E$368); E$4:E$368))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Korrektur und noch eine Variante

28.12.2011 06:54:00

Walter

Hallo Erich,
Als Rentner hat man Zeit. Ich möchte meinen Stromzähler täglich um 10:00Uhr ablesen, um so ein
Verbrauchsbild über einige Monate zu bekommen.
Spalte A formaiert Datum TT.MM.JJJJ
SPALTE E+F formatiert ZAHL 0,0
Ergebnis mit Deiner Formel in I + J #WERT
IRGENTWO KLEMMT ES NOCH
Gruß
Walter

Matrixformel

28.12.2011 09:17:57

Erich

Hi Walter,
hast du die Formeln richtig als Matrixformeln eingegeben - mit STRG+SHIFT+RETURN - und damit den
Matrixformel-Hinweis befolgt? Tut man das nicht, kommt #WERT! als Wert.
Wenn das nicht das Problem war, poste mal bitte deine Formeln in I3 und J3 genau.
Du könntest auch versuchen, die Formeln mit einem kleineren Bereich (Zeilen 4:20 bzw. 3:19) zu testen.
Wenn alles nicht hilft, solltest du eine kleine Beispielmappe mit dem Fehler hochladen.
Dass du täglich um 10 Uhr abliest, sagt noch nicht, wie du die Verbräuche den Monaten zuordnen willst.
Beispiel: Zählerstand
am 30.11.2011 10:00 ist 3000
am 01.12.2011 10:00 ist 3050
Zu welchem Monat gehören die 50 kWh Verbrauch? November oder Dezember - wenn nicht sogar aufgeteilt?
Danach richtet sich, ob es die Formel in Spalte I oder J sein sollte.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Matrixformel

29.12.2011 02:24:08

Walter

Hallo Erich,
so genau will ich es nicht machen,
https://www.herber.de/bbs/user/78117.xls
Mir geht es um das verstehen der Formeln.
warum #Wert?
Gruß Walter

MONAT(Text) geht nicht

29.12.2011 09:23:09

Erich

Hi Walter,
in Tabelle2 - darauf bezieht sich wohl deine Frage - stehen in A28:A34 Texte.
Die Formel in I2 versucht, daraus die Monate zu berechnen (MONAT(A$3:A$380)). Das knallt natürlich.
Wenn du die Texte in A28:A34 löschst, funzt die Formeln in I2.
In J2 ist noch ein anderer Fehler:
Die Bereiche in der Matrixformel müssel die selbe Größe haben. Deshalb musst du aus
=SUMME((MONAT(A$3:A$379)=MONAT(H2))*WENN(ISTZAHL(E$3:E$380); E$3:E$380))
machen:
=SUMME((MONAT(A$2:A$379)=MONAT(H2))*WENN(ISTZAHL(E$3:E$380); E$3:E$380))
Dann werden immer 387 Zeilen ausgewertet. In A2 sollte dann natürlich auch ein Datum stehen.
Ein weiterer Fehler:
In H2:H3 stehen die Zahlen 1 und 2. In den Formeln wird davon der Monat berechnet.
Ein Monat kann nur aus einem Datum berechnet werden.
Die 1 ist der 01.01.1900, der Monat davon ist 1.
Die 2 ist der 02.01.1900, der Monat davon ist - auch 1.
Entweder schreibst du H2 statt MONAT(H2) in den Formeln,
oder in Spalte H steht ein vernünftiges Datum.
Noch eins: Es geht nicht so sehr um Genauigkeit. Da sind einfach zwei Formeln mit unterschiedlichen Ergebnissen,
zwischen denen du dich entscheiden müsstest. Dafür wäre es schon gut zu wissen,
warum die Werte sich unterscheiden.
Hier noch deine Mappe: https://www.herber.de/bbs/user/78119.xls
Alles klar?
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich, der auch einen guten Rutsch wünscht

AW: MONAT(Text) geht nicht

29.12.2011 12:10:43

Walter

Hallo Erich,
Danke für die Lösung und den Hinweis auf gleiche Größen.
Danke sagt
Rentner Walter
aus dem nördlichen Nordhessen

AW: SUMMENPRODUKT

28.12.2011 00:21:30

Walter

Hallo Erich, einige Fragen zu Deinen Formeln:
Der Mittelwert müsste 9,85 sein =MITTELWERT(E4:E400)
warum wird hinter der Klammer ein " ; " gesetzt, =MAX(;D4-D3)
Wie werden die Spalten A + H formatiert?
Gruß
Rentner Walter
aus dem nördlichen Nordhessen

und so hab ich es gemacht ...

27.12.2011 09:30:36

Matthias

Hallo
... zwar hier mit einer Hilfsspalte (E) was nicht unbedingt notwendig wäre, aber trotzdem auch funktioniert.

	A	B	C	D	E	F	G	H	I	J
1	Stromverbauch
2	Datum	Tag	KW	Zähler	Monat	Verbrauch
3	01.01.2012	So	52	8775,2		Ø 13,50			Januar	39,4
4	02.01.2012	Mo	1	8786,4	1	11,2			Februar	41,6
5	03.01.2012	Di	1	8794,2	1	7,8			März	0
6	04.01.2012	Mi	1	8803,4	1	9,2			April	0
7	05.01.2012	Do	1	8814,6	1	11,2			Mai	0
8	06.01.2012	Fr	1		1				Juni	0
9	07.01.2012	Sa	1		1				Juli	0
10	08.01.2012	So	1		1				August	0
11	09.01.2012	Mo	2		1				September	0
12	10.01.2012	Di	2		1				Oktober	0
13	11.01.2012	Mi	2		1				November	0
14	12.01.2012	Do	2		1				Dezember	0
15	13.01.2012	Fr	2		1
34	01.02.2012	Mi	5		2	22
35	02.02.2012	Do	5		2	19,6
36	03.02.2012	Fr	5		2

Formeln der Tabelle

Zelle	Formel
C3	=KÜRZEN((A3-DATUM(JAHR(A3+3-REST(A3-2;7));1;REST(A3-2;7)-9))/7)
F3	=MITTELWERT(F4:F368)
J3	=SUMMEWENN($E$4:$E$368;MONAT($I3);$F$4:$F$368)
C4	=KÜRZEN((A4-DATUM(JAHR(A4+3-REST(A4-2;7));1;REST(A4-2;7)-9))/7)
E4	=MONAT(A4)
F4	=WENN(D4="";"";D4-D3)
J4	=SUMMEWENN($E$3:$E$368;MONAT($I4);$F$3:$F$368)
C5	=KÜRZEN((A5-DATUM(JAHR(A5+3-REST(A5-2;7));1;REST(A5-2;7)-9))/7)
E5	=MONAT(A5)
F5	=WENN(D5="";"";D5-D4)
J5	=SUMMEWENN($E$3:$E$368;MONAT($I5);$F$3:$F$368)
C6	=KÜRZEN((A6-DATUM(JAHR(A6+3-REST(A6-2;7));1;REST(A6-2;7)-9))/7)
E6	=MONAT(A6)
F6	=WENN(D6="";"";D6-D5)
J6	=SUMMEWENN($E$3:$E$368;MONAT($I6);$F$3:$F$368)
C7	=KÜRZEN((A7-DATUM(JAHR(A7+3-REST(A7-2;7));1;REST(A7-2;7)-9))/7)
E7	=MONAT(A7)
F7	=WENN(D7="";"";D7-D6)
J7	=SUMMEWENN($E$3:$E$368;MONAT($I7);$F$3:$F$368)
C8	=KÜRZEN((A8-DATUM(JAHR(A8+3-REST(A8-2;7));1;REST(A8-2;7)-9))/7)
E8	=MONAT(A8)
F8	=WENN(D8="";"";D8-D7)
J8	=SUMMEWENN($E$3:$E$368;MONAT($I8);$F$3:$F$368)
C9	=KÜRZEN((A9-DATUM(JAHR(A9+3-REST(A9-2;7));1;REST(A9-2;7)-9))/7)
E9	=MONAT(A9)
F9	=WENN(D9="";"";D9-D8)
J9	=SUMMEWENN($E$3:$E$368;MONAT($I9);$F$3:$F$368)
C10	=KÜRZEN((A10-DATUM(JAHR(A10+3-REST(A10-2;7));1;REST(A10-2;7)-9))/7)
E10	=MONAT(A10)
F10	=WENN(D10="";"";D10-D9)
J10	=SUMMEWENN($E$3:$E$368;MONAT($I10);$F$3:$F$368)
C11	=KÜRZEN((A11-DATUM(JAHR(A11+3-REST(A11-2;7));1;REST(A11-2;7)-9))/7)
E11	=MONAT(A11)
F11	=WENN(D11="";"";D11-D10)
J11	=SUMMEWENN($E$3:$E$368;MONAT($I11);$F$3:$F$368)
C12	=KÜRZEN((A12-DATUM(JAHR(A12+3-REST(A12-2;7));1;REST(A12-2;7)-9))/7)
E12	=MONAT(A12)
F12	=WENN(D12="";"";D12-D11)
J12	=SUMMEWENN($E$3:$E$368;MONAT($I12);$F$3:$F$368)
C13	=KÜRZEN((A13-DATUM(JAHR(A13+3-REST(A13-2;7));1;REST(A13-2;7)-9))/7)
E13	=MONAT(A13)
F13	=WENN(D13="";"";D13-D12)
J13	=SUMMEWENN($E$3:$E$368;MONAT($I13);$F$3:$F$368)
C14	=KÜRZEN((A14-DATUM(JAHR(A14+3-REST(A14-2;7));1;REST(A14-2;7)-9))/7)
E14	=MONAT(A14)
F14	=WENN(D14="";"";D14-D13)
J14	=SUMMEWENN($E$3:$E$368;MONAT($I14);$F$3:$F$368)
C15	=KÜRZEN((A15-DATUM(JAHR(A15+3-REST(A15-2;7));1;REST(A15-2;7)-9))/7)
E15	=MONAT(A15)
F15	=WENN(D15="";"";D15-D14)
C34	=KÜRZEN((A34-DATUM(JAHR(A34+3-REST(A34-2;7));1;REST(A34-2;7)-9))/7)
E34	=MONAT(A34)
C35	=KÜRZEN((A35-DATUM(JAHR(A35+3-REST(A35-2;7));1;REST(A35-2;7)-9))/7)
E35	=MONAT(A35)
C36	=KÜRZEN((A36-DATUM(JAHR(A36+3-REST(A36-2;7));1;REST(A36-2;7)-9))/7)
E36	=MONAT(A36)
F36	=WENN(D36="";"";D36-D35)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Matthias

AW: und so hab ich es gemacht ...

27.12.2011 10:59:25

Walter

Danke Excelfreunde,
Es führen viele Wege nach Rom,
Werde den kürzesten Weg zu finden versuchen,
Heißen Dank
Was würden Sie tun wenn Sie
das neue Jahr regieren könnten?
Ich würde vor Aufregung wahrscheinlich
De ersten Nächte schlaflos verbringen.
Und darauf tagelang ängstlich und kleinlich
Ganz dumme, selbstsüchtige Pläne schmieden.
Dann hoffentlich aber laut lachen
Und endlich den lieben Gott abends leise
Bitten, doch wieder nach seiner Weise
Das neue Jahr göttlich selbst zu machen.
Joachim Ringelnatz (1883-1934)
Einen guten Start in das Neue Jahr
Wünscht
Rentner Walter

Beliebteste Forumthreads (12 Monate)

Forumthread: TEILERGEBNISSE

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread