Aus Excel via VBA PDF in Word einfügen

Hallo zusammen,
erst einmal ein großes Lob an die Herber-Gemeinde. Dank euch bin ich innerhalb von 1 Jahr relativ fit in VBA-Programmierung geworden, praktisch von Null aus.
Habe folgendes Wehwehchen:
Für die Arbeit habe ich ein Deckblatt-Tool erstellt. Dieses füllt automatisch ein Deckblatt mit Attributen (Dokumentennummer, Revision, Ersteller, Datum, Titel usw.), macht eine PDF draus und fügt Sie als Seite 1 dem entsprechenden Dokument zu. Es dient dazu technische Doku im Anlagenbau zu ergänzen. Dort gibt es aber auch immer Excel-Listen (z.b. Armaturenlisten). Denen von Excel zu Excel ein Deckblatt zu verpassen ist nicht das Problem, die Probleme kommen erst bei bei Word-Dokumenten.
Ich kann nicht einfach die Exceltabelle in Word integrieren, da er mir die Formatierung zerschießt. So ein Musterdeckblatt in der Excel ist genau auf eine A4-Seite ausgerichtet. Ich habe gesehen, dass ich in Word aber händisch eine PDF einfügen kann. Dann muss ich noch zwei-dreimal Enter drücken, damit das Deckblatt auf Seite 1 ist und das eigentliche Dokument erst ab Seite 2 beginnt, aber dann ist es perfekt. Kein Ärger mit der Tabelle, weil es wie eine Grafik integriert ist. Das geht über Einfügen--Objekte.
Nun die Frage: Wie kriege ich es hin, dass ich aus der Excel-VBA-Routine heraus das Worddokument aufrufe und die PDF in das Dokument einfüge, einschl. der Tatsache, dass das Deckblatt Seite 1 ist und das technische Dokument von Seite2 (bis x Seiten) beginnt . Worddokument soll Word bleiben. Wir verändern Inhalt und Format der Dokumente nicht (außer ein Deckblatt davor). Kann euch leider kein Musterdeckblatt schicken aber in Ansicht--Umbruchvorschau ist es eine A4-Seite.
Word-Datei heißt Test.docx
PDF heißt Test 1.pdf
Excel heißt Test 1.xlsm
PDFPrg ist PDF 24 (geht kein Weg dran vorbei)
Öffnen kann ich die Word bereits
Pfad = "C:\Users\c15979\Desktop\Deckblatt_Muster\Test.docx"
Dim WdApp As Object
Dim wdDok As Object
Set WdApp = CreateObject("Word.Application")
Set wdDok = WdApp.documents.Open(Filename:=Pfad, ReadOnly:=True)
WdApp.Visible = True
WdApp.Activate
Das Einfügen mit Makrorekorder in Word zeigt das:
Selection.InlineShapes.AddOLEObject ClassType:="AcroExch.Document.DC", _
FileName:="", LinkToFile:=False, DisplayAsIcon:=False
Selection.TypeParagraph
Selection.TypeParagraph
Die letzen 2 Zeilen sind wohl das Enter-Drücken um den eigentlichen Text auf Seite 2 zu bekommen. Da darf er sich nicht vertun. Nicht dass ich eine Bedienungsanleitung zerschieße weil die Zeilen verrutschen.
Ich krieg die zwei Abschnitte einfach nicht zusammen.
Hoffe ihr könnt mir helfen. Danke und Gruß, und bleibt Gesund!
Carsten

Sub Deckblatt()
' Öffnen der Word-Datei
Dim WdApp As Object
Dim wdDok As Object
Dim wdRange As Object 'Word.Range
Dim Pfad As String, PfadPDF As String
Pfad = "C:\Users\c15979\Desktop\Deckblatt_Muster\Test.docx"
PfadPDF = "C:\Users\c15979\Desktop\Deckblatt_Muster\Test.pdf" 'anpassen!!!
Set WdApp = CreateObject("Word.Application")
Set wdDok = WdApp.Documents.Open(Filename:=Pfad, ReadOnly:=True)
WdApp.Visible = True
WdApp.Activate
' Einfügen der pdf
Set wdRange = wdDok.Range(0, 0)
'Seitenwechsel einfügen
wdRange.InsertBreak Type:=7 '7=wdPageBreak
Set wdRange = wdDok.Range(0, 0)
wdRange.InlineShapes.AddOLEObject ClassType:="AcroExch.Document.7", _
Filename:=PfadPDF, LinkToFile:=False, _
DisplayAsIcon:=False ' 7 evtl. durch DC ersetzen
' Set wdDok = Nothing
' Set WdApp = Nothing
End Sub