Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1292to1296
1292to1296
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Spalten ausfüllen

Forumthread: Spalten ausfüllen

Spalten ausfüllen
09.01.2013 15:19:07
Black
Hallo Excel Freunde,
ich teile in der Spalte B und C, Datum und Zeit von der Spalte A.
Es sollte in einem Makro geschehen. Ich kann das nicht mit dem Befehl Range("B2:C35").Select Selection.FillDown machen, weil die zeilen Anzahl immer varriert.
Wie kann ich ausfüllen bis zu der letzten Position in Spalte A? Siehe Beispiel Datei.
https://www.herber.de/bbs/user/83314.xls
Gruß Stan

Anzeige

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Spalten ausfüllen
09.01.2013 15:26:00
Hajo_Zi
warum nicht Deine Formel und Doppelklick?

AW: Spalten ausfüllen
09.01.2013 15:29:05
Klaus
Hi Stan,
hab mal vier Varianten gemacht. Nimm die dritte oder vierte, die ersten beiden sind nur zur Veranschaulichung.
Option Explicit
Sub AusfuellenEins()
'Die Antwort auf deine Frage
Dim lRow As Long
lRow = Cells(Rows.Count, 1).End(xlUp).Row 'letzte Zelle
Range("B2:C" & lRow).Select
Selection.FillDown
End Sub
Sub AusfuellenZwei()
'Besser: ohne Select, und die Tabelle im WITH referenziert
Dim lRow As Long
With Sheets("Tabelle1")
lRow = .Cells(Rows.Count, 1).End(xlUp).Row 'letzte Zelle
.Range("B2:C" & lRow).FillDown
End With
End Sub
Sub AusfuellenDrei()
'noch besser: mit COPY statt mit FILLDOWN
'ist bei großen Tabellen viel schneller
Dim lRow As Long
With Sheets("Tabelle1")
lRow = .Cells(Rows.Count, 1).End(xlUp).Row 'letzte Zelle
.Range("B2:C2").Copy .Range("B3:C" & lRow)
End With
End Sub
Sub AusfuellenVier()
'am besten: gar nicht kopieren, sondern direkt die Formeln schreiben
Dim lRow As Long
With Sheets("Tabelle1")
lRow = .Cells(Rows.Count, 1).End(xlUp).Row 'letzte Zelle
.Range("B2:B" & lRow).FormulaR1C1 = "=MID(RC[-1],1,10)"
.Range("C2:C" & lRow).FormulaR1C1 = "=MID(RC[-2],12,5)"
End With
End Sub
Grüße,
Klaus M.vdT.

Anzeige
AW: Spalten ausfüllen
09.01.2013 15:37:35
Black
Hallo,
danke für die Vorschläge. Funktioniert super.
Gruß Stan

Danke für die Rückmeldung! o.w.T.
09.01.2013 15:46:18
Klaus
.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige