Straße & Hausnummer auswerten

Forumthread: Straße & Hausnummer auswerten

02.07.2013 16:00:44

Herbert

Hallo,
ich möchte in einer Auswertung die Straßen und Hausnummern auflisten.
In Spalte A stehen geordnet die Straßen. Dahinter in Spalte B die jeweilige Hausnummer.
Ich möchte gern, eine Übersicht "Straße / Hausnummer Beginn / Hausnummer Ende".
Es soll also nur einmal die Straße und die Erste sowie Letzte Nummer erscheinen.
Leider habe ich keine Lösung. Ihr vielleicht?
Bin über jede Hilfe dankbar.
Viele Grüße

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Straße & Hausnummer auswerten

02.07.2013 16:05:14

Klaus

Hi Herbert,
gibt uns doch mal ein paar dutzend Strassen + Hausnummern als Mustertabelle.
Grüße,
Klaus M.vdT.

AW: Straße & Hausnummer auswerten

02.07.2013 16:29:37

UweD

Hallo
das ginge so...
Probleme bei Hausnummern mit Zeichen...
also 14a, 16 Hinterhaus, 22 - 50 usw
Tabelle1

	A	B	C	D	E	F	G
1	Der Weg	40			Strasse	von	bis
2	Im Hasengarten	18			Der Weg	12	60
3	Im Hasengarten	14			Im Hasengarten	14	18
4	An der Autobahn	22			An der Autobahn	11	22
5	Hier	5			Hier	5	5
6	Der Weg	58			Dort	8	8
7	Im Hasengarten	16
8	An der Autobahn	11
9	Der Weg	60
10	Dort	8
11	Der Weg	12

verwendete Formeln
Zelle	Formel	Bereich
F2	{=MIN(WENN($A$1:$A$100=$E2;$B$1:$B$100))}	$F$2
G2	{=MAX(WENN($A$1:$A$100=$E2;$B$1:$B$100))}	$G$2

{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Tabellendarstellung in Foren Version 5.49

Gruß UweD

Mit der ein oder anderen Kleinen Formel

02.07.2013 16:19:53

JACKD

Hallo Herbert
so könnte es klappen =)
Spalte E erstellt eine Duplikatfreie Liste
Spalte F gibt das min der in E genannten Strasse
Spalte G das max
Grüße

Tabelle1

	A	B	C	D	E	F	G	H
1	Weg	1			Weg	1	7
2	Weg	4			Strasse	2	9
3	Weg	7
4	Weg	2
5	Strasse	9
6	Strasse	2
7
8
9

verwendete Formeln
Zelle	Formel	Bereich	R1C1 für Add In
E1:E7	{=WENNFEHLER(INDIREKT("A"&KKLEINSTE(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A$1;;;ZEILE($1:$100) ) ;A$1:A$100) =1;ZEILE($1:$100) ) ;ZEILE(A1) ) ) ;"") }	$E$1	=IFERROR(INDIRECT("A"&SMALL(IF(COUNTIF(OFFSET(R1C[-4],,,ROW(R1:R100) ) ,R1C[-4]:R100C[-4]) =1,ROW(R1:R100) ) ,ROW(RC[-4]) ) ) ,"")
F1:F8	{=WENN(E1="";"";(MIN(WENN((A:A=E1) ;(B:B) ) ) ) ) }	$F$1	=IF(RC[-1]="","",(MIN(IF((C[-5]=RC[-1]) ,(C[-4]) ) ) ) )
G1:G8	{=WENN(E1="";"";MAX(WENN((A:A=E1) ;(B:B) ) ) ) }	$G$1	=IF(RC[-2]="","",MAX(IF((C[-6]=RC[-2]) ,(C[-5]) ) ) )

{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

XHTML Tabelle für Darstellung in Foren,
einschl. Bedingter Formatierung ab Version 2007
XHTML-Version 11.26

AW: Straße & Hausnummer auswerten

02.07.2013 16:30:04

Herbert

Super, vielen Dank. Funktioniert.

da hast Du Glück, denn ...

02.07.2013 18:18:24

neopa

Hallo Herbert,
... sehr häufig sind die Hausnummern keine reine Zahlenwerte. Es gibt da sehr viele andere Arten von Hausnummern, wie z.B. IVb oder 17a oder ...
@Jack,
Deine Formel zur Ermittlung der Straßennamen gefällt mir ob Ihrer Kürze. Wenn Du darin INDIREKT() noch durch INDEX() ersetzt wird sie noch kürzer und vor allem fällt eine der beiden volatilen Funktionen weg und die Formel wird dadurch auch nicht so anfällig gegen Tabellenänderungen. Ich habe bisher anstelle BEREICH.VERSCHIEBEN() immer eine Formel auf Basis von VERGLEICH() eingesetzt. Diese erfordert jedoch, um sie noch etwas kurzer zu halten eine Leerzelle in A1.
Also in E2 so z.B.: {=INDEX(A:A;MIN(WENN((VERGLEICH(""&A$2:A$99;""&A$2:A$99;))*ISTNV(VERGLEICH(A$2:A$99;E$1:E1;))*(A$2:A$99"");ZEILE(A$2:A$99))))}
Gruß Werner
.. , - ...
Jeder Interessent ist willkommen beim Exceltreffen 11.-13.10.2013 in Duisburg
Mehr dazu, siehe http://www.exceltreffen.de/index.php?page=230

Beliebteste Forumthreads (12 Monate)

Forumthread: Straße & Hausnummer auswerten

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread