1. Buchstabe in Zelle groß

Forumthread: 1. Buchstabe in Zelle groß

01.07.2018 13:37:23

sigrid

Gute Tag zusammen,
ich habe dieses Makro gefunden:
Dim Zelle
For Each Zelle In Target
If Not IsEmpty(Zelle) Then
Application.EnableEvents = False
Zelle.Value = UCase(Left(Zelle, 1)) & Right(Zelle, Len(Zelle) - 1)
Application.EnableEvents = True
End If
Next Zelle
es werden in ALLEN Zellen der 1. Buchstabe groß geschrieben, ich
möchte aber nur im Bereich Spalte H + Spalte I ab Zelle3 und
Seperat für eine andere Tabelle im Bereich ab G3:G100 + K3:K100 das jeweils der 1. Buchstabe
groß geschrieben wird.
mfg
Sigrid

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: 1. Buchstabe in Zelle groß

01.07.2018 13:52:55

Nepumuk
Danke Nepumuk pefekt !!! -)

01.07.2018 14:15:33

sigrid
Danke Nepumuk pefekt !!! -)

01.07.2018 14:15:35

sigrid
AW: 1. Buchstabe in Zelle groß

01.07.2018 13:57:31

Hajo_Zi
Danke Hajo ! läuft -)

01.07.2018 14:18:05

sigrid

AW: 1. Buchstabe in Zelle groß

01.07.2018 13:52:55

Nepumuk

Hallo Sigrid,
für Spalte H - I so (in das Modul der Tabelle):

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Zelle As Range, Bereich As Range
    Set Bereich = Intersect(Target, Range("H3:I" & CStr(Rows.Count)))
    If Not Bereich Is Nothing Then
        Application.EnableEvents = False
        For Each Zelle In Bereich
            If Not IsEmpty(Zelle.Value) Then _
                Zelle.Value = UCase$(Left(Zelle.Text, 1)) & Right$(Zelle.Text, Len(Zelle) - 1)
        Next Zelle
        Application.EnableEvents = True
    End If
End Sub

Für das andere Tabellenblatt in SPalte G + K so:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Zelle As Range, Bereich As Range
    Set Bereich = Intersect(Target, Range("G3:G100,K3:K100"))
    If Not Bereich Is Nothing Then
        Application.EnableEvents = False
        For Each Zelle In Bereich
            If Not IsEmpty(Zelle.Value) Then _
                Zelle.Value = UCase$(Left(Zelle.Text, 1)) & Right$(Zelle.Text, Len(Zelle) - 1)
        Next Zelle
        Application.EnableEvents = True
    End If
End Sub

Gruß
Nepumuk

Danke Nepumuk pefekt !!! -)

01.07.2018 14:15:33

sigrid

Danke Nepumuk pefekt !!! -)

01.07.2018 14:15:35

sigrid

AW: 1. Buchstabe in Zelle groß

01.07.2018 13:57:31

Hajo_Zi

Hallo Sigrid,
falls jedes Wort Großbuchstabe

Option Explicit                                     ' Variablendefinition erforderlich
Private Sub Worksheet_Change(ByVal Target As Range)
'* H. Ziplies                                  *
'* 01.07.18                                    *
'* erstellt von HajoZiplies@web.de             *
'* http://Hajo-Excel.de/
Dim RaBereich As Range                          ' Variable f?r Bereich
Dim RaZelle As Range                            ' Variable f?r Zelle
Set RaBereich = Range("H3:H1048576, I3:I1048576")       ' Bereich der Wirksamkeit
Set RaBereich = Intersect(RaBereich, Target)
If Not RaBereich Is Nothing Then
'ActiveSheet.Unprotect ("Passwort")
Application.EnableEvents = False
For Each RaZelle In RaBereich
RaZelle = WorksheetFunction.Proper(RaZelle)
Next RaZelle
Application.EnableEvents = True
'ActiveSheet.protect ("Passwort")
End If
Set RaBereich = Nothing                         ' Variable leeren
End Sub

ansonsten füge Deine Code ein, angepasst.

Beiträge von Werner, Luc, robert, J.O.Maximo und folgende lese ich nicht.

Danke Hajo ! läuft -)

01.07.2018 14:18:05

sigrid

Beliebteste Forumthreads (12 Monate)

Forumthread: 1. Buchstabe in Zelle groß

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread