3-7 grösster eintrag eines bereiches davon mittelw

Forumthread: 3-7 grösster eintrag eines bereiches davon mittelw

16.07.2014 20:18:41

mittelw

hi
Suche den mittelwert des 3-7 grössten wertes .es dürfen aber nur die einträge >=heute()-180 betrachtet werden (gelb)
auch hier würd ichs warscheinlich mit mehreren hilfsspalten hinbekommen. eine formel wäre toll. häng aber natürlich auch selber hinter evtl bekomm ichs raus
im beispiel wirds besser erklärt
https://www.herber.de/bbs/user/91533.xlsx
Danke

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Amit {MITTELWERT()} ...

16.07.2014 20:32:15

der

Hallo,
.. so: {=MITTELWERT(KGRÖSSTE(WENN(A2:A22>HEUTE()-180;B2:B22);ZEILE(A3:A7)))} Gruß Werner
.. , - ...

danke :)

16.07.2014 20:39:27

Spenski

hallo werner , das klappt super , ich danke dir für die schnelle antwort :)
magst du eventuell 3 threads unter diesem auch mal schauen? hab da ein ähnliches problem.
aber auf jedenfall danke:)
schönen abend wünsch ich dir noch
gruss chriatian

ähnlich ist auch der Wolf dem Schaf, ...

16.07.2014 20:43:07

der

Hallo Christian,
... wenn man nur die Größe betrachtet ;-)
Zwischen beiden Themen sind Unterschiede, fast wie zwischen Wolf und Schaf oder so ähnlich ... ;-)
Gruß Werner
.. , - ...

AW: ähnlich ist auch der Wolf dem Schaf, ...

16.07.2014 20:45:44

Spenski

ja jetzt wo ich die lösung sehe , sehe ichs genauso. bin dir sehr dankbar

noch eine frage dazu

18.07.2014 15:52:28

Spenski

haben uns auf der arbeit sehr gefreut , da diese formel uns sehr viel arbeit erspart hat.
Spalte A = Materialnummer
Spalte B = Datum
Spalte C = Mengenangabe
in E1 Steht die Materialnummer die durchsucht werden soll
in E2 steht die Formel:
{=MITTELWERT(KGRÖSSTE(WENN($B$1:$B$25000>HEUTE()-180*($A$1:$A$25000=E1);$C$1:$C$25000); ZEILE($A$3:$A$7))) }
klappt auch soweit super. allerdings kommt kein ergebnis wenn die formel nur zb 6 Einträge in der Datenbank findet.
meine frage:
kann ich ohne weiteres zb wenn(zählenwenn... um die formel rumbauen und dann alles in {} setzen oder bau ich mir dann ein fehler ein?
das würde ich wohl hinbekommen.
oder gibts da einen anderen weg?
tut mir leid für die doppeltarbeit , aber daran hab ich nicht gedacht.
gruss
Christian

ein fehlendes Klammerpaar ...

18.07.2014 19:31:57

der

Hallo Christian,
... vorhin hatte ich Deine zusätzliche Fragestellung übersehen.
Der Fehler ist eine Unterlassung eines Klammerpaares.
Richtig muss es lauten:

{=MITTELWERT(KGRÖSSTE(WENN(($B$1:$B$25000>HEUTE()-180)*($A$1:$A$25000=E1);$C$1:$C$25000);  ZEILE($A$3:$A$7))) }

Gruß Werner
.. , - ...

AW: ein fehlendes Klammerpaar ...

18.07.2014 19:49:24

Spenski

ah super dank dir :D

AW: ein fehlendes Klammerpaar ...

18.07.2014 20:00:30

Spenski

Hallo werner
auch mit der klammer kommt #Zahl raus wenn die materialnummer weniger als 7 einträge hat. macht ja auch irgendwo sinn wenn der Mittelwert der TOP 3-7 gesucht wird aber nur zb 5 einträge gibt.
wenns hilfreich ist würd ich eine beispieldatei bauen. die original hat mottlerweile 2MB und wäre eher unpraktisch zum hochladen^^
gruss

da bist zunächst Du gefragt ...

19.07.2014 18:57:48

der

Hallo Christian,
... allerdings es bedarf keiner Beispieldatei.
Ich war gestern zu stark fokussiert auf das fehlende Klammerpaar, als dass ich Deine Frage richtig gelesen habe. Natürlich, ergibt die bisherige Formel eine Fehlermeldung, wenn weniger als 7 Werte für die auszuwertende Materialnummer vorhanden sind.
Nun bist Du da aber zunächst gefragt. Soll dann noch ein Mittelwert ermittelt werden und wenn ja von welchen Werten?
Hier mal nur ein Vorschlag, wo eine ("abgestufte") Auswertung vorgenommen wird, für den Fall, wenn mindestens drei Werte vorhanden sind.

	E
3	17,2

Formeln der Tabelle

Zelle	Formel
E3	{=WENN(ZÄHLENWENN(A:A;E1)>2;MITTELWERT(KGRÖSSTE(WENN((B1:B25000>HEUTE()-180)*(A1:A25000=E1); C1:C25000); ZEILE(INDEX(A:A;MIN(ZÄHLENWENN(A:A;E1)-2;3)):INDEX(A:A;MIN(ZÄHLENWENN(A:A;E1); 7))))); "")}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

AW: da bist zunächst Du gefragt ...

20.07.2014 14:15:24

Spenski

Danke werd's morgen testen

Beliebteste Forumthreads (12 Monate)

3-7 grösster eintrag eines bereiches davon mittelw

Forumthread: 3-7 grösster eintrag eines bereiches davon mittelw

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

3-7 grösster eintrag eines bereiches davon mittelw

Forumthread: 3-7 grösster eintrag eines bereiches davon mittelw

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread