Zeitformat ändern

Forumthread: Zeitformat ändern

Zeitformat ändern

27.07.2017 21:36:58

Jenny

Hallo an euch alle,
fällt euch eine Formel ein, die Fahrzeiten wie sie bei Google Maps ausgegeben werden, also z.B. 4 Std. 10 Min. in das Format hh:mm umwandeln kann?
Danke für euren Rat
Jenny

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeitformat ändern

27.07.2017 21:50:52

Sepp

Hallo Jenny,
so?
Tabelle1

	A	B
1	4 Std. 10 Min.	04:10:00
2	3 Std. 32 Min.	03:32:00

Formeln der Tabelle

Zelle	Formel
B1	=ZEITWERT(WECHSELN(WECHSELN(A1;" Min.";""); " Std. ";":"))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Sepp

AW: Zeitformat ändern

27.07.2017 21:55:48

Jenny

Hallo Sepp,
leider nicht so ganz. Wenn es eine Minuten und eine Stundenangabe gibt, funktioniert die Formel, aber Google lässt wenn die Zeit genau 4 Stunden beträgt die Minutenangabe weg, es steht also nur 4 Std. da, genauso wie die Stundenangabe weggelassen wird, wenn die Zeit unter 1 Stunde beträgt.
In diesen Fällen gibt die Formel #WERT! aus.
Gruß und schonmal danke
Jenny

Hättest du das gleich geschrieben, ...

28.07.2017 02:49:13

Luc:-?

…Jenny,
hätte dir Sepp sicher eine andere Fml angeboten, zB folgende (klassische), und du hättest das Problem bereits gelöst und deshalb ruhig schlafen können: ;-]
=--WECHSELN(WECHSELN("h:m";"h";WENNFEHLER(LINKS(A1;FINDEN(" Std.";A1)-1);0));"m"; RECHTS("00"&WENNFEHLER(TEIL(A1;FINDEN(" Std.";A1)+6;2);LINKS(A1;2));2))
Morrn, Luc :-?

ein paar Zeichen weniger

28.07.2017 06:51:04

... aber auch nicht einfacher:
=1*WECHSELN(WECHSELN(WENN(RECHTS(A1;2)="d.";LINKS(A1;2)&":0";WENN(ISTZAHL(SUCHEN("s";A1));A1; "0:"&LINKS(A1;2)));" Std. ";":");"Min.";)
WF

AW: ein paar Zeichen weniger

28.07.2017 07:44:09

Jenny

sorry ich hätte wirklich etwas ausführlicher beschreiben können.
Eine ruhige Nacht hatte ich trotzdem.
So klappt es auf jeden Fall,
danke
Jenny

Na, denn iss ja jut! Aber es gibt natürlich ...

28.07.2017 23:31:49

Luc:-?

…noch mehr Möglichkeiten, Jenny;
hier mal eine Zusammenstellung inkl aller bisherigen (blaue Schrift) ohne Sepps:

4 Std. 10 Min.

4h 10m

4 Std.

4h 0m

10 Min.

0h 10m

25 Std. 1 Min.

25h 1m

(ohne UDFs)

(WF)

(1 UDF)

(2 UDFs)

(1 UDF)

Formellänge:

153

139

135

133

Formeln:

Format (B1:H4): [h]\h m\m

B1[:B4]:=--WECHSELN(WECHSELN("h:m";"h";WENNFEHLER(LINKS(A1;FINDEN(" Std.";A1)-1);0));"m"; RECHTS("00"&WENNFEHLER(TEIL(A1;FINDEN(" Std.";A1)+6;2);LINKS(A1;2));2))

C1[:C4]:=--WECHSELN(WAHL((FINDEN("S";A1&"S")<LÄNGE(A1))+2*(FINDEN("M";A1&"M")<LÄNGE(A1));WECHSELN(A1;" Std.";":0");"0:"&A1;WECHSELN(A1;" Std. ";":"));" Min.";"")

D1[:D4]:=--WECHSELN(WAHL(ISTZAHL(FINDEN("S";A1))+2*ISTZAHL(FINDEN("M";A1));WECHSELN(A1;" Std.";":0");"0:"&A1;WECHSELN(A1;" Std. ";":"));" Min.";"")

E1[:E4]:=--WECHSELN(WECHSELN(WENN(RECHTS(A1;2)="d.";LINKS(A1;2)&":0";WENN(ISTZAHL(SUCHEN("s";A1));A1; "0:"&LINKS(A1;2)));" Std. ";":");"Min.";)

F1[:F4]:=--WECHSELN(WAHL(VERGLEICH(MaskOn(A1;"gb");{"S M"."S"."M"};);WECHSELN(A1;" Std. ";":");WECHSELN(A1;" Std.";":0");"0:"&A1);" Min.";"")

G1[:G4]:=--MaskOn(WAHL(VLike(A1;"*S*")+2*VLike(A1;"*M*");A1&":0";"0:"&A1;WECHSELN(A1;". ";":"));"num";":")

H1[:H4]:=--(WENN(MaskOn(A1;"gb")="M";"0:";"")&WECHSELN(MaskOn(A1;"num";".");" .";":")&0)

Die grünen (mit grüner Schrift) enthalten folgende UDFs:
MaskOn: https://www.herber.de/cgi-bin/callthread.pl?index=1344962#1345181
VLike (o. VPairs): https://www.herber.de/cgi-bin/callthread.pl?index=1247144#1247699
Luc :-?

Beliebteste Forumthreads (12 Monate)

Forumthread: Zeitformat ändern

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread