Zu lange Formel

Forumthread: Zu lange Formel

Zu lange Formel

Thomas

Hallo zusammen,
ich hab das Problem, dass eine Zellenformel zu lang ist. Außerdem sobald eine Subtraktion keinen Wert liefert, liefert mir auch die gesamte Formel nicht's.
Kann mir bitte hierzu jemand helfen ?
=((Verschleiß!Q1033+Verschleiß!S1033)-(Verschleiß!Q991+Verschleiß!S991))
+((Verschleiß!Q991+Verschleiß!S991)-(Verschleiß!Q949+Verschleiß!S949))
+((Verschleiß!Q949+Verschleiß!S949)-(Verschleiß!Q907+Verschleiß!S907))
+((Verschleiß!Q907+Verschleiß!S907)-(Verschleiß!Q865+Verschleiß!S865))
+((Verschleiß!Q865+Verschleiß!S865)-(Verschleiß!Q823+Verschleiß!S823))
+((Verschleiß!Q823+Verschleiß!S823)-(Verschleiß!Q781+Verschleiß!S781))
+((Verschleiß!Q781+Verschleiß!S781)-(Verschleiß!Q739+Verschleiß!S739))
+((Verschleiß!Q739+Verschleiß!S739)-(Verschleiß!Q697+Verschleiß!S697))
+((Verschleiß!Q697+Verschleiß!S697)-(Verschleiß!Q655+Verschleiß!S655))
+((Verschleiß!Q655+Verschleiß!S655)-(Verschleiß!Q613+Verschleiß!S613))
+((Verschleiß!Q613+Verschleiß!S613)-(Verschleiß!Q571+Verschleiß!S571))
+((Verschleiß!Q571+Verschleiß!S571)-(Verschleiß!Q529+Verschleiß!S529))
+((Verschleiß!Q529+Verschleiß!S529)-(Verschleiß!Q487+Verschleiß!S487))
+((Verschleiß!Q487+Verschleiß!S487)-(Verschleiß!Q445+Verschleiß!S445))
Es liegen immer 42 Zeilen dazwischen. Die Formel soll auch ausgeführt werden, wenn nur beispielsweise Q487, S487, Q445 und S445 ausgefüllt sind.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Kürzere Formel

21.03.2012 15:15:59

Erich

Hi Thomas,
so ist deine Formel wirklich viel zu lang. B3 liefert den selben Wert:

	B	C
3	-6789
4
5	0	ist immer 0

Formeln der Tabelle

Zelle	Formel
B3	=Verschleiß!Q1033+Verschleiß!S1033-Verschleiß!Q445-Verschleiß!S445
B5	=-(Verschleiß!Q697+Verschleiß!S697) +(Verschleiß!Q697+Verschleiß!S697)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Außer bei den Werten der untersten (1033) und der obersten (445) Zeile subtrahierst du die Werte,
um sie dann gleich wieder zu addieren. Welchen Sinn soll das haben?
Da stehen dann nur haufenweise Nullen - wie in B5.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Rückfrage

21.03.2012 15:21:07

Erich

Hi Thomas,
deinen Satz
"Außerdem sobald eine Subtraktion keinen Wert liefert, liefert mir auch die gesamte Formel nicht's."
habe ich nicht verstanden.
Welche Subtraktion liefert keinen Wert? Wie kann eine Formel NICHTS liefern?
Eine Formel hat IMMER einen WERT, auch 0 oder "" oder ein Fehlerwert wie #NV sind mögliche Werte.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Rückfrage

21.03.2012 16:28:14

Thomas

Ne, nicht ganz.
Ich kürze die Formel mal zum besseren Verständnis:
=((Verschleiß!Q1033+Verschleiß!S1033)-(Verschleiß!Q991+Verschleiß!S991)) +((Verschleiß!Q991+Verschleiß!S991)-(Verschleiß!Q949+Verschleiß!S949))
Q1033 = Datumsangabe (z.B. 21.03.2012)
S1033 = Uhrzeitangabe (z.B. 10:00)
Q991 = Datumsangabe (z.B. 22.03.2012)
S991 = Uhrzeitangabe (z.B. 10:00)
Die Zelle mit dieser oben genannten Formel soll nun die Zeitdifferenz aus vorher und nacher ausgeben werden, in diesem Beispielfall 24:00
Die lange, vorher genannte Formel, berechnet nichts anderes, nur dass diese eben deutlich mehr Zeitdifferenz als Eingangsgrößen hat.
Erweitert gesprochen... sind Q1033, S1033, Q991 und S991 mit Werten bestückt, die darauffolgenden Zellen jedoch nicht (z.B. Q949 und S949), so ist die Ausgabe "#############".
Danke und Gruß
Thomas

AW: Rückfrage

21.03.2012 18:33:38

Sheldon

Hallo Thomas,
mit Datum und Uhrzeit rechnen ist was ganz anderes als mit normalen Zahlen. In diesem Fall wäre eine Beispieldatei echt hilfreich, denn aus dem Namen des Blatts habe ich nicht geschlossen, dass es sich um Zeitangaben handelt. Die Ausgabe ist deshalb ####, weil ein negatives Ergebnis herauskommt. Excel kann aber kein negatives Ergebnis im Zeitformat ausgeben. Da hilft nur folgendes:
Füge eine Hilfsspalte ins Blatt Verschleiß ein. Darin berechnest du jeweils die Differenz aus den zu vergleichenden Werten. Die Zellen der Hilfsspalte formatierst du zum Abschluss noch als Standard. Die einzelnen Zellen summierst du und formatierst dann die Ergebniszelle z.B. mit [mm]:ss als benutzerdefiniertes Format, wenn du immer die Summe der Minuten sehen willst. Bei Stunden [hh]:mm:ss. Die eckigen Klammern sorgen dafür, dass die jeweils größeren Einheiten ebenfalls in Stunden oder Minuten addiert und dargestellt werden, also 3 Tage = 72 Stunden.
Gruß
Sheldon

@Sheldon: Widerspruch

21.03.2012 19:55:16

Erich

Hi Sheldon,
"mit Datum und Uhrzeit rechnen ist was ganz anderes als mit normalen Zahlen"?
Nein - im Gegenteil!
Datum und Uhrzeit sind ganz normale Zahlen, mit ihnen kann man auch normal rechnen.
Das Problem ist nur die Anzeige, die Formatierung:
Wenn man eine Zahl als Datum oder Uhrzeit anzeigen lassen will, geht das nur, wenn die Werte "sinnvoll" sind.
Für das Datum heißt das:
- Die Zahl darf nicht negativ sein. Excel fängt im Jahr 1900 mit Null an.
- Die Zahl muss kleiner/gleich 2958465 sein. Das ist der 31.12.9999.
Für die Uhrzeit heißt das:
- Die Zahl darf nicht negativ sein. Es gibt keine negative Uhrzeit. (Wer geht um minus 5 Uhr ins Kino?)
- Die Zahl muss kleiner als 1 sein. (1 wäre 24 Uhr, also 0 Uhr am nächsten Tag)
Auch eine Zahl größer als 1, z. B. 1,75 kann wie eine Uhrzeit angezeigt werden:
Beim Format hh:mm käme 18:00 raus - der eine zusätzliche Tag würde nicht angezeigt.
Beim Format [hh]:mm käme 42:00 raus, also 42 Stunden.
Wenn von einer "negativen Uhrzeit" gesprochen wird, ist das überhaupt keine Uhrzeit, kein Zeitpunkt,
sondern ein Zeitraum, ausgedrückt in Stunden und Minuten und evtl. Sekunden.
Dummerweise sieht der Zeitraum 11:35:10 (11 Stunden und 35 Minuten und 10 Sekunden)
genau so aus wie die Uhrzeit 11:35:10 (11 Uhr 35 und 10 Sekunden).
Wenn man den Zeitraum 11:35:10 nicht in diesem hh-mm-ss-Einheiten-Mischmasch anzeigt,
sondern z. B. in hh = Stunden als 11,58611111, dann klappt die Darstellung auch negativer Zeiträume problemlos.
Solche negativen Zeiträume (z. B. Stundenanzahlen) können etwa 'negative Überstunden' sein.
Wenn in einer Zelle die Uhrzeit 11:35:10 angezeigt wird:
Der Wert der Zelle ist einfach nur 0,48275463. Und mit diesem Wert wird gerechnet.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

...und wo ist der Widerspruch?

21.03.2012 20:13:41

Sheldon

Hi Erich,
aber genau davon hab ich doch geschrieben. Dass es am Format liegt. Oder etwa nicht? Abgesehen davon, was nützt denn die Wortklauberei dem Thomas, der will doch wissen warum die Ausgabe immer einen Fehler liefert, wenn die Differenz negativ ist. Da hilft die Info, dass Datum und Zeit ganz normale Zahlen sind, nicht weiter.
Gruß
Sheldon

@Sheldon

21.03.2012 20:33:39

Erich

Hi Sheldon,
der Widerspruch steht IMHO klar in den drei Zeilen meines Beitrags unter "Hi Sheldon,". :-)
Was meinst du, wäre da Wortklauberei? Ich halte es für fundamental wichtig, dass ein Excel-Anwender
versteht,
was Datum und Uhrzeit in Excel sind. Sehr viele Fehler und Fragen resultieren aus mangelndem Verständnis dieser Größen.
Fast lustig finde ich immer wieder, wenn in Formeln (auch bei "Profis") DATEDIF(A1;B1;"d") statt B1-A1 auftaucht.
Wenn ein Datum was Besonderes ist, braucht man natürlich für die Tagesdifferenz DATEDIF...
Bei Thomas liefert die Ausgabe wohl gar keinen Fehler.
Ich habe ihm zwei mögliche Gründe für die ###-Anzeige beschrieben und dazu noch,
dass er sich das Formelergebnis auch im Standardformat ansehen kann.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Vorbeugend ...

21.03.2012 20:16:04

Erich

Hi,
... sollte ich hier ergänzen, dass ich in meinem Beitrag unterstelle, dass der Würgaround "1904-Datumswerte"
nicht benutzt wird. Wer das tut, sollte genau wissen, was er da tut.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

nächster Versuch

21.03.2012 20:11:14

Erich

Hi Thomas,
der Übersichtlichkeit halber habe ich mal Werte und Formeln "übersetzt" an den Beginn einer Tabelle:

	A	B	C
1		Q	S
2	1033	21.03.2012	10:00
3	991	25.07.2005	13:45
4	949
5
6	TT.MM.JJJJ hh:mm	Standard
7	21.03.2012 10:00	40989,41667
8	21.03.2012 10:00	40989,41667
9	21.03.2012 10:00	40989,41667

Formeln der Tabelle

Zelle	Formel
A7	=((B2+C2)-(B3+C3)) +((B3+C3)-(B4+C4))
B7	=A7
A8	=B2+C2-(B3+C3) +B3+C3-(B4+C4)
B8	=A8
A9	=B2+C2-(B4+C4)
B9	=A9

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
In A7 steht im Prinzip deine Formel.
In A8 habe ich etliche überflüssige Klammern weggelassen.
In A9 ist der Teil weggelassen, der ohnehin immer =0 ist. Das sind die Werte aus Zeile 991 (hier 3),
die in A7 und in A8 erst subtrahiert und dann wieder addiert werden - das hebt sich auf.
-(B3+C3)+B3+C3 ist gleich 0 - immer - egal, welche Zahlen in B3 und C3 stehen.
Dass du das Formelergebnis als "####..." angezeigt bekommst, kann zwei Ursachen haben:
- Die Spaltenbreite reicht nicht aus für die Anzeige des Werts im gewünschten Format (dann: Spalte breiter machen).
- Der Wert ist negativ, das Zahlenformat der Zelle ist ein Uhrzeit- oder Datumsformat.
Dazu schau mal bitte in meine Antwort an Sheldon.
Frage:
Welches Format hat die Zelle, in der die Formel steht, bei dir?
Wie wird das Formelergebnis angezeigt, wenn du das Zahlenformat mal auf Standard stellst?
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: nächster Versuch

22.03.2012 11:16:50

Thomas

Vielen Dank Euch beiden !
Ich hab die Problematik nun verstanden.
Habe mein Dokument daraufhin abgeändert, dass ich nun mit mehreren Hilfsspalten arbeite. Damit reduziert sich die "ganz große" Formel deutlich und ich addiere alle Teilergebnisse zuletzt zusammen.
Das funktioniert soweit auch. Allerdings wenn eine folgende Datumsangabe fehlt, weil der Versuch damit dann auch abgeschlossen war, zerschießt mir dieses negative Teilergebnis natürlich auch mein Summenergebnis.
Negatives Teilergebnis in Ausgabe nach [hh]:mm liefert "#########", nach standard "-40990,375". Wie erwähnt, das ist klar nachdem auch das folgende Datum eben fehlt. Dennoch möchte ich mir die Summe aus den bisherigen Teilergebnissen ausgeben, quasi soll diese Zeitdifferenz welche "####" liefert ignoriert werden.
Vielen Dank !
Thomas

AW: nächster Versuch

22.03.2012 11:34:02

Thomas

ich fang diese Problematik nun einfach primitiv über die WENN - Funktion ab.
z.B.:
=WENN((((Verschleiß!Q193+Verschleiß!S193)-(Verschleiß!Q151+Verschleiß!S151))-R8)<=0;"00:00"; ((Verschleiß!Q193+Verschleiß!S193)-(Verschleiß!Q151+Verschleiß!S151))-R8)
Hat sich nun für mich erledigt.
Vielleicht nicht die eleganteste Lösung aber das Ergebnis zählt.
Danke nochmals und Gruß
Thomas

noch zwei Hinweise

22.03.2012 13:10:42

Erich

Hi Thomas,
vielleicht liest du ja doch noch diese beiden Tipps:
Die "00:00" in deiner Formel ist keine Uhrzeit, sondern ein Text. Die Uhrzeit ist einfach die Zahl 0.
Per Zahlenformat wird der Wert 0 dann z. B. als 0:00 angezeigt.
Einfacher als mit dem WENN geht es so:
=MAX(0;Verschleiß!Q193+Verschleiß!S193-(Verschleiß!Q151+Verschleiß!S151)-R8)
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Beliebteste Forumthreads (12 Monate)

Forumthread: Zu lange Formel

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread