Datei per Mail versenden

Forumthread: Datei per Mail versenden

31.10.2013 19:33:16

Dani

Hallo zusammen
In meiner Datei ist ein "Senden" Button, welcher folgenden Code enthält:


Sub Send()
Dim sSubject As String
Dim fEmpfaenger() As Variant
Dim byWert As Byte
Mailadress = Cells(36, 10).Value
byWert = MsgBox("Die Datei wird an folgende Mailadressen gesendet:" & vbCrLf & "einteiler@abc. _
com" & vbCrLf & Mailadress, 1, "Sendebestätigung")
If byWert = 1 Then
sSubject = "Zulagenblatt" & " " & Cells(2, 9) & "_" & Cells(1, 9) & "_" & Year(Date)
ReDim fEmpfaenger(1 To 2)
fEmpfaenger(1) = Mailadress
fEmpfaenger(2) = "einteiler@abc.com"
Application.Dialogs(xlDialogSendMail).Show fEmpfaenger(), sSubject
Else
End If
End Sub

Dies funktioniert einwandfrei, solange der User ein Mailprogramm (meist Outlook) benutzt.
Leider gibt es bei uns User die ihre Mails nur via Webmail nutzen. Gibt es die Möglichkeit, die Datei über eine "Allerwelts Mailadresse" (zb. GMX oder so) direkt ohne ein anderes Programm öffnen zu müssen zu versenden?
Das würde heissen, ich müsste die Einstellungen (SMTP und Benutzerdaten) ja wahrscheinlich in den Code einbauen.
Hoffe dies ist möglich ?...
Danke schon mal für eure Hilfe
Gruess Dani

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Datei per Mail versenden

01.11.2013 20:57:21

Tino
AW: Datei per Mail versenden

03.11.2013 21:24:39

Dani
AW: Datei per Mail versenden

04.11.2013 11:40:56

Tino

AW: Datei per Mail versenden

01.11.2013 20:57:21

Tino

Hallo,
schau dir mal dies an, vielleicht hilft es dir.
https://www.herber.de/forum/archiv/1056to1060/t1059921.htm#1059958
Gruß Tino

AW: Datei per Mail versenden

03.11.2013 21:24:39

Dani

Hallo Tino
Dein Vorschlag habe ich umgesetzt und zwei Sachen festgestellt.
Nach einem Versuch auf eine Gmailadresse zu senden, musste ich feststellen, dass Gmail die Mail geblockt hat. Aber auf einer anderen Adresse klappte es problemlos.
Ich kann die Mail nicht aus der geöffneten Datei senden, es kommt ein Zugriffsfehler. Wie kann ich das "umgehen". Ziel wäre ja eigentlich, dass der User mit einem Active X Button die Datei direkt senden kann.
Mit einem beliebigen Attachment klappt es wunderbar.
Danke schon mal für deine Hilfe
Gruess Dani

AW: Datei per Mail versenden

04.11.2013 11:40:56

Tino

Hallo,
also habe es gerade nocheinmal getestet auch auf ein GMAIL Konto, geht bei mir.
Hast Du bei dir den Serverport richtig angegeben in der Regel 465 (bei mir) evtl. auch 587.
Ich kann die Mail nicht aus der geöffneten Datei senden
Dann speichere eine kopie dieser Datei und sende diese.
Wenn es große Dateien sind, evtl. auch mal mit einen Timeout testen.
Hier ein Beispiel

Sub EMail__Senden_Ohne_Outlook()
Dim iNachricht As Object, iKonfiguration As Object, Felder As Variant
Dim strMailAdress$, strKennwort$, strTmpFile$

strMailAdress = "xxxxxx@gmail.com"   '"Deine E-Mail-Adresse" 
strKennwort = "xxxxxxxxx"            'Passwort angeben 

'Datei für Anlage erstellen 
strTmpFile = ThisWorkbook.Path
If Right$(strTmpFile, 1) <> "\" Then strTmpFile = strTmpFile & "\"
ChDrive strTmpFile
ChDir strTmpFile
'File Name für Nachricht 
strTmpFile = strTmpFile & "Mail_" & ThisWorkbook.Name
'evtl. löschen fals vorhanden 
If Dir(strTmpFile, vbNormal) <> "" Then Kill strTmpFile
'eine kopie der Datei speichern 
ThisWorkbook.SaveCopyAs strTmpFile


Set iNachricht = CreateObject("CDO.Message")
Set iKonfiguration = CreateObject("CDO.Configuration")
iKonfiguration.Load -1
Set Felder = iKonfiguration.Fields

With Felder
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
   .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = strMailAdress
   .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = strKennwort
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com" 'Postausgangsserver 
   .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465 'SMTP-Port 
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpservertimeout") = 60 'Timeout 
   .Update
End With


With iNachricht
    Set .Configuration = iKonfiguration
    .To = "xxxxxx@Proviter.com"            'Empfänger 
    .CC = ""                               'Zur Kenntnis 
    .BCC = ""                              '.BCC nicht sichtbare Empfänger 
    .Sender = strMailAdress                'Von 
    .Subject = "Betreff"                   'Betreffzeile 
    .TextBody = "Deine Nachricht!"         'Nachricht 
    .AddAttachment strTmpFile              'Anlage 
    .Send
End With

'Datei wieder löschen 
If Dir(strTmpFile, vbNormal) <> "" Then Kill strTmpFile
End Sub

Gruß Tino

Beliebteste Forumthreads (12 Monate)

Forumthread: Datei per Mail versenden

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread