Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1624to1628
1624to1628
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Diagramm Farben mit Makro verändern

Forumthread: Diagramm Farben mit Makro verändern

Diagramm Farben mit Makro verändern
28.05.2018 10:02:43
Sarah
Guten Morgen :-)
Hier eine Beispiel-Tabelle: https://www.herber.de/bbs/user/121853.xlsm
Wenn Excel Diagramme erstellt, werden die Farben pro Wert/Kategorie ja zufällig ausgewählt. Ich hätte aber gerne für eine Kategorie, der ein Wert zugeordnet ist, immer die gleiche Farbe, deshalb habe ich mir folgendes Makro zugelegt: 
Sub DiagrammFormat()
Dim i As Long
Dim Farbe As Integer
With ActiveChart.SeriesCollection(1)
For i = 1 To .Points.Count
Select Case WorksheetFunction.Index(.XValues, i)
Case "Verderb"
Farbe = 6   ' Gelb
Case "zu viel"
Farbe = 5  ' Blau
Case "Transport"
Farbe = 3   ' Rot
Case "Sonstiges"
Farbe = 13  ' Violett
Case "zu spät"
Farbe = 46  ' Orange
End Select
.Points(i).Interior.ColorIndex = Farbe
Next
End With
End Sub
Allerdings funktioniert das Makro NICHT bei gestapelten Daten, und NICHT bei Treemap-Diagrammen, was ich aber beides verwende.

Hat mir jemand einen Tipp, was ich machen könnte, um mein Problem zu lösen?
Vielen Dank schonmal im Voraus.
Grüße
Sarah
Anzeige

11
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
VBA unterschiedliche Diagrammtypen färben
28.05.2018 11:40:38
Beverly
Hi Sarah,
in deiner Mappe gibt es folgende Diagrammtypen:
Kreis, gruppierte Säulen, Sunburst, gestapelte Säulen, gestapelte Balken, nicht jedoch das von dir genannte Treemap-Diagramm.
Zu deinem Problem ist folgendes zu sagen:
1. die beiden gestapelten Diagrammtypen haben nicht 1 Datenreihe mit mehreren Datenpunkten, sondern mehrere Datenreihen mit 1 Datenpunkt - deshalb muss für diesen Diagrammtyp die Schleife über alle Datenreihen und nicht über alle Datenpunkte laufen. Da das gestapelte Balkendiagramm andere Werte in der Darstellung hat als die gestapelte Säule, muss dieses außern vor bleiben, oder du machst einen extra Code dafür. Du musst also den Code je nach Diagramm-Typ unterteilen.
2. das Sunburst-Diagramm in deiner Mappe lässt sich farblich nicht per VBA bearbeiten - wenn du stattdessen ein Kreis(Dougnut)-Diagramm verwendest, ist das dagegen möglich, obwohl die Darstellung der Beschriftung für diesen Diagrammtyp sicherlich optisch nicht so "schön" ist wie bei einem Sunburst-Diagramm.
Außerdem würde ich generell nicht ColorIndex verwenden sondern Color.
Sub DiagrammFormat()
Dim i As Long
Dim Farbe As Long
Dim chrDia As ChartObject
Dim serReihe As Series
For Each chrDia In ActiveSheet.ChartObjects
Select Case chrDia.Chart.ChartType
Case xlColumnStacked
' Schleife über alle Datenreihen
For Each serReihe In chrDia.Chart.SeriesCollection
Select Case serReihe.Name
Case "Verderb"
Farbe = 65535   ' Gelb
Case "zu viel"
Farbe = 16711680  ' Blau
Case "Transport"
Farbe = 255   ' Rot
Case "Sonstiges"
Farbe = 8388736  ' Violett
Case "zu spät"
Farbe = 26367  ' Orange
End Select
serReihe.Interior.Color = Farbe
Next serReihe
Case xlDoughnut, xlPie, xlColumnClustered
' Schleife über alle Datenpunkte
With chrDia.Chart.SeriesCollection(1)
For i = 1 To .Points.Count
Select Case WorksheetFunction.Index(.XValues, i)
Case "Verderb"
Farbe = 65535   ' Gelb
Case "zu viel"
Farbe = 16711680  ' Blau
Case "Transport"
Farbe = 255   ' Rot
Case "Sonstiges"
Farbe = 8388736  ' Violett
Case "zu spät"
Farbe = 26367  ' Orange
End Select
.Points(i).Interior.Color = Farbe
Next
End With
End Select
Next chrDia
End Sub

Der Code läuft über alle Diagramme, wobei keines der Diagramme selektiert werden muss.

Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
28.05.2018 12:08:00
Sarah
Hallo Beverly,
vielen Dank für die schnelle und kompetente Antwort :-) .
Hab den Code ausprobiert und er klappt bei dem gestapelten Balken, Doughnut, Kreis und Säulendiagramm.
Gibt es für die gestapelten Säulen & ein Treemap-Diagramm dann keine Lösung, wie ich das mit dem Umfärben machen könnte?
Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
28.05.2018 12:51:55
Beverly
Hi Sarah,
selbstverständlich funktioniert der Code auch für gestapelte Säulen - und zwar ist für diesen Diagrammtyp die folgende Case-Anweisung zuständig: Case xlDoughnut, xlPie, xlColumnClustered
Was NICHT geht ist das Sunburst - dafür hatte ich eine Alternative abngeboten (Doughnut). Ob es für ein Treemap-Diagramm eine Lösung gibt, kann ich so nicht sagen, dazu müsstest du ein Beispiel bereitstellen.

Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
28.05.2018 14:30:18
Sarah
Ah, jetzt geht mir ein Licht auf... Jetzt klappt alles, außer natürlich das Treemap-Diagramm.
Hab jetzt nochmal die Excel-Datei aktualisiert und mit einem Treemap-Diagramm hochgeladen:
https://www.herber.de/bbs/user/121857.xlsm
Vielleicht gibt es dafür ja doch eine Lösung?
Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
28.05.2018 15:58:21
Beverly
Beim Treemap-Diagramm habe ich nur die Möglichkeit gefunden, die Beschriftungslabel auszulesen, was natürlich ziemlich kompliziert ist, da dort 3 Angaben möglich sind und es verschiedene Kombinationen geben kann, für das Auslesen jedoch nur die Kategorie notwendig ist. Man kann es sicher realisieren aus der Kombination die Rubrik auszulesen, aber ich bin der Einfachheit halber mal davon ausgegangen, dass in deinem Fall die Beschriftungslabel vorhanden sind und nur die Kategorie angezeigt wird.
Du musst für das Treemap-Diagramm eine weitere Case-Anweisung verwenden:
             Case xlTreemap
' Schleife über alle Datenpunkte
With chrDia.Chart.SeriesCollection(1)
For i = 1 To .Points.Count
Select Case .Points(i).DataLabel.Caption
Case "Verderb"
Farbe = 65535   ' Gelb
Case "zu viel"
Farbe = 16711680  ' Blau
Case "Transport"
Farbe = 255   ' Rot
Case "Sonstiges"
Farbe = 8388736  ' Violett
Case "zu spät"
Farbe = 26367  ' Orange
End Select
.Points(i).Format.Fill.ForeColor.RGB = Farbe
Next
End With

Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
29.05.2018 07:39:51
Sarah
Klasse, vielen vielen Dank für die Mühe!
Eine Frage hätte ich da noch zu Farben in VBA, gibt es da eine Liste mit allen Farben und ihren jeweiligen Werten?
AW: VBA unterschiedliche Diagrammtypen färben
29.05.2018 07:58:21
Beverly
Seit Version 2007 bietet Excel über 1 Mio unterschiedliche Farben/Farbnuancen an - was für einen Sinn würde eine Farbliste da machen? Der einfachste Weg, eine gewünschte Farbnummer zu ermitteln ist, eine Zelle entsprechend zu formatieren und die Nummer dann per VBA auszulesen mittels ActiveCell.Interior.Color

Anzeige
AW: VBA unterschiedliche Diagrammtypen färben
29.05.2018 08:14:57
Sarah
Ach so. Und wie geht das? So hat es nämlich nicht funktioniert:
Sub Neu()
ActiveCell.Interior.Color
End Sub

MsgBox ActiveCell.Interior.Color - o.w.T.
29.05.2018 09:20:18
Beverly

AW: Diagramm Farben mit Makro verändern
29.05.2018 08:36:50
Sarah
Sorry für die vielen Fragen, aber mindestens eine hätte ich da noch...
Habe jetzt folgendes Makro: 
Sub Treemap()
Dim i As Long
Dim Farbe As Long
Dim chrDia As ChartObject
Dim serReihe As Series
For Each chrDia In ActiveSheet.ChartObjects
Select Case chrDia.Chart.ChartType
Case xlTreemap 'für Treemap-Diagramme
' Schleife über alle Datenpunkte
With chrDia.Chart.SeriesCollection(1)
For i = 1 To .Points.Count
Select Case .Points(i).DataLabel.Caption
Case "zu viel"
Farbe = 9592886  ' Blau
Case "falscher Artikel"
Farbe = 14408946  ' Rosa
Case "Verderb"
Farbe = 5066944 'Dunkelrot
Case "Transportschaden"
Farbe = 9420794  ' Orange
Case "Sonstiges"
Farbe = 8421504 'Grau
End Select
.Points(i).Format.Fill.ForeColor.RGB = Farbe
Next
End With
End Select
Next chrDia
End Sub

Wie muss ich das Makro verändern, dass nur das Diagramm, dass aktuell ausgewählt ist, verändert wird?
Anzeige
AW: Diagramm Farben mit Makro verändern
29.05.2018 09:39:07
Beverly 

Sub Treemap()
Dim i As Long
Dim Farbe As Long
If ActiveChart.ChartType = xlTreemap Then 'für Treemap-Diagramm
' Schleife über alle Datenpunkte
With ActiveChart.SeriesCollection(1)
For i = 1 To .Points.Count
Select Case .Points(i).DataLabel.Caption
Case "zu viel"
Farbe = 9592886  ' Blau
Case "falscher Artikel"
Farbe = 14408946  ' Rosa
Case "Verderb"
Farbe = 5066944 'Dunkelrot
Case "Transportschaden"
Farbe = 9420794  ' Orange
Case "Sonstiges"
Farbe = 8421504 'Grau
End Select
.Points(i).Format.Fill.ForeColor.RGB = Farbe
Next
End With
End If
End Sub

Beachte: wenn kein Diagramm selektiert ist, wird ein Laufzeitfehler ausgegeben.

Anzeige
;

Forumthreads zu verwandten Themen

Balkendiagramm mit verschiedenen Farben
Räber

Hallo zusammen
Ich habe ein Problem mit einem Excel-Diagramm, welches ich nicht den Anforderungen entsprechend erstellen kann. Folgende Ausgangslage:
1. Ich habe ein Excel-Sheet, welches per SQL mit Daten abgefüllt wird.
2. Es gibt diverse Spalten, für das Diagramm ist die Spalte "K...
23.09.2009 15:41:32
Thread-ID: 1104938
2 Beiträge
Diagramm Säulen Farbe ändern
Sven

Hallo,
ich komme einfach nicht weiter.
Ich habe Säulendiagramme und will, dass wenn der Wert unter X ist, die Säule die Farbe Rot bekommt.
Wie kann ich sowas umsetzen?
Bitte um Hilfe! Ist sehr wichtig!
Vielleicht per Addin, oder so?
Gruß
Sven
05.11.2009 19:10:51
Thread-ID: 1114792
7 Beiträge
unterschiedliche Spaltenbreite in Liniendiagramm
anke

Hallo,
ich habe ein Diagramm mit einer X- und 2 Y-Achsen erstellt. In der X-Achse werden Daten angezeigt.
Lieder ist der Abstand zwischen den Daten nicht immer gleich. Kann ich in einem Diagramm die Spaltenbreite bestimmen?
Vielen Dank schonmal
Anke
13.04.2010 13:05:58
Thread-ID: 1151417
2 Beiträge
Balkendiagramm verschiedene Farben je nach Name
kathy

Hallo Leute,
ist es möglich, in einem Balkendiagramm je nach Raum unterschiedliche Farben automatisch zuzuordnen?
https://www.herber.de/bbs/user/69129.xlsx
Bin für jede Hilfe dankbar.
Gruß
kathy
17.04.2010 09:49:23
Thread-ID: 1152315
5 Beiträge
Diagramm Balkenfarben fest einstellen
Kurt

Hallo zusammen,
ich würde gerne die Farben der Balken in einem Diagramm bei jedem Start von Excel gleich haben.
Gibt es eine Möglichkeit diese Einstellungen zu setzen. Habe es schon unter "Extras Optionen Farbe " versucht. Hat aber den nächsten Neustart nicht überlebt.
Vielleicht h...
02.05.2010 11:06:37
Thread-ID: 1154909
4 Beiträge
Diagrammfarben ändern abhängig vom Vorzeichen
Overmind

Hallo zusammen.
Ich möchte gerne eine Tortendiagramm erstellten mit einer variablen Anzahl von Stücken, die alle gleich groß sein sollen. So weit so gut. Jetzt möchte ich, dass abhängig, ob ein Wert positiv oder negativ ist die Tortenstückchen in rot oder grün angezeigt werden (jedes einzel...
20.07.2010 12:20:04
Thread-ID: 1167870
2 Beiträge
Diagramm Säulen umfärben
Fabio

Diagramm Säulen unterschiedlich?
Hallo zusammen,
irgendwie stehe ich auf dem Schlauch. Ich will Monatswerte vergleichen. Was muss ich tun, damit in meinem Diagramm die jeweiligen SÄulen andere Farben haben.
Konkret:
alle Monate mit "2009" (plus der Januar 2010) sollen eine Farbe...
13.04.2011 10:29:09
Thread-ID: 1210164
5 Beiträge
Anzeige
Diagramm Säulenfarbe aus Zellfarbe
Sven

Hi,
ich habe ein kleines Problem, bei dem ich einfach nicht weiterkomme.
Ich habe Daten, welche ich als Stapeldiagramm verwende. Es soll eine Füllstandanzeige sein.
Es gibt "weiße" und grüne Felder. Wie kann ich es machen, dass das Diagramm die Farben von den Zellen annimmt? Wisst...
24.11.2011 10:29:34
Thread-ID: 1239044
9 Beiträge
Anzeige
Diagramm Balken farben verändern wenn im minus
Mike

Hallo,
Ich möchte in einem Diagramm drei werte anzeigen, der minus wert wird nach unten angezeigt, dies möchte ich aber nicht.Wie kann ich ereichen das sich der Balken farblich verändert, also wenn der wert von 0 - 10 dann Blau, ist der wert aber -5 dann rot.
Wer kann helfen?
Danke im...
29.05.2002 11:56:16
Thread-ID: 124537
2 Beiträge
Füllfarbe nach Wahrheitswert ausgeben
Tina

Hallo Zusammen,
Meine Problem von Gestern:
Der Wert aus Zeile A2 soll in der Spalte B: Zeilen 2 bis 100, gesucht werden und in Zeile C2 ausgegeben werden. Bei GENAU demselben Wert soll ein x ausgegeben und andernfalls ein - ausgegeben werden.
habe ich Dank der Hilfe hier gelöst beko...
30.01.2013 10:45:07
Thread-ID: 1296653
3 Beiträge
Diagramm: 2Linien mit unterschiedlicher Zeilenzahl
Phil

Hallo,
ich erstelle gerade ein Diagramm, bei dem ich auf unterschiedliche Datenmengen zurückgreife. Die Zeit liegt bei beiden Datenreihen zwischen 14 und 16.30Uhr.
Die Datenmenge in dieser Stunde unterscheidet sich allerinds.
Parameter "Temp" hat 230 Zeilen (auch die Zeitzuweisung)...
05.04.2013 12:26:27
Thread-ID: 1307443
12 Beiträge
Farben im Balkendiagramm
doni

Hallo Profis!!!
Ich werde gleich verrückt und brauche bitte dringend Hilfe!!
Ich habe ein Balkendiagramm, dass aus einer Tabelle gespeist wird.
Kann man Balken die einen Wert haben, z.B. 2, eine Farbe automatisch zuordnen?
Gebe ich den nächsten Wert ein, 3, soll der nächste Balk...
13.06.2014 12:25:14
Thread-ID: 1365722
4 Beiträge
Anzeige
Anzeige

Infobox / Tutorial

Farben in Excel-Diagrammen mit Makro anpassen

Schritt-für-Schritt-Anleitung

Um die Farben in Excel-Diagrammen mithilfe von VBA-Makros anzupassen, kannst du die folgenden Schritte befolgen:

  1. Makro erstellen: Öffne Excel und drücke ALT + F11, um den VBA-Editor zu öffnen. Füge ein neues Modul hinzu.

  2. Code einfügen: Kopiere den folgenden Code in das Modul:

    Sub DiagrammFormat()
    Dim i As Long
    Dim Farbe As Long
    Dim chrDia As ChartObject
    Dim serReihe As Series

    For Each chrDia In ActiveSheet.ChartObjects
        Select Case chrDia.Chart.ChartType
            Case xlColumnStacked, xlColumnClustered
                For Each serReihe In chrDia.Chart.SeriesCollection
                    Select Case serReihe.Name
                        Case "Verderb"
                            Farbe = RGB(255, 255, 0)  ' Gelb
                        Case "zu viel"
                            Farbe = RGB(0, 0, 255)  ' Blau
                        Case "Transport"
                            Farbe = RGB(255, 0, 0)   ' Rot
                        Case "Sonstiges"
                            Farbe = RGB(128, 0, 128) ' Violett
                        Case "zu spät"
                            Farbe = RGB(255, 165, 0)  ' Orange
                    End Select
                    serReihe.Interior.Color = Farbe
                Next serReihe
            Case xlTreemap
                ' Schleife über alle Datenpunkte
                With chrDia.Chart.SeriesCollection(1)
                    For i = 1 To .Points.Count
                        Select Case .Points(i).DataLabel.Caption
                            Case "Verderb"
                                Farbe = RGB(255, 255, 0)
                            Case "zu viel"
                                Farbe = RGB(0, 0, 255)
                            Case "Transport"
                                Farbe = RGB(255, 0, 0)
                            Case "Sonstiges"
                                Farbe = RGB(128, 0, 128)
                            Case "zu spät"
                                Farbe = RGB(255, 165, 0)
                        End Select
                        .Points(i).Format.Fill.ForeColor.RGB = Farbe
                    Next
                End With
        End Select
    Next chrDia
End Sub

  3. Makro ausführen: Schließe den VBA-Editor und gehe zurück zu Excel. Wähle das gewünschte Diagramm aus und führe das Makro aus.

  4. Farben überprüfen: Die Diagrammfärbung sollte nun entsprechend den definierten Kategorien angepasst sein.

Häufige Fehler und Lösungen

  • Fehler: "Laufzeitfehler 1004": Dieser Fehler tritt auf, wenn kein Diagramm ausgewählt ist. Stelle sicher, dass du ein Diagramm markiert hast, bevor du das Makro ausführst.

  • Farben ändern sich automatisch: Wenn das Diagramm die Farben nach Werten oder Kategorien ändert, stelle sicher, dass du die Farben fixierst, indem du den richtigen VBA-Code verwendest.

  • Gestapelte Diagramme: Für gestapelte Diagramme musst du die Schleife so anpassen, dass sie über die Datenreihen und nicht über die Punkte iteriert.

Alternative Methoden

  • Excel Diagramm Farben aus Tabelle übernehmen: Du kannst die Farben auch direkt aus einer Zelle übernehmen, indem du den RGB-Wert aus einer Zelle ausliest.

    Farbe = ActiveSheet.Range("A1").Interior.Color

  • Farbpalette importieren: Du kannst auch eine benutzerdefinierte Farbpalette importieren, um die Farben für dein Diagramm zu ändern.

Praktische Beispiele

  • Einzelne Balken färben: Um spezifische Balken in einem Balkendiagramm zu färben, kannst du den Index des Punktes angeben:

    .Points(1).Interior.Color = RGB(255, 0, 0)  ' Färbt den ersten Balken rot

  • Farbe basierend auf Wert: Du kannst auch die Farbe eines Balkens basierend auf seinem Wert ändern:

    If .Points(i).Value > 100 Then
    .Points(i).Interior.Color = RGB(0, 255, 0)  ' Grün für Werte über 100
End If

Tipps für Profis

  • Farben für Diagramme fixieren: Verwende den Color-Befehl anstelle von ColorIndex, um sicherzustellen, dass die Farben nicht automatisch angepasst werden.

  • Farbänderungen dokumentieren: Halte die Farbzuweisungen in einer separaten Tabelle fest, um die Übersichtlichkeit zu erhöhen und spätere Änderungen zu erleichtern.

FAQ: Häufige Fragen

1. Wie kann ich Farben in einem Diagramm ändern, ohne VBA zu verwenden? Du kannst die Farben manuell über die Diagrammtools im Excel-Menü ändern. Wähle das Diagramm aus, gehe zu "Format" und ändere die Farben unter "Füllung".

2. Gibt es eine Möglichkeit, alle Diagramme in einem Arbeitsblatt gleichzeitig zu ändern? Ja, du kannst eine Schleife verwenden, die alle Diagrammobjekte in einem Arbeitsblatt durchläuft und die gewünschten Farben anwendet, wie im Beispiel oben gezeigt.

3. Wo finde ich eine Liste aller verfügbaren Farben in Excel? Es gibt keine vollständige Liste, da Excel über 1 Million Farben unterstützt. Du kannst jedoch eine Farbe auswählen und ihren RGB-Wert über VBA ermitteln, indem du ActiveCell.Interior.Color verwendest.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige