Zelladresse im Select Bereich

Forumthread: Zelladresse im Select Bereich

20.03.2014 09:32:53

Valeri

Moin Excel Profis,
ich habe da mal eine Frage, ich versuche mal es so verständlich wie möglich zu umschreiben. In unserem Urlaubsplan haben wir z.B. von H102:H106 eine Arbeitswoche abgebildet. Wenn jetzt jemand von H102:H104 "U" (für Urlaub) und von H105:H106 "G" (für Gleitzeit) drin stehen hat, und ich jetzt den Bereich von H102:H106 markiere, dann möchte ich die Zelladresse der ersten und letzten Zelle von "U" wissen und die Adressen von der ersten und letzten Zelle von "G" wissen. Zur Info in diesem Urlaubsplan befindet sich die Planung für 30 Personen fürs ganze Jahr.
Ist so etwas möglich?
Danke schon Mal!
Gruß Valeri

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Zeillenummern ersten und letzten Wertes ermitteln

20.03.2014 11:48:15

NoNet

Hallo Valerie,
um die Zeilennummer zu ermitteln (die Spallte ist ja bekannt), kann ich Dir 2 Lösungen anbieten :

	H	I	J	K	L	M	N
100
101	Woche		Suche nach	Von	Bis	Von	Bis
102	U		U	102	104	102	104
103	U		G	105	106	105	106
104	U
105	G
106	G

© 19.09.2013, Tab2HTML (beta), NoNet - www.excelei.de
Zum Ansehen der hinterlegten Funktionen bitte mit der Maus über die Zellen fahren. Zum Markieren der Funktion bitte einzelne Funktion doppelt anklicken und per Strg+C kopieren !
Die Funktionen in Spalten K und L bitte ohne die Klammern { } eingeben, jedoch mit Strg+Shift+ENTER bestätigen !
Gruß, NoNet

AW: Zeillenummern ersten und letzten Wertes ermitteln

20.03.2014 12:22:51

Valeri

Hallo NoNet,
vielen Dank für deine Antwort.
Ich habe versäumt zu erwähnen dass ich eine Lösung für VBA benötige.
Gruß Valeri

Makro: Zeile-Nr d. 1. und letzten Wertes ermitteln

20.03.2014 13:05:08

MCO

'Bitte schön:
' Gruß, MCO

Sub adresse()
Dim zl_U(5) As String
Dim zl_G(5) As String
Dim i As Single
i = 0
j = 0
For Each cl In Selection
If cl.Value = "U" Then
zl_U(i) = cl.Address(0, 0)
i = i + 1
ElseIf cl.Value = "G" Then
zl_G(j) = cl.Address(0, 0)
j = j + 1
End If
Next cl
MsgBox "Urlaubszeilen: " & zl_U(0) & " - " & zl_U(i - 1) & vbCrLf & _
"Gleitzeitzeilen: " & zl_G(0) & " - " & zl_G(j - 1)
End Sub

AW: Makro: Zeile-Nr d. 1. und letzten Wertes ermitteln

20.03.2014 14:35:51

Valeri

Hallo MCO,
dein Code funktioniert ja tadellos! Vielen Dank dafür.
Wie kriege ich den Code so abgeändert das ich nur die Zeilennummer erhalte?
Gruß Valeri

AW: Makro: Zeile-Nr d. 1. und letzten Wertes ermitteln

20.03.2014 16:02:40

Rudi

Hallo,
c1.Row statt c1.Address(0,0)
Gruß
Rudi

AW: Makro: Zeile-Nr d. 1. und letzten Wertes ermitteln

20.03.2014 17:43:02

Valeri

Vielen Dank an Alle!!!
Funzt Supper!
Gruß Valeri

AW: Zeillenummern ersten und letzten Wertes ermitteln

20.03.2014 13:12:21

fcs

Hallo Valeri,
könnte man so per Makro lösen.
Gruß
Franz

'Code in einem allgemeinen Modul - Makro zugewiesen zu einer Form oder einem _
Formular-Steuerelement inmm tabellenblatt
Sub cmbCheck_U_G_Tage()
Dim rng As Range, ZelleU1 As Range, ZelleU2 As Range, ZelleG1 As Range, ZelleG2 As Range
Dim Zeile As Long
Dim intAnz_U As Integer, intAnz_G As Integer
Dim msgText As String
'Ermitteln der 1. / letzten Zelle mit "U" bzw. "G"  in 1. Spalte der selektierten Zellen.
Set rng = Selection
intAnz_U = 0: intAnz_G = 0
For Zeile = 1 To rng.Rows.Count
If rng.Cells(Zeile, 1).Value = "U" Then
intAnz_U = intAnz_U + 1
If ZelleU1 Is Nothing Then
Set ZelleU1 = rng.Cells(Zeile, 1)
Set ZelleU2 = rng.Cells(Zeile, 1)
Else
Set ZelleU2 = rng.Cells(Zeile, 1)
End If
ElseIf rng.Cells(Zeile, 1).Value = "G" Then
intAnz_G = intAnz_G + 1
If ZelleG1 Is Nothing Then
Set ZelleG1 = rng.Cells(Zeile, 1)
Set ZelleG2 = rng.Cells(Zeile, 1)
Else
Set ZelleG2 = rng.Cells(Zeile, 1)
End If
End If
Next Zeile
'Ergebnisausgabe
msgText = "Gleit- und Urlaubstage in Bereich " & rng.Columns(1).Address(False, False)
If intAnz_U = 0 Then
msgText = msgText & vbLf & "Keine U-Tage"
Else
msgText = msgText & vbLf & intAnz_U & " U-Tag" & IIf(intAnz_U = 1, "", "e") _
& " von " & ZelleU1.Address(False, False) _
& " bis " & ZelleU2.Address(False, False)
End If
If intAnz_G = 0 Then
msgText = msgText & vbLf & "Keine G-Tage"
Else
msgText = msgText & vbLf & intAnz_G & " G-Tag" & IIf(intAnz_G = 1, "", "e") _
& " von " & ZelleG1.Address(False, False) _
& " bis " & ZelleG2.Address(False, False)
End If
MsgBox msgText, vbInformation + vbOKOnly, "Anzeige Ulaubs- und Gleittage in Woche"
End Sub

Beliebteste Forumthreads (12 Monate)

Forumthread: Zelladresse im Select Bereich

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread