Formel gesucht

Forumthread: Formel gesucht

Formel gesucht

Jean

Hallo,
ich suche eine Formel, die den Wert in der Anlage ermittelt.
Gruß
Jean
Tabelle2

	A	B	C	D	E
1
2
3
4
5
6
7		3		9
8	7	8		2
9
10	Zelle A14 soll den ersten Wert des Bereichs A6:D8,
11	also die 3 erhalten.
12	Mit welcher Formel erreicht man dies?
13
14
15

Tabellendarstellung in Foren Version 5.46

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Formel gesucht

28.01.2012 16:37:40

Josef

Hallo Jean,
Tabelle1

	A	B	C	D	E
4
5
6
7	3		9
8	7	8		2
9
10
11
12
13
14	3
15

Formeln der Tabelle

Zelle	Formel
A14	{=INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); MIN(WENN(A6:D8<>"";SPALTE(A:D))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

« Gruß Sepp »

AW: Formel gesucht

28.01.2012 16:46:00

Jean

Hallo Sepp,
bie mir kommt 0 heraus. Waran kann dies liegen?
Gruß
Jean
NEU

	A	B	C	D
1
2
3
4
5
6
7		3		9
8	7	8		2
9
10	Zelle A14 soll den ersten Wert des Bereichs A6:D8,
11	also die 3 erhalten.
12	Mit welcher Formel erreicht man dies?
13
14	0

verwendete Formeln
Zelle	Formel	Bereich
A14	{=INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); MIN(WENN(A6:D8<>"";SPALTE(A:D))))}	$A$14

{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Tabellendarstellung in Foren Version 5.46

AW: Formel gesucht

28.01.2012 16:48:03

Josef

Hallo Jean,
dann sind die Zellen nicht leer!

« Gruß Sepp »

AW: Formel gesucht

28.01.2012 16:52:12

Jean

Hallo Sepp,
die "leeren" Zellen sind leer, wurden mit der Funktion ISTLEER überprüft.
Ein Rätsel ... oder doch nicht?
Gruß
Jean

Erklärung

28.01.2012 17:09:04

Erich

Hi Jean,
die 0 kommt da raus, weil Sepps Formel Zeile und Spalte unabhängig von einander bestimmt.
Die 1. Zeile mit einem nichtleeren Wert hat in deinem Beispiel (wegen B7) die Nr. 7 (2. Zeile der Matrix A6:D8),
die 1. Spalte mit einem nichtleeren Wert hat (wegen A8) in deinem Beispiel die Nr. 1.
Sepps Formel gibt INDEX(A6:D8;2;1) zurück, das ist die Zelle A7. Die ist leer, deshalb die 0.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

..wenn A7 kein Wert, = 0 ?

28.01.2012 16:49:13

robert

Gruß

Formel erweitert

28.01.2012 16:58:10

Erich

Hi zusammen,
Sepps Formel (Zeile 14) reicht wohl noch nicht ganz aus.
Ich habe mich an http://www.excelformeln.de/formeln.html?welcher=35 orientiert.
IMHO passen die Formeln in Zeile 12 und kürzer in Zeile 13:

	A	B	C	D
6			1	2
7		3	4
8	555	6	3
9
10
11		Zeile	Spalte
12	1	1	3
13	1	1	3
14	0	1	1

Formeln der Tabelle

Zelle	Formel
A12	{=INDEX(A6:D8; KÜRZEN(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999))); 999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1))}
B12	{=KÜRZEN(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)))}
C12	{=999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1)}
A13	{=INDEX(A6:D8; MIN(WENN(A6:D8<>"";ZEILE(1:3))); 999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1))}
B13	{= MIN(WENN(A6:D8<>"";ZEILE(1:3)))}
C13	{=999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1)}
A14	{=INDEX(A6:D8; MIN(WENN(A6:D8<>"";ZEILE(1:3))); MIN(WENN(A6:D8<>"";SPALTE(A:D))))}
B14	{= MIN(WENN(A6:D8<>"";ZEILE(1:3)))}
C14	{=MIN(WENN(A6:D8<>"";SPALTE(A:D)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Danke, das passt ;-) owT-Gruß

28.01.2012 17:04:52

robert

längere Alternative

28.01.2012 18:00:12

Erich

Hi,
in A13 bzw. C13 wird die Spalte nur in der Zeile von A6:D8 bestimmt, die schon als Zeile gefunden wurde.
Statt in A6:D8 wird der erste nichtleere Wert in
INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3)));) gesucht - das ist hier die 1. Zeile, also A6:D6.
Die A13-Formel ist weder kürzer noch "schöner" als A12, hilft aber vielleicht ein wenig beim Verstehen.

	A	B	C	D
6			1	2
7		3	4
8	555	6	3
9
10
11		Zeile	Spalte
12	1	1	3
13	1	1	3

Formeln der Tabelle

Zelle	Formel
A12	{=INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); 999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1))}
B12	{=MIN(WENN(A6:D8<>"";ZEILE(1:3)))}
C12	{=999*REST(MIN(WENN(A6:D8<>"";ZEILE(1:3)+SPALTE(A:D)/999)); 1)}
A13	{=INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); MIN(WENN(INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); )<>"";SPALTE(A:D))))}
B13	{=MIN(WENN(A6:D8<>"";ZEILE(1:3)))}
C13	{=MIN(WENN(INDEX(A6:D8;MIN(WENN(A6:D8<>"";ZEILE(1:3))); )<>"";SPALTE(A:D)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Nochmals Dank an Erich-ist OK ;-) Gruß

28.01.2012 18:22:04

robert

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel gesucht

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread