Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1672to1676
1672to1676
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Daten aus Tabellenblatt1 je nach Bezug in andere T

Forumthread: Daten aus Tabellenblatt1 je nach Bezug in andere T

Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 07:38:21
Stefan
Hallo, ich grüble an einem Problem und bei meiner Suche in den Foren habe ich leider bis jetzt noch nicht die Lösung gefunden aber die Erkenntnis, dass ich mich wohl mit VBA befassen sollte.
Aber hier die Frage, für die ich hoffe, eine Lösung zu bekommen:
Ich möchte bestimmt Daten aus Tabellenblatt 1 je nach Bezug in ein anderes Tabellenblatt kopieren. Das ist die Hauptliste, die täglich weitere Daten erhält:
Datum Text Betrag Kunden
05.01.2019 Text 200 Kunde C
04.01.2019 Text 200 Kunde A
04.01.2019 Text 180 Kunde B
03.01.2019 Text 200 Kunde A
02.01.2019 Text 350 Kunde C
02.01.2019 Text 150 Kunde A
Und ich möchte je Kunde ein eigenes Tabellenblatt, dass sich mit jeder weiteren neuen Eingabe entsprechend aktualisiert und wie folgt aussehen soll:
Tabellenblatt Kunde A
Datum Text Betrag
04.01.2019 Text 200
03.01.2019 Text 200
02.01.2019 Text 150
Und das entsprechend für Kunde A-C. Es werden max. 10 Kunden werden
Ich hoffe, ich konnte meinen Wunsch verständlich erklären und danke im Voraus für Eure Hilfe und Tipps
Vielen Dank und viele Grüße
Stefan
Anzeige

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 07:43:25
Sepp
Hallo Stefan,
zwei Fragen dazu.
  • Was soll die Übertragung der Daten auslösen?
  • Sollen die Daten nach der Übertragung im Hauptblatt gelöscht werden?

 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 08:00:12
Stefan
Hallo und guten Morgen Sepp,
ich hoffe ich verstehe die erste Frage richtig.
Ich möchte für jeden Kunden ein laufendes, tagesaktuelles Kundeblatt. Also der reine Name "KundeA" oder "KundeB" soll die Übertragung auslösen. Und noch kurz zur Erklärung: "Text" meint einfach eine weitere Info zur Bestellung ohne Möglichkeit danach zu filtern oder zuzugreifen
Und die Daten im Hauptblatt sollen bestehen bleiben
Danke + Gruß
Stefan
Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 08:24:45
Sepp
Hallo Stefan,
in das Modul des Hauptblattes. (Rechtsklick auf das Blattregister > Code anzeigen > in das rechte Fenster einfügen)
Die Daten werden beim Eintragne des Kundennamens übertragen.
Microsoft Excel Objekt Tabelle1 
Option Explicit 
 
Private Sub Worksheet_Change(ByVal Target As Range) 
  Dim objWS As Worksheet, strName As String 
   
  With Target 
    If .Column = 4 And .Row > 1 And .Count = 1 Then 
      If Len(.Value) Then 
        strName = ValidSheetName(.Value) 
        If SheetExist(strName) Then 
          Set objWS = Sheets(strName) 
        Else 
          Set objWS = Worksheets.Add(After:=Sheets(Sheets.Count)) 
          With objWS 
            .Name = strName 
            .Range("A1:C1") = Array("Datum", "Text", "Betrag") 
            .Range("A1:C1").Font.Bold = True 
          End With 
        End If 
        With objWS 
          .Rows(2).Insert 
          Target.Offset(0, -3).Resize(1, 3).Copy .Cells(2, 1) 
        End With 
      End If 
      Me.Activate 
    End If 
  End With 
End Sub 
 
Private Function SheetExist(ByVal sheetName As String, Optional Wb As Workbook, Optional ByVal byCodeName As Boolean = False) As Boolean 
  Dim wks As Object 
  On Error GoTo ERRORHANDLER 
  If Wb Is Nothing Then Set Wb = ThisWorkbook 
  For Each wks In Wb.Sheets 
    If byCodeName Then 
      If LCase(wks.CodeName) = LCase(sheetName) Then SheetExist = True: Exit Function 
    Else 
      If LCase(wks.Name) = LCase(sheetName) Then SheetExist = True: Exit Function 
    End If 
  Next 
ERRORHANDLER: 
  SheetExist = False 
End Function 
 
Private Function ValidSheetName(ByVal strName As String) As String 
  'Returns a valid name for excel-sheets 
  Dim objRegExp As Object, strTmp As String 
 
  On Error GoTo ErrExit 
 
  Set objRegExp = CreateObject("vbscript.regexp") 
 
  With objRegExp 
    .Global = True 
    .Pattern = "[\/\\:\*\?\[\]]" 
    .IgnoreCase = True 
    strTmp = Trim$(.Replace(strName, "")) 
    .Pattern = "[ ]+" 
    strTmp = .Replace(strTmp, " ") 
  End With 
 
  If Len(strTmp) Then 
    ValidSheetName = Left(strTmp, 31) 
  Else 
    GoTo ErrExit 
  End If 
 
  Exit Function 
 
ErrExit: 
 
  ValidSheetName = "Invalid Name!" 
End Function 


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 08:58:00
Stefan
Hallo Sepp, ich bin sprachlos! Haust du einfach mal so ein Ding raus!
Ich habe keine Ahnung wie es geht, aber es funktioniert genau wie gewünscht!
Vielen Dank für die super schnelle Hilfe am Morgen :)
Darf ich noch eine kleine Frage nachschieben:
Ich habe ein Summenfeld auf D1 in den Neuen Tabellen platziert, das die Summe aller Zahlen in der Spalte C (=summe(c2:c100)) addiert. Aber bei jedem Neueintrag rutscht die Formel um 1 nach unten (=summe(c3:c101))
OK - ich kann das leicht per Hand korrigieren, aber gibt es evtl. einen Kniff, den ich anwenden könnte, damit ich immer die aktuelle Summe habe?
Vielen Dank noch einmal
Gruß Stefan
Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 09:05:04
Sepp
Hallo Stefan,
ändere die Formel in '=SUMME($C:$C)'
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim objWS As Worksheet, strName As String
  
  With Target
    If .Column = 4 And .Row > 1 And .Count = 1 Then
      If Len(.Value) Then
        strName = ValidSheetName(.Value)
        If SheetExist(strName) Then
          Set objWS = Sheets(strName)
        Else
          Set objWS = Worksheets.Add(After:=Sheets(Sheets.Count))
          With objWS
            .Name = strName
            .Range("A1:C1") = Array("Datum", "Text", "Betrag")
            .Range("D1").Formula = "=SUM($C:$C)"
            .Range("A1:C1").Font.Bold = True
          End With
        End If
        With objWS
          .Rows(2).Insert
          Target.Offset(0, -3).Resize(1, 3).Copy .Cells(2, 1)
        End With
      End If
      Me.Activate
    End If
  End With
End Sub


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Daten aus Tabellenblatt1 je nach Bezug in andere T
02.02.2019 09:16:46
Stefan
Hallo Sepp,
nochmals vielen Dank!
Ich dachte, ich kann ein wenig Excel, aber ich bin platt, was alles geht.
Aber ich freue mich jetzt mit meiner Liste arbeiten zu können und werde die jetzt befüllen und zum Leben bringen.
Ich wünsche Dir ein schönes Wochenende.
Danke und viele Grüße
Stefan
Anzeige

Forumthreads zu verwandten Themen

datenimport aus excel in excel
caot

Hi mal wieder!
ich hab mal wieder ne frage:
es sind ca 1200 Excel Dateien aus denen jeweils aus ein paar Zeilen und Spalten die Werte in eine Exceldatei eingelesn werden sollen.
Die Ursprungsdateien sind laufend nummeriert... und dann
kommt noch ein name als nummer- name.xls <...
09.08.2008 11:22:00
Thread-ID: 1000469
3 Beiträge
Daten aus vielen xls-Datein auslesen
Daniel

Hallo Profis,
ich suche einen VBA-Befehl für folgendes:
Ich habe einen Ordner mit vielen xls-Dateien. Diese sollen nun alle in einer Datei zusammengefahren werden, alle Zeilen, wenn der Wert der 2. Spalte links mit "12345" anfängt.
Geht dies?
Vielen Dank vorab.
Daniel
...
18.08.2008 15:07:01
Thread-ID: 1002621
2 Beiträge
daten aus Arbeitsmappe einlesen
Peter

Hallo,
kurze Fragestellung an die Experten. Habe mir einen Code zusammengebastelt, der in einer geöffneten Arbeitsmappe, bestimmte Daten aus einer anderen noch "unbestimmten" Arbeitsmappe importieren soll. Funktioniert auch, jedoch kommt mir der Code zu unübersichtlich und auch "unsauber" v...
19.08.2008 13:25:00
Thread-ID: 1002916
3 Beiträge
Textdatei per VBA einlesen
Werner

Ich möchte eine Textdatei per VBA einlesen. Untenstehender Versuch bringt die Fehlermeldung:
Excel kann auf die Datei in '' nicht zugreifen.
Die Datei ist unter Umständen schreibgeschützt oder verschlüsselt.
Woher weiß das Makro das, wo ich noch gar keinen Dateinamen angegeben habe...
11.09.2008 09:57:26
Thread-ID: 1008986
4 Beiträge
Datenvergleich und danach ausgegebene Info
Merle

Guten morgen alle zusammen!
Hab mal wieder eine Frage. Kriege ständig irgendwelche Listen, die ich zusammenfassen soll.
Hier ein Beispiel meiner Liste:
https://www.herber.de/bbs/user/55376.xls
Ich hätte es gerne, dass wenn ich in der Liste in Tabelle1, nur die Bez. D127 aus dem...
15.09.2008 08:58:00
Thread-ID: 1009662
2 Beiträge
Anzeige
Daten aus Userfom in eine ausgeblendete Tabelle
Ramon

Hallo alle zusammen,
ich möchte nach Klick auf den Command_Button "cb_send" Eingabewerte aus einer
Userform in eine Tabelle schreiben.
In Abhängigkeit der eingegebenen Werte sollen die Daten entweder in das Tabllenblatt
"data_booked" oder in "data_planned" geschrieben werden, u...
16.09.2008 12:28:00
Thread-ID: 1010054
5 Beiträge
Daten aus Zellbereich in eine neue Arbeitsmappe
André

Für eine "Tägliche Auswertung" suche ich ein Makro.
Meine erste Idee war es, hier im Forum zu suchen, ob es da nicht schon was gibt. Leider erfolglos. Ich hab zwar Makros gefunden, die ein neues Wks erstellen mit genau den Vorgaben, die ich brauche und ein Makro zum Zellenbereich kopieren,...
26.09.2008 10:23:00
Thread-ID: 1012532
3 Beiträge
Daten aus Tabelle in eine andere Tabelle
Cornelia

Ich habe 2 Tabellen mit dem gleichen Aufbau.
Tabelle 1 soll die Daten eingetragen werden. Von mehreren Leuten. Deshalb eben seperat.
Tabelle 2 soll die Daten aus Tabelle 1 übernehmen. Jeweils ein Blatt mit identischen Blattnamen aus Tabelle 1. Bisherige Lösung von mir in jede Zelle rein...
01.10.2008 08:11:00
Thread-ID: 1013510
6 Beiträge
Daten aus Inputbox in Zellen untereinander lesen
Peter

Hallo
Bin neu hier, und auch ein Anfänger in VBA, habe folgendes Problem.
Ich möchte, das Datum über eine InputBox in die Zellen untereinander schreiben lassen, also wenn ich am Freitag was Schreibe soll das Datum in A1 stehen, beim nächsten Aufruf der InputBox, soll das Datum in A2 ges...
09.10.2008 20:00:59
Thread-ID: 1015445
3 Beiträge
Import von daten aus txt file
daten

Guten Morgen an alle VBA-Aktivisten
Ich hätte mal ne kleine Frage. Ich hab einen Code der es mir ermöglicht innerhalb eines Tabellenblattes über einen Button eine txt-Datei zu öffnen und in eine bestehende Tabelle einzulesen. Leider fängt er immer im txt file ganz oben links an. Wie kann ic...
10.10.2008 09:07:22
Thread-ID: 1015499
6 Beiträge
Neuanordnung von Quelldaten aus Spalte in Zeile
Quelldaten

Hallo liebe Excel-Freunde,
folgendes Excel-Problem kann ich nicht lösen:
ich habe zwei Excelspalten mit Daten.
Die erste Spalte enthält eine fortlaufende Nummerierung. In der zweiten Spalte befinden sich untereinander zwei zusammengehörige Werte, also z. B. so:
Spalte 1___Spalt...
10.10.2008 15:05:18
Thread-ID: 1015600
7 Beiträge
Daten aus einer anderen Mappe auslesen
Uwe

Hallo zusammen, habe mir einen funktionierenden Einsatzplan für 24 MA und 3 Schichten zusammengebastelt welcher die Monate inkl. Feiertage und Wochenenden dynamisch generiert.
Nun möchte ich wenn ich im zum Beispiel den Einsatzplan für die Mitarbeiter für Februar abrechne, das Excel sich...
14.10.2008 22:12:36
Thread-ID: 1016451
5 Beiträge
Anzeige

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige