HTML Tabelle in Outlook erzeugen

Hm, da wurde wohl aufgrund des HTML Syntax etwas verhauen...
Hinter "Tabelle & Spalte" = folgt der Code für eine HTML Tabelle; wie das genau aussieht sollte aber für meine Frage nicht relevant sein.

Hallo,
kannst mal diesen Code testen.
Tabelle wo die Daten sind musst du natürlich anpassen!

Sub Makro1()
Dim sHTML$
Dim lngRow&, lngCol&
Dim MyOutApp As Object, MyMessage As Object

With Tabelle1 'Tabelle anpassen 
    lngRow = .Cells(.Rows.Count, 1).End(xlUp).Row 'letzte Zeile 
    lngCol = .Cells(1, .Columns.Count).End(xlToLeft).Column 'letzte Spalte 
    sHTML = RangeToHTML(.Range("A1", .Cells(lngRow, lngCol))) 'Range in HTML 
End With

Set MyOutApp = CreateObject("Outlook.Application")
Set MyMessage = MyOutApp.CreateItem(0)
With MyMessage
    .To = "Hier kommt die Adresse rein"
    .Subject = "hier der Betreff"
    .htmlbody = sHTML
'    .Attachments.Add 'für Anlagen 
    .Importance = 2 'Wichtigkeit hoch 
    .Display
    '.Send  'Hier wird die Mail gesendet 
End With

Set MyOutApp = Nothing
Set MyMessage = Nothing
End Sub

Function RangeToHTML(rng As Range) As String
Dim sPath$
Dim F%

sPath = ThisWorkbook.Path
sPath = sPath & IIf(Right$(sPath, 1) <> "\", "\", "")
sPath = sPath & "TmpHtml.html"

With ThisWorkbook.PublishObjects.Add(xlSourceRange, sPath, _
    rng.Parent.Name, rng.Address, xlHtmlStatic, "", "")
    .Publish (True)
    .AutoRepublish = False
End With

F = FreeFile
Open sPath For Binary As #F
RangeToHTML = Space$(LOF(F))
Get #F, , RangeToHTML
Close
Kill sPath
End Function

Gruß Tino

Hallo Tino
Prinzipiell funktioniert der Code, aber ich verwende die Tabelle eigentlich etwas anders.
Dein Code "kopiert" ja die Zellen aus Excel, ich habe vorher die Tabelle mit Daten aus verschiedenen Zelllen befüllt, da ich nicht genau das gleiche Layout in der E-Mail haben möchte.
Das könnte ich jedoch anpassen.
Aber ich benutze in Excel noch in verschiedenen Zellen Steuerelemente, die beim Kopieren dann nicht übernommen werden, diese (bzw. deren ausgewählter Inhalt) fehlen dann in der Mail, das ist problematisch...

Hallo,
kenne Deine Tabelle nicht und auch nicht was du in der Mail haben willst und was nicht.
Ich lass die Frage offen stehen.
Gruß Tino

Tino, dein Code kopiert die Tabelle mit einem "komischen" Einzug in die E-Mail.
Die Tabelle steht dadurch immer in der Mitte.
Kann man das ändern, bzw. wie/wo?
Danke & Gruss
Katie

Hallo,
schreibe zusätzlich nach der Code-Zeile

sHTML = RangeToHTML(.Range("A1", .Cells(lngRow, lngCol)))

diese

sHTML = Replace(sHTML, "align=center", "align=left")

Gruß Tino

Tino, dein Code kopiert die Tabelle mit einem "komischen" Einzug in die E-Mail.
Die Tabelle steht dadurch immer in der Mitte.
Kann man das ändern, bzw. wie/wo?
Danke & Gruss
Katie

…ZusatzFunktion, Katie,
die kannst du nicht so einfach in HTML übernehmen. Warum benutzt du nicht die von MS vorgesehene HTML-Ausgabe der Datei? Das wird dann sehr viel mehr, könnte aber eher fktsfähig sein…
Ansonsten gibt's ja noch die Möglichkeit, die Xl-Datei als Anlage zu versenden.
Morrn, Luc :-?