Index mit mehreren Lösungen

Forumthread: Index mit mehreren Lösungen

09.10.2019 09:36:18

Niklas

Hallo zusammen,
Ich möchte gerne alle Zeilen einer Tabelle ausgeben, in denen der Inhalt (Spalte D) zu einem von drei key words (E-G) passt.
Ich habe in Spalte A jede Zeile nummeriert und möchte die entsprechenden Zeilennummern in I ausgeben.
Ich habe mithilfe dieses Forums meine Index Funktion bereits umgebaut, dass nicht nur ein Ergebnis (Zeilennummern) ausgespuckt wird, sondern mehrere Lösungen.
Das Problem ist nur, dass die Ergebnisse nicht die korrekten Zeielennummern sind.
VG Niklas
https://www.herber.de/bbs/user/132438.xlsx

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Index mit mehreren Lösungen

09.10.2019 09:41:20

Niklas

Hier noch die Formel in deutsch:
=wennfehler(INDEX($C$3:$C$8;AGGREGAT(15;6;zeile($C$3:$C$8)-1/((istzahl(suchen($G$3;$D$3:$D$8)) *($E$3""))+(istzahl(suchen($F$3;$D$3:$D$8))*($F$3""))+(istzahl(suchen($E$3;$D$3:$D$8) ) *($G$3"")));zeile(C2)));"")
Meine key-word Felder sind E3,F3&G3

AW: Index mit mehreren Lösungen

09.10.2019 09:42:52

Niklas

Oh, und die Zeilennummern stehen in Spalte C nicht A

da feht ZEILE(.. bis ..)

09.10.2019 10:15:52

Hi,
jetzt nur mit mit dem 1. Key word:
[=WENNFEHLER(INDEX(C:C;KKLEINSTE(WENN(ISTZAHL(SUCHEN(E$3;D$1:D$9));ZEILE(X$1:X$9));ZEILE(X1)));"")}
runterkopieren
WF

AW: da feht ZEILE(.. bis ..)

09.10.2019 10:44:32

Niklas

Hi,
Jetzt gibt er als erste LÖsung eine 0 an und wenn ich die Fromel runterziehe #Zahl.
https://www.herber.de/bbs/user/132440.xlsx
VG Niklas

AW: da feht ZEILE(.. bis ..)

09.10.2019 10:46:58

Torsten

Hallo Niklas,
bei mir nicht. Da das eine Matrixformel ist, solltest du die mit strg+Shift+Enter abschliessen.
Gruss Torsten

alle 3 Key words

09.10.2019 10:51:15

Hi,
{=WENNFEHLER(INDEX(C:C;KKLEINSTE(WENN(ISTZAHL(SUCHEN(INDEX(E$3:G$3;VERGLEICH("*";E$3:G$3;0));D$1:D$9) );ZEILE(X$1:X$9));ZEILE(X1)));"") }
Bei "Excel gut" weiß man, dass das eine Arrayformel ist.
WF

AW: alle 3 Key words

09.10.2019 11:31:58

Niklas

Hi,
dann sind meine Excel Kenntnisse wohl schlechter als gedacht..
Naja, vielen Dank für die Hilfe!
VG Niklas

AW: alle 3 Key words

09.10.2019 15:23:08

Niklas

Kann man die Formel mit "und" o.Ä. erweitern, dass alle Eintragungen in E3:G3 in D vorhanden sein müssen?
Heißt, je mehr key word ich eintrage, desto weniger Ergebnisse müsste er anzeigen.
Ich probiere seit 2 Stunden daran herum und komme zu keiner Lösung..
VG Niklas

AW: auch da bedarf es keines {}-Fmlabschlusses ...

09.10.2019 16:55:30

neopa

Hallo Niklas,
... und auch kein Index, denn Du gibst ja in C3:C8 Zahlenwerte vor.
Nachstehender hab ich Dir die von Dir gemäß Deiner letzten Beschreibung nun gesuchte Formel in E11 aufgezeigt. Dazu hab ich mal willkürlich die "Beschreibungen" abgeändert, und auch die"Key-Wörter" als "key Silben" definiert, damit die Formelergebniwerte besser kontrollierbar waren.
Deine Eingangsbeschreibung konnte noch anders interpretieren. Doch die Matrixformel in C11, die dafür aufgezeigt wurde, berücksichtigt so nicht korrekt "Key-Silbe 2". Meine Formel dafür wäre die in D11.
Müsste nur ein Suchwert z.B. der in E3 berücksichtigt werden, so würde die Formel natürlich viel kürzer, dafür dann nur so: =WENNFEHLER(AGGREGAT(15;6;C$3:C$8/SUCHEN(E$3:G$3;D$3:D$8)^0;C3);"")

Arbeitsblatt mit dem Namen 'Sheet1'
	C	D	E	F	G
2	Z-Nr.	Beschreib.	1. Key Silbe	2. Key Silbe	3. Key Silbe
3	1	Elektriker	ke	eu	ch
4	2	treuer Mechaniker
5	3	Monteur
6	4	Elektriker
7	5	treue Mechatroniker Elektriker
8	6	Laborant
9
10		neopa
11	1	1	2
12	2	2	5
13	4	3
14	5	4
15		5

Zelle	Formel
C11	{=WENNFEHLER(INDEX(C:C;KKLEINSTE(WENN(ISTZAHL(SUCHEN(INDEX(E$3:G$3;VERGLEICH("*";E$3:G$3;0));D$1:D$9) );ZEILE(X$1:X$9));ZEILE(X1)));"")}
D11	=WENNFEHLER(AGGREGAT(15;6;C$3:C$8/(MMULT(ISTZAHL(SUCHEN(E$3:G$3;D$3:D$8)/(E$3:G$3&gt0))+0;{1;1;1})&gt0);C3);"")
E11	=WENNFEHLER(AGGREGAT(15;6;C$3:C$8/(MMULT(ISTZAHL(SUCHEN(E$3:G$3;D$3:D$8)/(E$3:G$3&gt0))+0;{1;1;1})=ANZAHL2(E$3:G$3));C3);"")

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

AW: auch da bedarf es keines {}-Fmlabschlusses ...

09.10.2019 17:31:04

Niklas

Hallo Werner,
vielen Dank für deine Antwort!
Jetzt passt es perfekt.
Entschuldigt die schwammige Formulierung..
VG Niklas

AW: bitteschön owT

09.10.2019 19:49:45

neopa

Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Forumthread: Index mit mehreren Lösungen

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread