Daten aus einer Tabelle in andere

Major · 2020-03-17T14:30:26+00:00

Hallo, Ich brauche für die Arbeit ein Makro, dass mir und anderen Leuten einige Arbeit abnimmt. Es muss einen Button geben, auf den man drauf drückt und der dann den Arbeitsplatz öffnet, und dann eine Datei manuell ausgewählt werden kann. Von der Datei soll dann immer die 8te Zelle aus Spalte F in die 2te Spalte der bereits geöffneten Tabelle eingetragen werden aber vorher noch mal 1000gerechnet werden. Allerdings soll damit erst ab Zelle F40 begonnen werden. Ist das überhaupt möglich oder ist das garnicht realisiebar? Würde mir sehr weiterhelfen. LG Major

Also ich hoffe das klappt jetzt. https://www.herber.de/bbs/user/135920.xlsx
Das ist die Tabelle und aus der sollen immer die markierten Felder * 1000 genommen werden und in die 2 Spalte der Tabelle (die noch leer ist) untereinander geschrieben werden. In dieser Tabelle soll auch der Knopf sein auf den man drückt und eine Datei auswählt. Es können immer andere Dateien aus denen die Werte genommen werden (das jetzt ist nur ein Beispiel).
Außerdem ist das Beispiel auch viel zu kurz. Normalerweise stehen da noch viel mehr Zeilen unten drunter. Deshalb es soll immer das T.Small Autosomal und davon das Quantitiy Mean * 1000 gerechnet werden, bis es halt keinen Wert mehr gibt.
Ich hoffe das war jetzt nicht zu verwirrend erklärt. Wenn noch Fragen offen sind bitte immer gerne stellen :)

Hallo
dann kann ich dir das anbieten
- Erstelle ein normales Modul und kopore den Code dorthinein
- Erzeuge dir auf dem Tabellenblatt einen Button und weise Dem dann das Makro zu.
Modul1

Option Explicit 
 
Sub Datei_Verzeichnis() 
    Dim Dlg As FileDialog 
    Dim Datei As String, WB As Workbook, TB1 As Worksheet, TB2 As Worksheet 
    Dim Suchwort As String, SuchSp As Integer 
         
    'anpassen*** 
    Set TB1 = ThisWorkbook.Sheets("Tabelle1") 
    Suchwort = "T.Small Autosomal" 
    SuchSp = 4 'suchen in Spalte D 
    '*** 
     
    'Datei auswählen 
    Set Dlg = Application.FileDialog(msoFileDialogFilePicker) 'Datei wählen 
    With Dlg 
        .Filters.Add "Excelfiles", "*.xls*" 
        .InitialFileName = ThisWorkbook.Path 'Welches Verzeichnis soll voreingestellt sein 
    End With 
     
    If Dlg.Show = True Then 
        'Verhindert Bildschirmzappeln 
        Application.ScreenUpdating = False 
         
        'Name der ausgewählten Datei 
        Datei = Dlg.SelectedItems(1) 
         
        'Datei öffnen 
        Set WB = Workbooks.Open(Datei) 
        Set TB2 = WB.Sheets(1) 
         
        'Filtern 
        TB2.Columns(SuchSp).AutoFilter Field:=1, Criteria1:=Suchwort 
        With TB1 
            'Reset Zielbereich 
            .UsedRange.ClearContents 
             
            'gefilterte Zeilen kopieren 
            TB2.Cells(1, 1).CurrentRegion.Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Copy .Cells(1, 1) 
             
            'Datei schließen ohne Speichern 
            WB.Close False 
             
            'überflüssige Spalten löschen 
            .Columns(1).Resize(, SuchSp - 1).Delete xlLeft 
            .Columns(2).Delete xlLeft 
             
            'Duplikate entfernen 
            .Columns(1).Resize(, 2).RemoveDuplicates Columns:=Array(1, 2), Header:=xlNo 
             
            'Spaltenbreite 
             .Columns(1).Resize(, 2).EntireColumn.AutoFit 
 
        End With 
        MsgBox "Fertig" 
    End If 
End Sub

LG UweD

Daten aus einer Tabelle in andere

Forumthread: Daten aus einer Tabelle in andere

18
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Daten aus einer Tabelle in andere

Forumthread: Daten aus einer Tabelle in andere

18 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

18
Beiträge zum Forumthread

Beiträge zu diesem Forumthread