Spalte A mehrerer Tabellenblätter zusammenführen

Forumthread: Spalte A mehrerer Tabellenblätter zusammenführen

19.01.2020 16:23:18

DerLeo

Ich habe ca. 100 Tabellenblätter, die in Spalte A von Zeile 4 bis Zeile 200 18-stellige ID-Nummern enthalten. Die Anzahl der Einträge je Tabelle ist verschieden.
Nun möchte ich alle IDs der Tabellenblätter Tabelle (1) bis z.B. Tabelle (100) in einer Gesamtliste in einem neuen Tabellenblatt in Spalte A auflisten.
Hat jemand eine Lösung dafür?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Spalte A mehrerer Tabellenblätter zusammenführen

19.01.2020 17:13:18

Nepumuk

Hallo Leo,
teste mal:

Option Explicit

Public Sub Zusammenfassung()

    Dim objTargetWorksheet As Worksheet
    Dim lngIndex As Long

    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    With ThisWorkbook

        Set objTargetWorksheet = .Worksheets.Add(Before:=.Worksheets(1))

        For lngIndex = 2 To .Worksheets.Count

            With .Worksheets(lngIndex)

                Call .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)).Copy( _
                    Destination:=objTargetWorksheet.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0))

            End With
        Next
    End With

    Call objTargetWorksheet.Rows(1).Delete

    Set objTargetWorksheet = Nothing

    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk

AW: Spalte A mehrerer Tabellenblätter zusammenführ

19.01.2020 18:12:33

DerLeo

Hi,
das sieht fürs Erste schon gut aus.
Es gibt auch Tabellenblätter, die keine IDs enthalten und die ich nicht auslesen möchte. Kann ich die auszulesenden Tabellenblätter definieren. z.B. Liste (1) bis Liste (100)?
Danke
DerLeo

AW: Spalte A mehrerer Tabellenblätter zusammenführ

19.01.2020 18:39:53

Nepumuk

Hallo Leo,
teste mal:

Option Explicit

Public Sub Zusammenfassung()

    Dim objTargetWorksheet As Worksheet
    Dim lngIndex As Long

    With Application
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    With ThisWorkbook

        Set objTargetWorksheet = .Worksheets.Add(Before:=.Worksheets(1))

        For lngIndex = 1 To 100

            With .Worksheets("Liste (" & CStr(lngIndex) & ")")

                Call .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)).Copy( _
                    Destination:=objTargetWorksheet.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0))

            End With
        Next
    End With

    Call objTargetWorksheet.Rows(1).Delete

    Set objTargetWorksheet = Nothing

    With Application
        .Calculation = xlCalculationAutomatic
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Gruß
Nepumuk

AW: eine Lösungsmöglichkeit dazu ...

19.01.2020 17:13:29

neopa

Hallo derLeo,
... ... könnte z.B. der Einsatz von PowerQuery sein. Google brachte mir z.B. folgenden Link:
https://www.tabellenexperte.de/massen-import-mit-powerquery/
Hab mich jetzt allerdings nicht näher damit auseinandergesetzt.
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Spalte A mehrerer Tabellenblätter zusammenführen

Forumthread: Spalte A mehrerer Tabellenblätter zusammenführen

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Spalte A mehrerer Tabellenblätter zusammenführen

Forumthread: Spalte A mehrerer Tabellenblätter zusammenführen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread