Zeile mit Formate automatisch zufügen

Roland · 2015-01-24T23:09:45+00:00

Hallo an alle. Ich bin auf der Suche nach einem Makro, was in meiner Tabelle nach beschreiben einer Zeile, immer wieder eine neue Zeile hinzufügt. Ich habe auch schon etwas gefunden. Aber es ist halt nicht das was ich für mich brauche. Darum hoffe ich auf dieses Forum. Folgendes Problem Ich habe eine Tabelle, in der ich ab Zeile 40 einige Einträge tätigen muss.und zwar in den Spalten A bis H . Die Zeile 40 enthält Formatierungen und auch einige Berechnungsformeln. sobald ich jetzt eine Spalte angefangen habe zu beschreiben, soll sich immer eine weitere Zeile mit allen Formaten und Formeln unten anhängen. Ich würde mich freuen, wenn sich jemand mein Problem anschaut und mir ein geeignetes Makro zeigt. Ich bedanke mich schon mal im Voraus. Bis bald.....Roland

Hallo Roland,
unter Excel 2003 hieß die Funktion, die automatisch den Datenberech inklusive Formaten und Formeln erweitert noch Liste (im Menü Daten oder Einfügen).
Per Makro geht es auch.
Hier eine Beispieldatei mit beiden Varianten erstellt unter Excel 2010 und im 2003er-Format gespeichert.
https://www.herber.de/bbs/user/95240.xls
Gruß
Franz

'Code unter dem Tabellenblatt mit den Eingaben
Private Sub Worksheet_Change(ByVal Target As Range)
'Überwachung von Eingaben in den Spalten B bis F
Dim rngAktiv As Range, rngZelle As Range
Dim StatusCalc As Long
Const bolBlattschutz As Boolean = True 'Auf False ändern, wenn ohne Blattschutz _
gearbeitet werden soll
If Target.Cells.Count = 1 Then
Select Case Target.Row
Case Is >= 40
Select Case Target.Column
Case 2, 3, 4, 5, 6 'Spalten B bis F 'Spalten ggf. anpassen
'Prüfung ob Eingabe in letzter Zeile mit Formel erfolgte
'Die 1 in der folgenden Zeile ggf. ändern, wenn Spalte A keine _
Formel enthält
If Target.Row = Cells(39, 1).End(xlDown).Row Then
With Application
.EnableEvents = False
StatusCalc = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
End With
Set rngAktiv = ActiveCell 'aktive Zelle merken
If bolBlattschutz Then Me.Unprotect
Rows(Target.Row).Copy
Rows(Target.Row).Offset(1, 0).Insert
'8 in folgezeile = letzte Spalte mit Eingabe
For Each rngZelle In Range(Cells(Target.Row + 1, 1), _
Cells(Target.Row + 1, 8))
If Not rngZelle.HasFormula Then
rngZelle.ClearContents
End If
Next
rngAktiv.Select
If bolBlattschutz Then
Me.Protect DrawingObjects:=True, Contents:=True, _
Scenarios:=True
End If
With Application
.EnableEvents = True
.Calculation = StatusCalc
.ScreenUpdating = True
End With
End If
End Select
Case Else
'do nothing
End Select
End If
End Sub

Hallo Roland,
ich hab die Datei entsprechend anepasst.
Damit die Prüfung, wo/ob ggf. eine Leerzeile eingefügt werden soll, einfacher wird habe ich für die Zeile, oberhalb der die Leerzeile eingefügt werden soll, einen Bereichsnamen definiert. Dies über den Namensmanager, damit für den Bereich das Tabellenblatt festgelegt werden kann und nicht automatisch die Arbeitsmappe.
Um das Ganze etwas übersichtlicher zu machen, hab ich die eigentlichen Kopier-Einfüge-Aktionen in ein separates Makro mit entsprechenden Übergabe-Parametern ausgelagert. Der Vorteil dieser Struktur ist, dass man das Kopier-Einfüge-Makro problemlos in andere VBA-Projekte kopieren/integrieren kann.
Auch die Anpassung des Makros in den Case Zeilen dürfte jetzt leichter fallen.
https://www.herber.de/bbs/user/95400.xlsm
Nach dem gleichen Schema kann man ohne Problem auch die anderen beiden Listenbereiche dynamisch machen, so dass keine unnötigen Leerzeilen in der Tabelle vorhanden sind.
https://www.herber.de/bbs/user/95401.xlsm
Gruß
Franz

Zeile mit Formate automatisch zufügen

Forumthread: Zeile mit Formate automatisch zufügen

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Zeile mit Formate automatisch zufügen

Forumthread: Zeile mit Formate automatisch zufügen

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread