Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1572to1576
1572to1576
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Shell("cmd") Ersatz:zum Start von 64Bit-"cmd"

Forumthread: Shell("cmd") Ersatz:zum Start von 64Bit-"cmd"

Shell("cmd") Ersatz:zum Start von 64Bit-"cmd"
21.08.2017 13:53:41
64Bit-"cmd"
Hallo zusammen,
Ein exotischer Titel, bedarf genauerer Erklärung.
Voraussetzung: Windows (7) - 64Bit / Excel (2010) 32-Bit
Wenn ich per VBA-Shell Funktion ein Programm starte, läuft diese automatisch in einer cmd.exe *32 (siehe Taskmanager). Das Java-Programm das ich starten möchte, läuft aber nur richtig, wenn ich es in einer nativen (d.h. 64Bit) cmd.exe starten kann.
Egal, was ich bis jetzt versucht habe: Direkter Aufruf via
lngPid = Shell("cmd")
lngPid = Shell("C:\Windows\system32\cmd")
lngPid = Shell("C:\Windows\sysWOW64\cmd")
Applicatio.OnTime aller Varianten
es wird immer die cmd.exe *32 gestartet.
Vielleicht kennt ein API-Profi (wie z.B. Nepumuk) einen Trick, wie ich aus einer 32Bit-Office Umgebung die 32Bit Schranke durchbrechen und eine 64Bit cmd.exe starten kann?
Vielen Dank und Gruess Hansueli
Anzeige

10
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Shell("cmd") Ersatz:zum Start von 64Bit-"cmd"
21.08.2017 14:00:47
64Bit-"cmd"
Hallo!
Lege mal eine Verknüpfung zur 64-bit-Kommandozeile an (z.B. auf dem Desktop) und führe die Verknüpfung per VBA aus.
Gruß, René
Verknüpfung startet ebenfalls cmd.exe *32
21.08.2017 14:07:48
EtoPHG
Hallo René
Windows ist nicht so einfach auszutricksen:
Starte ich direkt über die Verknüpfung wird cmd.exe (native) gestartet.
Starte ich über VBA-Shell wird cmd.exe *32 gestartet.
Guter Rat ist anscheinend teurer!
Gruess Hansueli
Anzeige
64bit cmd.exe aus office-32bit starten ist offen!
21.08.2017 14:08:37
EtoPHG

AW: 64bit cmd.exe aus office-32bit starten ist offen!
21.08.2017 14:22:42
Nepumuk
Hallo Hansueli,
teste mal:
Option Explicit

Public Declare PtrSafe Function Wow64EnableWow64FsRedirection Lib "kernel32.dll" ( _
    ByVal Enable As Boolean) As Boolean

Public Sub Test()
    Call Wow64EnableWow64FsRedirection(False)
    Call Shell("C:\WINDOWS\System32\cmd.exe")
    Call Wow64EnableWow64FsRedirection(True)
End Sub

Gruß
Nepumuk
Anzeige
Das funktioniert.. cmd.exe 64Bit wird gestartet
21.08.2017 14:59:27
EtoPHG
Danke Nepumuk,
Ich hab gewusst, du hast da was im Ärmel...
Gruess Hansueli
AW: Das funktioniert.. cmd.exe 64Bit wird gestartet
21.08.2017 15:08:36
mumpel
Eine kleine Erweiterung von mir. Mit Unterscheidung zwischen 32-bit und 64-bit. Und da bei "Shell" das Fenster nicht in den Vordergrund rückt arbeite ich mit ShellExecute.
Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
                                                       (ByVal hWnd As Long, _
                                                        ByVal lpOperation As String, _
                                                        ByVal lpFile As String, _
                                                        ByVal lpParameters As String, _
                                                        ByVal lpDirectory As String, _
                                                        ByVal nshowcmd As Long) As Long
  
Public Declare PtrSafe Function Wow64EnableWow64FsRedirection Lib "kernel32.dll" _
                                                       (ByVal Enable As Boolean) As Boolean
    
Public Const SW_HIDE = 0            'Alternative: vbHide, Fenster versteckt öffnen 
Public Const SW_MAXIMIZE = 3        'Alternative: vbMaximizedFocus, Fenster maximiert öffnen 
Public Const SW_MINIMIZE = 6        'Alternative: vbMinimizedNoFocus, Fenster minimiert öffnen 
Public Const SW_RESTORE = 9
Public Const SW_SHOW = 5
Public Const SW_SHOWDEFAULT = 10
Public Const SW_SHOWMAXIMIZED = 3
Public Const SW_SHOWMINIMIZED = 2   'Alternative: vbMinimizedFocus 
Public Const SW_SHOWMINNOACTIVE = 7
Public Const SW_SHOWNA = 8
Public Const SW_SHOWNOACTIVATE = 4  'Alternative: vbNormalNoFocus 
Public Const SW_SHOWNORMAL = 1      'Alternative: vbNormalFocus 

  
Public Sub RunCMD64()

 Dim objWMI        As Object
 Dim objWMIe       As Object
 Dim obj           As Object
 Dim sql           As String
 Dim strSystemTyp  As String
 Dim strComputer   As String
 Dim varSystemTyp  As Variant
 
 strComputer = "."
 
 Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" _
                        & strComputer & "\root\cimv2")
  
 sql = "SELECT * FROM Win32_ComputerSystem"
 
 Set objWMIe = objWMI.ExecQuery(sql)
 
 For Each obj In objWMIe
     strSystemTyp = obj.SystemType & vbCrLf
 Next obj
 
  varSystemTyp = Split(strSystemTyp, "-")
  
  
  If varSystemTyp(0) = "x64" Then
     Call Wow64EnableWow64FsRedirection(False)
     Call ShellExecute(0, "open", "C:\Windows\system32\cmd.exe", _
                       vbNullString, vbNullString, SW_SHOW)
     Call Wow64EnableWow64FsRedirection(True)
  Else
     Call ShellExecute(0, "open", "C:\Windows\SysWOW64\cmd.exe", _
                       vbNullString, vbNullString, SW_SHOW)
  End If
  
End Sub


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

Anzeige
Nachtrag
21.08.2017 15:17:13
mumpel
Braucht man die Prüfung überhaupt?
AW: Nachtrag
21.08.2017 15:24:00
Nepumuk
Hallo René,
32 / 64 Bit Unterscheidung mache ich so (ab Office 2010):
Option Explicit

Private Declare PtrSafe Function GetProcAddress Lib "kernel32.dll" ( _
    ByVal hModule As LongPtr, _
    ByVal lpProcName As String) As LongPtr
Private Declare PtrSafe Function GetModuleHandleA Lib "kernel32.dll" ( _
    ByVal lpModuleName As String) As LongPtr
Private Declare PtrSafe Function IsWow64Process Lib "kernel32.dll" ( _
    ByVal hProcess As LongPtr, _
    ByRef Wow64Process As LongPtr) As Long
Private Declare PtrSafe Function GetCurrentProcess Lib "kernel32.dll" () As LongPtr

Public Sub Test()
    Dim lngptrHandle As LongPtr, lngptrAddress As LongPtr, lngptrIsWow64 As LongPtr
    lngptrHandle = GetModuleHandleA("kernel32.dll")
    lngptrAddress = GetProcAddress(lngptrHandle, "IsWow64Process")
    If lngptrAddress > 0 Then Call IsWow64Process(GetCurrentProcess, lngptrIsWow64)
    If lngptrIsWow64 = 0 Then
        MsgBox "32"
    Else
        MsgBox "64"
    End If
End Sub

WMI ist mir zu langsam.
Gruß
Nepumuk
Anzeige
AW: Nachtrag
21.08.2017 15:31:10
mumpel
Danke! Das verkürzt den Code um "ein paar" Zeilen.
Information: Abgelöste Wow64-Redirection
22.08.2017 15:29:34
EtoPHG
Hallo zäme,
Mein Problem konnte ich lösen.
Microsoft hat aber die API-Funktion Wow64EnableWow64FsRedirection durch 2 neue Funktionen ersetzt. Das Ganze funktioniert jetzt mit den neuen Funktionen so (Windows 64Bit Command Process aus 32Bit Umgebung starten): 
' Disable Redirection
Public Declare PtrSafe Function Wow64DisableWow64FsRedirection Lib "kernel32.dll" ( _
ByVal Enable As Boolean) As Boolean
' Revert Disable (re-Enable) Redirection
Public Declare PtrSafe Function Wow64RevertWow64FsRedirection Lib "kernel32.dll" ( _
ByVal Enable As Boolean) As Boolean
Public lngPid As Long       ' PID des Command Processors
' Starts a 64Bit Command Process out of a 32Bit Office Environment
Sub Start64BitCmdProcess()
Dim vRedirected
If lngPid > 0 Then
MsgBox "The 64Bit Command Process is already running!", vbCritical
Exit Sub
End If
vRedirected = Wow64DisableWow64FsRedirection(vRedirected)
lngPid = Shell("cmd", vbNormalFocus)
vRedirected = Wow64RevertWow64FsRedirection(vRedirected)
If lngPid > 0 Then MsgBox "Command Process started as PID " & lngPid
End Sub
' Stopps the started Command Process based on its PID
Sub Stop64BitCmdProcess()
If lngPid > 0 Then
Shell ("taskkill /PID " & lngPid)
MsgBox "Command Process " & lngPid & " killed!"
lngPid = 0
End If
End Sub
Gruess Hansueli
Anzeige
;

Forumthreads zu verwandten Themen

64 Bit vba Problem
Bernhard

Hallo,
habe ein vba, welches in Excel 2010 32 bit wunschgemäß läuft.
Nun habe ich auf Excel 2016 64 bit upgedatet, und in dieser Version reagiert das vba nicht auf folgende Code-Zeile:
Sheets("Grafik").select
Das sheet "grafik" wird leider nicht angezeigt, während das 64 bit vba...
15.06.2016 14:10:31
Thread-ID: 1499060
3 Beiträge
VBA-Fehler bei 64-bit-Excel
Gunter

Servus alle zusammen,
bei uns sind einige Rechner wegen CAD-Anwendungen bereits auf Windows 7 64-bit/Excel 2010 64- _ bit umgestellt. Folgender Befehl funktioniert auf Windows 7 32-bit/Excel 2010 32-bit auf allen und unter Windows 7 64-bit/Excel 2010 64-bit auf fast allen Rechnern problemlo...
11.09.2017 15:21:39
Thread-ID: 1579772
10 Beiträge
VBA 64bit
Pepi

Hallo Zusammen
Ich habe von Office 2010 auf Office 2019 Student (neuer Notebook - HP-Pavilion i7-8650) gewechselt. Jetzt bekomme ich beim öffnen meiner Tabellen Fehlermeldungen. Offenbar kann man das wie nachfolgend mit einer Versionsabfrage machen. Leider erscheint die else-Zeile rot, was...
06.06.2019 14:32:23
Thread-ID: 1696488
6 Beiträge
VBA 32 Bit Datei / 64 Bit Auto (zoom)?
werner
Moin liebe Excelfreunde,
Ich habe keine Ahnung davon! -> VBA 32 Bit Datei / 64 Bit Auto (zoom)
Ich habe eine alte Exceldatei "Schwerpunktberechnung" aber auf 32 Bit geschrieben, ich habe Windows 10 mit 64 Bit Betriebssystem.
Hat jemand "Muße" dazu es umzuschreiben?
Anbei Datei
07.10.2022 07:46:07
Thread-ID: 1901886
2 Beiträge
Anzeige

Infobox / Tutorial

64-Bit CMD aus einer 32-Bit Excel VBA Umgebung starten

Schritt-für-Schritt-Anleitung

  1. Verwende die Wow64-API: Um eine 64-Bit cmd.exe aus einer 32-Bit Excel VBA Umgebung zu starten, benötigst du die Wow64EnableWow64FsRedirection-Funktion. Diese hilft dir, die Redirektion zu deaktivieren.

  2. Füge den folgenden Code in dein Modul ein:

    Option Explicit

Public Declare PtrSafe Function Wow64DisableWow64FsRedirection Lib "kernel32.dll" ( _
ByVal Enable As Boolean) As Boolean

Public Declare PtrSafe Function Wow64RevertWow64FsRedirection Lib "kernel32.dll" ( _
ByVal Enable As Boolean) As Boolean

Public lngPid As Long

Sub Start64BitCmdProcess()
   Dim vRedirected
   If lngPid > 0 Then
       MsgBox "Der 64-Bit Command-Prozess läuft bereits!", vbCritical
       Exit Sub
   End If
   vRedirected = Wow64DisableWow64FsRedirection(vRedirected)
   lngPid = Shell("C:\Windows\system32\cmd.exe", vbNormalFocus)
   vRedirected = Wow64RevertWow64FsRedirection(vRedirected)
   If lngPid > 0 Then MsgBox "Command-Prozess gestartet mit PID " & lngPid
End Sub

  3. Führe die Subroutine aus: Du kannst die Subroutine Start64BitCmdProcess ausführen, um die 64-Bit cmd.exe zu starten.

Häufige Fehler und Lösungen

  • Problem: Die cmd.exe startet immer in der 32-Bit-Version.

    • Lösung: Stelle sicher, dass du die Wow64DisableWow64FsRedirection-Funktion korrekt anwendest, um die Redirektion zu deaktivieren, bevor du die cmd.exe startest.

  • Problem: Fehlermeldung beim Ausführen des Codes.

    • Lösung: Überprüfe, ob dein Excel als 32-Bit-Anwendung läuft. Die oben genannten Funktionen sind nur in einer 64-Bit-Umgebung wirksam.

Alternative Methoden

  • Verknüpfung verwenden: Du kannst auch eine Verknüpfung zur 64-Bit-Kommandozeile erstellen und diese über VBA mit der ShellExecute-Funktion ausführen:

    Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
   ByVal hWnd As Long, _
   ByVal lpOperation As String, _
   ByVal lpFile As String, _
   ByVal lpParameters As String, _
   ByVal lpDirectory As String, _
   ByVal nShowCmd As Long) As Long

Sub RunCmdViaShellExecute()
   ShellExecute 0, "open", "C:\Path\To\Your\Shortcut.lnk", vbNullString, vbNullString, 1
End Sub

Praktische Beispiele

  • Beispiel einer vollständigen Subroutine:

    Sub Run64BitCommand()
   Call Start64BitCmdProcess
   ' Hier können weitere Shell-Befehle hinzugefügt werden
End Sub

  • Stoppen des Prozesses:

    Sub Stop64BitCmdProcess()
   If lngPid > 0 Then
       Shell ("taskkill /PID " & lngPid)
       MsgBox "Command-Prozess " & lngPid & " beendet!"
       lngPid = 0
   End If
End Sub

Tipps für Profis

  • Nutze die ShellExecute-Funktion: Diese Funktion kann verwendet werden, um sicherzustellen, dass das Fenster der cmd.exe im Vordergrund erscheint, was mit der Shell-Funktion nicht immer funktioniert.

  • VBA für Batch-Dateien verwenden: Du kannst auch Batch-Skripte erstellen und diese über Shell oder ShellExecute aufrufen, um komplexe Aufgaben zu automatisieren.

FAQ: Häufige Fragen

1. Warum kann ich die 64-Bit cmd.exe nicht direkt mit Shell starten?
Die 32-Bit-Version von Excel kann nur 32-Bit-Prozesse starten. Um einen 64-Bit-Prozess zu starten, musst du die Wow64-Redirection deaktivieren.

2. Gibt es eine Möglichkeit, die Version von Excel zu überprüfen?
Ja, du kannst die Funktion Application.Version verwenden, um die aktuelle Version abzurufen.

3. Funktioniert das auch in Excel 365?
Ja, die oben genannten Lösungen gelten auch für Excel 365, solange du die entsprechende Version (32-Bit oder 64-Bit) verwendest.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige