Combobox Auswahl

Walter · 2020-12-15T11:24:16+00:00

Guten Morgen, ich habe folgende Zeile im Makro für die Auswahl der Namen: Private Sub ComboBox1_DropButtonClick() If Range("A1") = 1 Then ActiveSheet.ComboBox1.ListFillRange = "AlleTage!I4:I20" nun möchte ich aber noch die Spalte J also J4:J20 und dazwischen ein Komma setzen. So geht nicht: ActiveSheet.ComboBox1.ListFillRange = "AlleTage!I4:I20 &"," & J4:J20" mfg walter

Hallo Walter,
so Ok?

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim lngRow As Long
    Dim objRange As Range, objCell As Range

    If Target.Address = "$A$1" Then
        Call ComboBox1.Clear
        Select Case Target.Value
            Case 1
                With Worksheets("Feiertage")
                    For lngRow = 4 To 20
                        ComboBox1.AddItem .Cells(lngRow, 9).Text & ", " & .Cells(lngRow, 10).Text
                    Next lngRow
                End With
            Case 2
                With Worksheets("Feiertage")
                    For lngRow = 4 To 20
                        ComboBox1.AddItem .Cells(lngRow, 12).Text & ", " & .Cells(lngRow, 14).Text
                    Next lngRow
                End With
        End Select
    Else
        Set objRange = Intersect(Range("D14:D44"), Target)
        If Not objRange Is Nothing Then
            Application.EnableEvents = False
            For Each objCell In objRange
                Select Case UCase$(objCell.Text)
                    Case "F", "U", "UU", "K"
                        objCell.Value = UCase$(objCell.Text)
                        Call objCell.Offset(0, 1).Resize(1, 3).ClearContents
                End Select
            Next objCell
            Set objRange = Nothing
            Application.EnableEvents = True
        End If
    End If
End Sub

Gruß
Nepumuk

Hallo Walter,
komisch, normalerweise speichern ActiveX-Controls auf Tabellenblättern ihre Werte. Aber bei mir verliert die ComboBox auch ihre Werte. Dann so:
Im Modul "DieseArbeitsmappe":

Option Explicit

Private Sub Workbook_Open()
Call Worksheets("Tabelle1").FillComboBox
End Sub

Im Modul der Tabelle:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objRange As Range, objCell As Range
    If Target.Address = "$A$1" Then
        Call FillComboBox
    Else
        Set objRange = Intersect(Range("D14:D44"), Target)
        If Not objRange Is Nothing Then
            Application.EnableEvents = False
            For Each objCell In objRange
                Select Case UCase$(objCell.Text)
                    Case "F", "U", "UU", "K"
                        objCell.Value = UCase$(objCell.Text)
                        Call objCell.Offset(0, 1).Resize(1, 3).ClearContents
                End Select
            Next objCell
            Set objRange = Nothing
            Application.EnableEvents = True
        End If
    End If
End Sub

Public Sub FillComboBox()
    Dim lngRow As Long
    Call ComboBox1.Clear
    Select Case Cells(1, 1).Value
        Case 1
            With Worksheets("Feiertage")
                For lngRow = 4 To 20
                    ComboBox1.AddItem .Cells(lngRow, 9).Text & ", " & .Cells(lngRow, 10).Text
                Next lngRow
            End With
        Case 2
            With Worksheets("Feiertage")
                For lngRow = 4 To 20
                    ComboBox1.AddItem .Cells(lngRow, 12).Text & ", " & .Cells(lngRow, 14).Text
                Next lngRow
            End With
    End Select
End Sub

Gruß
Nepumuk

Forumthread: Combobox Auswahl

39
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Combobox Auswahl

Forumthread: Combobox Auswahl

39 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

39
Beiträge zum Forumthread

Beiträge zu diesem Forumthread