Doppelte suchen, mit MSGBox anzeigen

Peter · 2016-05-27T09:49:30+00:00

Hallo zusammen In Spalte 5, ab Zeile 4 ist jeweils eine Datensatznummer eingetragen. Wenn ein neuer Datensatz eingetragen wurde, soll nach der Eingabe automatisch überprüft werden, ob dieser Datensatz (Nummer) schon vorhanden ist. Ist dies der Fall, dann soll ein PopUp erscheinen mit dem Text "ACN bereits vorhanden"und idealerweise mit der Angabe der Excel-Zeilennummer in der, der Datensatz vorhanden ist. Wie könnte der Code aussehen, hat jemand eine Idee? Danke Mit freundlichen Grüssen, Peter

Hallo,
so:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objCell As Range
    If Target.Column = 5 And Target.Row > 3 And Target.Count = 1 Then
        Set objCell = Columns(5).Find(What:=Target.Value, _
            After:=Cells(3, 5), LookIn:=xlValues, LookAt:=xlWhole)
        If Not objCell Is Nothing Then
            If objCell.Address <> Target.Address Then
                Call MsgBox("ACN bereits vorhanden. Zeile: " & CStr(objCell.Row), vbExclamation, "Hinweis")
                With Application
                    .EnableEvents = False
                    Call .Undo
                    .EnableEvents = True
                End With
            End If
            Set objCell = Nothing
        End If
    End If
End Sub

Gruß
Nepumuk

Hallo Thomas,
dann so:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objCell As Range
    If Target.Column = 5 And Target.Row > 3 And Target.Count = 1 Then
        Set objCell = Columns(5).Find(What:=Target.Value, _
            After:=Cells(3, 5), LookIn:=xlValues, LookAt:=xlWhole)
        If Not objCell Is Nothing Then
            If objCell.Address <> Target.Address Then
                If MsgBox("ACN bereits vorhanden. Zeile: " & CStr(objCell.Row) & vbLf & vbLf & _
                    "Eingabe löschen?", vbExclamation Or vbYesNo, "Hinweis") = vbYes Then
                    With Application
                        .EnableEvents = False
                        Call .Undo
                        .EnableEvents = True
                    End With
                Else
                    Target.Interior.Color = vbRed
                    objCell.Interior.Color = vbRed
                End If
            End If
            Set objCell = Nothing
        End If
    End If
End Sub

Gruß
Nepumuk

Doppelte suchen, mit MSGBox anzeigen

Forumthread: Doppelte suchen, mit MSGBox anzeigen

23
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Doppelte suchen, mit MSGBox anzeigen

Forumthread: Doppelte suchen, mit MSGBox anzeigen

23 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

23
Beiträge zum Forumthread

Beiträge zu diesem Forumthread