Kopieren von einer Tabelle in eine Andere

einer · 2016-01-12T13:10:49+00:00

Hallo, ich habe mal wieder ein Problem. Ich habe in Excel ein Steuerungssheet, auf dem nur ein Button liegt um ein Makro auszuführen. Das Makro macht folgendes: - es erstellt mir ein neues Sheet mit dem Aktuellen Datum - es ruft einen Dialog auf um ein weiteres Workbook zu öffnen. Jetzt möchte ich gerne dass alle Daten aus dem 2. geöffneten Workbook (nur ein Sheet) komplett mit Formatierungen in das (zuvor vom Makro) neu erstellte Sheet (in der Ausgangsdatei) kopieren. Leider stelle ich mich dafür zu blöd an. ich weiß, dass dass ich sowohl in der AUsgangsdatei, als auch in der zu kopierenden Datei die Sheets-Namen einer Variablen zuweisen muss. Aber ich bekomme es einfach nicht sauber hin und das mit dem Kopieren auch nicht. Könnt ihr mir helfen?

Morgen Christian!
dass es ja immer 100 Wege gibt ein Problem/Fragestellung zu lösen. Und diese Tatsache macht es nicht einfacher. Jeder geht wieder etwas anders an die Lösung ran.
Da hast Du Recht; und nix für ungut - ich wollte Dich nicht belehren, war nur gestern mein Eindruck.
Es funktioniert soweit alles wie ich mir das vorgestellt habe.
Das freut mich.
Warum verwendest du eine Konstante für den Tabellennamen der Importdatei? ich kann doch hier sicher auch eine variable nutzen
Ja, eine Variable ist auch möglich; die Frage ist hier aber, ob Dir die mehr hilft. Ich hab jetzt mal auf eine Konstante gesetzt, weil dadurch der Code etwas bequemer anzupassen ist, und es wird sofort im Prozedurkopf klar, dass im folgenden Code immer auf einen bestimmten Blattnamen zugegriffen wird. Wenn bspw. das Quell-Tabellenblatt bisher immer "Tabelle1" hieß, aber dann einigt Ihr Euch auf "Quelle" - so musst Du im Code nicht lange suche, sondern änderst nur den Wert der Konstanten und fertig.
Genauso könnten wir ja auch sagen, wir verwenden keine Konstante für den Blatt-Namen sondern für die Blatt-Indexnummer. Da wär's zB egal, wie das Blatt heißt, wenn nur seine Position in der Mappe immer gleich bleibt; also sinngemäß


Const wsNummer as Byte = 1
ActiveWorkbook.Sheets(wsNummer).Copy after:=.Sheets(.Sheets.Count)

Du sagst aber richtigerweise
Ich verlasse mich nicht drauf, dass der immer gleich ist :)
Sowohl Blatt-Name als auch Position (also Index-Nummer) können sich schnell ändern; ob das auch auf die Blattposition zutrifft musst Du bei Deinen Gegebenheiten (und Kollegen) beurteilen. Aber es bleibt Dir noch die Alternative den Codenamen des gewünschten Tabellenblattes in der Quell-Datei zu nutzen - also den Objekt-Namen des Tabellenblattes in VBA zu ändern:
Userbild

Dann ist sowohl die Position des Blattes als auch der angezeigte Blattname egal, und Du beziehst Dich im Code auf den Codenamen; den Codenamen zu nutzen geht aber nur innerhalb einer Mappe ohne Umwege, bei zwei Mappen dann zB so:

Sub b()
Dim DateiDialog As FileDialog
Dim wbPfad As String
Dim wbQuelle As Workbook
Dim wsQuellBlatt As Worksheet
Dim objDateiSystem As Object
Dim objDatei As Object
'Bildschirm-Aktualisierung ausschalten
Application.ScreenUpdating = False
Set objDateiSystem = CreateObject("Scripting.FileSystemObject")
Set DateiDialog = Application.FileDialog(msoFileDialogFilePicker)
'Dateiauswahl über Dialog...
With DateiDialog
.Title = "Bitte Quell-Arbeitsmappe wählen"
.AllowMultiSelect = False
If .Show  -1 Then
MsgBox "Vorgang abgebrochen", vbInformation
Exit Sub
Else: wbPfad = .SelectedItems(1)
End If
End With
'...mit dem entsprechenden Datei-Pfad
With ThisWorkbook
'...die Quell-Datei öffnen
Set wbQuelle = Workbooks.Open(Filename:=wbPfad)
'...Zugriff auf Datei über Datei-System für Erstelldatum
Set objDatei = objDateiSystem.getfile(wbQuelle.FullName)
'...das Quell-Blatt über den Code-Namen definieren...
Set wsQuellBlatt = BlattCodeHolen(ActiveWorkbook, "Vorlage")
'...und in diese Mappe ans Ende kopieren
wsQuellBlatt.Copy after:=.Sheets(.Sheets.Count)
'...dem kopierten Blatt das Erstelldatum der Quell-Datei als Name übergeben
.Sheets(.Sheets.Count).Name = Left(objDatei.DateCreated, 10)
'...Quell-Datei schließen, Änderungen speichern
wbQuelle.Close savechanges:=True
End With
'Bildschirm-Aktualisierung einschalten
Application.ScreenUpdating = True
End Sub
Function BlattCodeHolen(wb As Workbook, BlattCode As String) As Worksheet
' Funktion benötigt um zwischen zwei Mappen auf den Blatt-CodeNamen
' referenzieren zu können
Dim ws As Worksheet
'Blätter in Ziel-Mappe durchgehen...
For Each ws In wb.Worksheets
'Und Blatt-Namen auslesen wenn
'Code-Name übereinstimmt
If ws.CodeName = BlattCode Then
Set BlattCodeHolen = ws
Exit For
End If
Next
End Function

In diesem Code gehe ich jetzt davon aus, dass das Quell-Blatt im CodeNamen "Vorlage" getauft wird.
Passt?
LG
Michael

Christian,

.ActiveSheet.Columns("B:B").Delete

aber

.ActiveSheet.Columns(2).Delete

würde genauso funktionieren.
im Code (beziehe mich auf den ersten von mir geposteten Code, ohne Zugriff auf Blatt-Codenamen):

Sub b()
Dim DateiDialog As FileDialog
Dim wbPfad As String
Dim wbQuelle As Workbook
Const wsName As String = "Tabelle1"
Dim objDateiSystem As Object
Dim objDatei As Object
'Bildschirm-Aktualisierung ausschalten
Application.ScreenUpdating = False
Set objDateiSystem = CreateObject("Scripting.FileSystemObject")
Set DateiDialog = Application.FileDialog(msoFileDialogFilePicker)
'Dateiauswahl über Dialog...
With DateiDialog
.Title = "Bitte Quell-Arbeitsmappe wählen"
.AllowMultiSelect = False
If .Show  -1 Then
MsgBox "Vorgang abgebrochen", vbInformation
Exit Sub
Else: wbPfad = .SelectedItems(1)
End If
End With
'...mit dem entsprechenden Datei-Pfad
With ThisWorkbook
'...die Quell-Datei öffnen
Set wbQuelle = Workbooks.Open(Filename:=wbPfad)
'...Zugriff auf Datei über Datei-System für Erstelldatum
Set objDatei = objDateiSystem.getfile(wbQuelle.FullName)
'...das gewünschte Blatt in _diese_ Datei kopieren
'--> gesuchter Blattname im Quell-Blatt als Konstante definiert (s.o.)
ActiveWorkbook.Sheets(wsName).Copy after:=.Sheets(.Sheets.Count)
'...dem kopierten Blatt das Erstelldatum der Quell-Datei als Name übergeben
.Sheets(.Sheets.Count).Name = Left(objDatei.DateCreated, 10)
'...Spalten B, D im kopierten Blatt löschen
.ActiveSheet.Columns("B:B").Delete
.ActiveSheet.Columns("D:D").Delete
'...Quell-Datei schließen, Änderungen speichern
wbQuelle.Close savechanges:=True
End With
'Bildschirm-Aktualisierung einschalten
Application.ScreenUpdating = True
End Sub

Der "." (Punkt) vor dem ActiveSheet ist nicht zufällig da ;-), eingebettet in With-Anweisung. Aber das kannst Du ja evtl. mal recherchieren? ;-)
Passt?
LG
Michael

Kopieren von einer Tabelle in eine Andere

Forumthread: Kopieren von einer Tabelle in eine Andere

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Kopieren von einer Tabelle in eine Andere

Forumthread: Kopieren von einer Tabelle in eine Andere

15 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread