Ordner öffnen mit teilw. bekanntem Namen

Stefan · 2021-03-02T09:43:38+00:00

Hallo Excel/VBA-Gemeinde, für mein Problem, bin ich hier im Forum Archiv bereits zu einem entsprechenden VBA Code fündig geworden. Allerdings benötige ich hier doch noch Hilfe, da meine VBA Kenntnisse dann nicht so umfangreich sind. Es geht um den Code aus dem Thread: https://www.herber.de/forum/archiv/1272to1276/1274048_ordner_suchen_mit_teilweise_bekannte_namen.html#bottom Für mein Problem möchte ich letztlich nur, dass sich der Ordner mit dem Suchbegriff öffnen. Es muss keine Datei gesucht und geöffnet werden. Meine bisherigen Versuche den Quellcode so anzupassen, dass das Makro es so tut sind leider gescheitert. Kann mir hier jemand bei der Lösung helfen. Oder muss es ein ganz neuer Code sein? Vielen Dank für eure Hilfe.

Hallo Stefan,
teste mal. Der Ordner der gesucht werden soll enthält den Namen Test.

Option Explicit

Private Declare PtrSafe Function ShellExecuteA Lib "shell32.dll" ( _
    ByVal hwnd As LongPtr, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As LongPtr

Private Const SW_SHOWNORMAL As Long = 1

Public Sub Test()

    Dim strFolder As String

    If SearchFolder("Test", strFolder) Then

        Call ShellExecuteA(0, "OPEN", strFolder, vbNullString, vbNullString, SW_SHOWNORMAL)

    Else

        Call MsgBox("Ordner nicht gefunden.", vbExclamation, "Hinweis")

    End If
End Sub

Private Function SearchFolder(ByVal pvstrSearchText As String, ByRef pvstrFolder As String) As Boolean

    Const FOLDER_PATH As String = "G:\Eigene Dateien\" 'Ordner in dem gesucht werden soll

    Dim strFolder As String, strPath As String
    Dim astrFolders() As String
    Dim ialngIndex1 As Long, ialngIndex2 As Long
    Dim blnFound As Boolean

    strPath = FOLDER_PATH

    If Right$(strPath, 1) <> "\" Then strPath = strPath & "\"

    Do

        strFolder = Dir$(PathName:=strPath & "*", Attributes:=vbDirectory)

        Do Until strFolder = vbNullString

            If strFolder <> "." And strFolder <> ".." Then

                If GetAttr(PathName:=strPath & strFolder) And vbDirectory Then

                    If InStr(1, strFolder, pvstrSearchText, vbTextCompare) > 0 Then

                        SearchFolder = True
                        pvstrFolder = strPath & strFolder & "\"
                        blnFound = True
                        Exit Do

                    Else

                        Redim Preserve astrFolders(0 To ialngIndex1)
                        astrFolders(ialngIndex1) = strPath & strFolder & "\"
                        ialngIndex1 = ialngIndex1 + 1

                    End If
                End If
            End If

            strFolder = Dir$

        Loop

        If blnFound Then Exit Do

        If ialngIndex1 = ialngIndex2 Then Exit Do

        strPath = astrFolders(ialngIndex2)
        ialngIndex2 = ialngIndex2 + 1

    Loop
End Function

Gruß
Nepumuk

Hallo Nepumuk, ich meinte es wie folgt:
Der Nutzer startet das Makro durch einen "verlinkten" Button.
Dieser ruft das Makro auf und startet es automatisch.
Es wird der Suchstring aus einer Bildschirmmaske ausgelesen (das hatte ich programmiert) und der im Makro hinterlegte Pfad nach dem Ordner mit Suchstring durchsucht.
Wird der Ordner gefunden, wird er geöffnet, andernfalls kommt ein Hinweis. Das hast Du freundlicherweise programmiert.
Ich bekomme zwar hin, dass das Makro nach Aufruf startet, den Suchstring ausliest und den Ordner sucht, öffnet oder einen Hinweis auswirft. Ich bekomme es jedoch nicht hin, dass sich das Makro und Excel (wenn es die einzige offene Datei gewesen war) schliesst. Auch bekomme ich es nicht hin, dass Excel im Hintergrund ist, wenn das Hinweisfenster erscheint.
Ich hoffe ich konnte deutlichmein Problem beschreiben. Soll ich ggf. mal den Code posten oder eine Datei? Viele Grüße aus dem Norden..... Stefan

Ordner öffnen mit teilw. bekanntem Namen

Forumthread: Ordner öffnen mit teilw. bekanntem Namen

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Ordner öffnen mit teilw. bekanntem Namen

Forumthread: Ordner öffnen mit teilw. bekanntem Namen

15 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

15
Beiträge zum Forumthread

Beiträge zu diesem Forumthread