VBA Excel - Datenreihen bestimmen - in Dia einfüge

Andre · 2016-12-18T20:11:48+00:00

Guten Abend. Ich möchte aus einem Excel-Blatt Datenreihen(Spalte 1 bis 5) in 5 einzelne Diagramme einfügen. Die Reihen werden automatisch gezählt, da nach einer Messreihe neue Daten hinzukommen können. Anschließend werden die Spaltennummer durch eine For-Schleife gesetzt, dann sollen alle 5 Diagramme erstellt werden. Leider kann ich in den Sourcebereich nicht meine Zaehler verwenden. Wenn ich die Zahlen eintrage geht es. Das Tabellenblatt existiert so. Sub Diagramm() Dim intZaehler1 As Integer Dim intCountRows as Interger intCountRows = Cells(Rows.Count, 1).End(xlUp).Row For intZaehler1 = 1 to 5 With ActiveChart.SeriesCollection.NewSeries .Name = strDiagrammName(intZaehler1) .SetSourceData Source:=Sheets("Tabelle1").Range(Cells(3, _ intZaehler1 + 29), Cells(intCountRows, intZaehler1 + 29)) End With Next intZaehler End Sub Würde mich sehr freuen, wenn mir jemand weiterhelfen könnte.

Hallo André,
wenn ich dein Problem richtig verstanden habe, dann kannst du das mit dem folgenden Programm machen:


Sub Diagramme_erstellen()
Dim breite As Single
Dim ch As Chart
Dim höhe As Single
Dim links As Single
Dim lngCountRows As Long
Dim oben As Single
Dim rng As Range
Dim sh As Shape
Dim spalteX As Long
Dim spalteY As Long
Dim wsD As Worksheet
Dim wsC As Worksheet
Set wsD = ThisWorkbook.Worksheets("Daten")
Set wsC = ThisWorkbook.Worksheets("Diagramme")
' Vorhandene Diagramme löschen
For Each sh In wsC.Shapes
sh.Delete
Next sh
spalteX = 29
lngCountRows = wsD.Cells(wsD.Rows.Count, "AC").End(xlUp).Row
oben = 20
links = 20
wsC.Activate
For spalteY = 30 To 34
Set rng = Union(wsD.Range(wsD.Cells(2, spalteX), wsD.Cells(lngCountRows, spalteX)), _
wsD.Range(wsD.Cells(2, spalteY), wsD.Cells(lngCountRows, spalteY)))
Set sh = wsC.Shapes.AddChart2(Style:=240, _
XlChartType:=xlXYScatterLines, _
Left:=links, _
Top:=oben)
links = links + 20 + sh.Width
sh.Select
ActiveChart.SetSourceData Source:=rng
Next spalteY
End Sub

Die Daten stehen im Blatt "Daten" und die Diagramme werden im Blatt "Diagramme" erzeugt.
Viele Grüße
Dieter
Hochgeladene Datei: https://www.herber.de/bbs/user/110139.xlsm

Hallo André,
mit dieser Schleife zählst du nicht die Diagramme, sondern sämtliche Shape-Objekte. Das sind verschiedenste Objekte, die auf die Excel-Oberfläche geklebt werden (Bilder, Grafiken, Steuerelemente, Diagramme, Kommentare, Textfelder).
Karin hat ja einen Vorschlag gemacht, um die Diagramme zu zählen und sehr elegant auch zu löschen.
Deine Frage zu den "IF-Schleifen, bei denen Bedingungen nicht passen" habe ich nicht verstanden. Könntest du das noch präzisieren?
An meinem Programmvorschlag gefielen mir "Select" und "ActiveChart" nicht, ich konnte das aber nicht auf die Schnelle eliminieren. Jetzt habe ich das geschafft und auch den Löschvorschlag von Karin übernommen. Mein Programm sieht jetzt folgendermaßen aus:


Sub Diagramme_erstellen()
Dim breite As Single
Dim cho As Object
' Wenn cho als ChartObject deklariert wird, dann funktioniert unten die Set-Anweisung nicht!
Dim höhe As Single
Dim links As Single
Dim lngCountRows As Long
Dim oben As Single
Dim rng As Range
Dim sh As Shape
Dim spalteX As Long
Dim spalteY As Long
Dim wsD As Worksheet
Dim wsC As Worksheet
Set wsD = ThisWorkbook.Worksheets("Daten")
Set wsC = ThisWorkbook.Worksheets("Diagramme")
' Vorhandene Diagramme löschen
If wsC.ChartObjects.Count > 0 Then
wsC.ChartObjects.Delete
End If
spalteX = 29
lngCountRows = wsD.Cells(wsD.Rows.Count, "AC").End(xlUp).Row
oben = 20
links = 20
For spalteY = 30 To 34
Set rng = Union(wsD.Range(wsD.Cells(2, spalteX), wsD.Cells(lngCountRows, spalteX)), _
wsD.Range(wsD.Cells(2, spalteY), wsD.Cells(lngCountRows, spalteY)))
Set cho = wsC.Shapes.AddChart2(Style:=240, _
XlChartType:=xlXYScatterLines, _
Left:=links, _
Top:=oben)
links = links + 20 + cho.Width
cho.Chart.SetSourceData Source:=rng
Next spalteY
wsC.Activate
End Sub

Ist für deine Anwendung nicht so wesentlich, aber ich versuche, die genannten und verwandte Begriffe zu vermeiden.
Bei weiteren Fragen ist sicherlich eine Beispielmappe hilfreich, wie Karin schon gesagt hat. Die Daten können verändert und/oder anonymisiert sein.
Viele Grüße
Dieter

VBA Excel - Datenreihen bestimmen - in Dia einfüge

Forumthread: VBA Excel - Datenreihen bestimmen - in Dia einfüge

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

VBA Excel - Datenreihen bestimmen - in Dia einfüge

Forumthread: VBA Excel - Datenreihen bestimmen - in Dia einfüge

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread