Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1688to1692
1688to1692
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

listbox überwachen

Forumthread: listbox überwachen

listbox überwachen
05.05.2019 19:20:57
Thomas
Hallo Excelfreunde,
ich habe in einer Userform eine Listbox mit 22 spalten. Diese fülle ich mit Rowsource.
Nun möchte beim Start der Userform ein Label einblenden, in dem alle Datensätze aufgelistet sind, bei der die Bearbeitung noch nicht abgeschlossen ist.
Alle Datensätze bei der die Bearbeitung abgeschlossen wurde steht in der zweiten Spalte der Listbox
( ListBox2.List(ListBox2.ListIndex, 2))
entweder ein ( "möglich" oder ein "nicht möglich" ).
So zu sagen möchte ich in einem Label alle Datensätze auflisten wo in der zweiten Spalte kein "möglich" oder kein " nicht möglich" steht.
Hat jemand von euch so etwas schon mal gemacht? Oder weiß jemand wie ich dies machen könnte?
habt schon mal recht vielen dank für euer Interesse.
mfg thomas
Anzeige

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: listbox überwachen
05.05.2019 19:25:41
Hajo_Zi
Hallo Thomas,
ich würde eine Listbox nehmen da mehr als ein Datensatz angezeigt werden soll.
Die Lösung must Du selber erstellen, da Du Deine Datei siehst.

Beiträge von Werner, Luc, robert, J.O.Maximo und folgende lese ich nicht.
Die Beiträge werden auch ignoriert, es erfolgt keine Antwort.
Anzeige
Datei mit UF hochladen! o.T.
05.05.2019 19:34:56
Sepp
AW: listbox überwachen
05.05.2019 20:35:04
Thomas
Hallo Hajo_Zi und Sepp,
erstmal besten dank das ihr euch dies mal angeschaut habt.
Ich habe eine Musterdatei erstellt. Da habe ich bemerkt das meine zu prüfende Spalte nicht die zweite Spalte ist sondern die dritte Spalte ist. Man Man.
Auf Hajo sein Hinweis habe ich gleich noch eine neue Userform mit einer Listbox integriert. Diese wird jetzt beim Start der Userform1 eingeblendet.
In dieser Listbox würde ich jetzt gern alle nicht abgeschlossenen Datensätze anzeigen.
So zu sagen alle Datensätze auflisten wo in der dritten Spalte kein "möglich" oder kein " nicht möglich" steht. ( Listbox2 der Userform1). Wenn ich jetzt nicht übertreibe sortiert nach Datum der Fälligkeit. ( wäre nur noch besser).
https://www.herber.de/bbs/user/129606.xlsm
Bitte nicht sauer sein falls ich das unklar beschrieben habe.
mfg thomas
Anzeige
AW: listbox überwachen
05.05.2019 20:51:03
Sepp
Hallo Thomas,
in das Modul von UserForm1.
Private Sub UserForm_Activate()
Dim lngIndex As Long, lngC As Long
    With nicht_Bearbeitet
      For lngIndex = 0 To ListBox2.ListCount - 1
        If Not ListBox2.List(lngIndex, 2) Like "*möglich*" Then
          .ListBox1.AddItem ListBox2.List(lngIndex, 0)
          For lngC = 1 To 3
            .ListBox1.List(.ListBox1.ListCount - 1, lngC) = _
              IIf(lngC = 1, Format(ListBox2.List(lngIndex, lngC), "dd.mm.yyy"), ListBox2.List(lngIndex, lngC))
          Next
        End If
      Next
      Call SortListBox(.ListBox1, 0, .ListBox1.ListCount - 1, 1)
      .Show
    End With
End Sub

Private Sub SortListBox(ByRef TheBox As MSForms.ListBox, LowerBound As Long, UpperBound As Long, SortColumn As Byte)
  'original by Nepumuk 
  Dim lngIndex1 As Long, lngIndex2 As Long
  Dim vntTemp As Variant, vntBuffer As Variant
  Dim bytIndex As Byte
  lngIndex1 = LowerBound
  lngIndex2 = UpperBound
  vntTemp = TheBox.List((LowerBound + UpperBound) \ 2, SortColumn)
  Do
    Do While TheBox.List(lngIndex1, SortColumn) < vntTemp
      lngIndex1 = lngIndex1 + 1
    Loop
    Do While vntTemp < TheBox.List(lngIndex2, SortColumn)
      lngIndex2 = lngIndex2 - 1
    Loop
    If lngIndex1 <= lngIndex2 Then
      For bytIndex = 0 To TheBox.ColumnCount - 1
        vntBuffer = TheBox.List(lngIndex1, bytIndex)
        TheBox.List(lngIndex1, bytIndex) = TheBox.List(lngIndex2, bytIndex)
        TheBox.List(lngIndex2, bytIndex) = vntBuffer
      Next
      lngIndex1 = lngIndex1 + 1
      lngIndex2 = lngIndex2 - 1
    End If
  Loop Until lngIndex1 > lngIndex2
  If LowerBound < lngIndex2 Then Call SortListBox(TheBox, LowerBound, lngIndex2, SortColumn)
  If lngIndex1 < UpperBound Then Call SortListBox(TheBox, lngIndex1, UpperBound, SortColumn)
End Sub


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

Anzeige
Hallo Sepp das ist cool besten dank
05.05.2019 21:00:33
Thomas
Hallo Sepp,
ich bin komplett überwältigt. Wie kann man so etwas so schnell denken und dann noch schreiben?
Absolut cool. Das du mir geholfen hast.
Hab recht vielen vielen vielen dank.
mfg thomas
;

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige