Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1848to1852
1848to1852
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

.Range(lastrow, 2)

Forumthread: .Range(lastrow, 2)

.Range(lastrow, 2)
04.10.2021 09:31:06
Eisi
Guten Morgen :-)
seit Freitag hänge ich fest. Kann man anhand der Codezeilen bereits den Fehler erkennen?
Es soll ein dynamischer Bereich nach Sheet PDF in die Spalte B .... 2 Leerzellen unter der letzten befüllten Zelle kopiert werden.
Im Moment also B2 = letzte Zelle, Zielzelle soll dann B5 sein.
-----------------------------------------------------------------------------------------------------------------
Dim lastrow As Long ' Ist Long richtig oder Range ?
lastrow = Worksheets("PDF").Range("B2000").End(xlUp).Row + 2
'merke dir die 2. Zelle nach der letzten befüllten Zelle in Spalte B
-----------------------------------------------------------------------------------------------------------------
' kopiere den Bereich aus Sheet: Leerzeilen_ausblenden nach ->> Sheet: PDF
With Leerzeilen_ausblenden
lngZeileMax = .Range("A" & .Rows.Count).End(xlUp).Row
Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
rngBereich.Copy Sheets("PDF").Range(lastrow, 2)
' Das geht: rngBereich.Copy
' ? Dieser Teil geht nicht: Sheets("PDF").Range(lastrow, 2) ?
' kopiere den Bereich aus Sheet: Leerzeilen_ausblenden nach ->> Sheet: PDF. In der Zelle B2 steht der letzte Inhalt.
End With
-----------------------------------------------------------------------------------------------------------------
Vielen Dank für die Hilfe.
VG Eisi :-)
Anzeige

11
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 09:36:31
Klaus
ungetestet:

Dim lastrow As Long 'LONG IST KORREKT
lastrow = Worksheets("PDF").Range("B2000").End(xlUp).Row + 2
'merke dir die ZEILE DER 2. Zelle nach der letzten befüllten Zelle in Spalte B
' kopiere den Bereich aus Sheet: Leerzeilen_ausblenden nach ->> Sheet: PDF
With Leerzeilen_ausblenden
lngZeileMax = .Range("A" & .Rows.Count).End(xlUp).Row
Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
rngBereich.Copy
End With
Sheets("PDF").Range(lastrow, 2).PasteSpecial
LngZeileMax ist nicht dimensioniert, rngBereich ebenso nicht. Aber ich nehme an, das wird in dem Bereich des Makro erledigt welches du nicht zeigen wolltest :-)
LG,
Klaus M.
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 09:40:39
Klaus
Noch ein bisschen aufgeräumt. Man sieht, dass du viel Copy&Paste benutzt. Gewöhne dir an, Code einheitlich zu beschreiben (nicht einmal cells und einmal Range, um eine Zeile zu ermitteln ...) sonst wird er mit der Zeit unlesbar.

Dim lastRow As Long 'LONG IST KORREKT
With Sheets("PDF")
lastRow = .Cells(.Rows.Count, 2).End(xlUp).Row + 2
End With
'merke dir die ZEILE DER 2. Zelle nach der letzten befüllten Zelle in Spalte B
' kopiere den Bereich aus Sheet: Leerzeilen_ausblenden nach ->> Sheet: PDF
With Sheets("Leerzeilen_ausblenden")
lngZeileMax = .Cells(.Rows.Count, 1).End(xlUp).Row
Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
rngBereich.Copy
End With
Sheets("PDF").Range(lastRow, 2).PasteSpecial

Anzeige
AW: .Range(lastrow, 2)
04.10.2021 10:22:33
Eisi
Hallo Klaus,
vielen Dank für Deine Hilfe. Ich hänge mal den kompletten Code an, weil noch immer eine Fehlermeldung kommt:
Fehlermeldung: Sheets("PDF").Range(lastrow, 2).PasteSpecial
______________________________________________________________________________

Sub PlattenKopieren()
Application.ScreenUpdating = False
'*** Deklaration ***
Dim lngZeileMax As Long
Dim rngBereich As Range
Dim lastrow   As Long
'*** merke dir die 2. Zelle nach der letzten befüllten Zelle in Spalte B ***
'        lastrow = Worksheets("PDF").Range("B2000").End(xlUp).Row + 2
'*** Zelleninhalte mit Formatierung im Sheet: PDF löschen ***
PDF.Activate
Range("F1").Activate
With ActiveCell.CurrentRegion
.Clear                                    'Clear löscht den Inhalt + Formatierung
End With
'*** merke dir die ZEILE DER 2. Zelle nach der letzten befüllten Zelle in Spalte B ***
With Sheets("PDF")
lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row + 2
End With
'*** kopiere den Bereich aus Sheet: Leerzeilen ausblenden
With Sheets("Leerzeilen ausblenden")
lngZeileMax = .Cells(.Rows.Count, 1).End(xlUp).Row
Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
rngBereich.Copy
End With
'*** Füge die Kopie (rngBereich) in das ->> Sheet: PDF ein ***
Sheets("PDF").Range(lastrow, 2).PasteSpecial    ' ? Hier kommt die Fehlermeldung ?
'*** Letzte Zellen der Tabelle in Sheet ->> PDF: Dicke Linie erzeugen ***
PDF.Activate
Range("F1").Activate
With ActiveCell.CurrentRegion
.Borders(xlEdgeBottom).Weight = xlMedium  'Dicke Linie am Ende der Tabelle erzeugen
End With
'*** Zurück zum AusgangsSheet springen ***    '
Leerzeilen_ausblenden.Activate
Range("A1").Activate
endmacro:
Application.ScreenUpdating = True
End Sub
_________________________________________________________________
Vielen Dank :-)
VG Eisi :-)
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 11:03:57
Klaus
Moin,
müsste eigentlich funktionieren. Nur aus Spaß, setzt "PDF.activate" mal VOR das Pastespecial, vielleicht hilft das schon.
auf .select und .activate sollte man möglichst verzichten. Kannst du einmal eine Musterdatei hochladen, dann schaue ich mir das genau an. Nur mit dem Code kann ich ja nicht gut testen.
LG,
Klaus M.
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 11:29:16
Klaus
Schnell gelöst:

'*** 5) Füge die Kopie (rngBereich) in das ->> Sheet: PDF ein ***
'    PDF.Activate  'Hat keine Auswirkung
Sheets("PDF").Cells(lastrow, 2).PasteSpecial  'CELLS, nicht RANGE!
ich poste gleich nochmal eine Verbesserung.
LG,
Klaus M.
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 11:36:35
Klaus
Was die "CurrentRegion" Sache macht habe ich nicht verstanden - Fette Linien hat sie bei mir nicht erzeugt, und warum sie auf F1 abziehlt war mir auch nicht klar. Darum habe ich das rausgeworfen. Das Makro sollte so bereits ausreichend sein, habe die Reihenfolge geändert und die WITH-Blöcke zusammen gezogen um zu kürzen. Select und Activate habe ich entfernt.

Sub PlattenKopieren()
Application.ScreenUpdating = False
'*** 1) Deklaration ***
Dim lngZeileMax As Long
Dim rngBereich As Range
Dim lastrow   As Long
'*** 4) kopiere den Bereich aus Sheet: Leerzeilen ausblenden
With Leerzeilen_ausblenden
lngZeileMax = .Cells(.Rows.Count, 1).End(xlUp).Row
Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
rngBereich.Copy
End With
'*** 3) merke dir die ZEILE DER 2. Zelle nach der letzten befüllten Zelle in Spalte B ***
With PDF
lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row + 2
'*** 5) Füge die Kopie (rngBereich) in das ->> Sheet: PDF ein ***
.Cells(lastrow, 2).PasteSpecial  'CELLS, nicht RANGE!
End With
Application.ScreenUpdating = True
End Sub
LG,
Klaus M.
Anzeige
AW: .Range(lastrow, 2)
04.10.2021 11:58:11
Eisi
Hallo Klaus,
vielen herzlichen Dank, läuft perfekt. :-)
Folgenden Code brauche ich, wenn die Zelle innerhalb der Tabelle leer ist und ich diese ausblende. Dann ist der Zellenrahmen mit einer dünnen Linie gesetzt.
Als Endergebnis soll aber um die neue Tabelle komplett immer eine dicke Linie eingestellt sein. Die Linien oben, links und rechts der Tabelle sind immer dick, nur die untere Linie eben nicht immer. Darum der Code.
With ActiveCell.CurrentRegion
.Borders(xlEdgeBottom).Weight = xlMedium 'Dicke Linie am Ende der Tabelle erzeugen
End With
Nochmal vielen herzlichen Dank für Deine super Unterstützung.
GLG Eisi :-)
Anzeige
Rückfrage an Klaus____AW: .Range(lastrow, 2)
04.10.2021 15:49:16
Eisi
https://www.herber.de/bbs/user/148428.xlsm
Hallo Klaus,
ich hänge immer noch. Wie kann ich in den Zellen B:C den Rahmen setzen? Siehe bitte Datei im Anhang.
'*** 5) Formatiere die Linie dick in der letzten Tabelle, der letzten Zeile
With PDF
lngZeileMaxFormat = .Cells(.Rows.Count, 3).End(xlUp).Row ' Finde die letzte Zelle in Spalte 3
Set rngBereichFormat = .Range("B" & lngZeileMaxFormat) ' Markiere die letzten Zellen in Spalte B:C 'Hier kommt die Fehlermeldung !!!!!!!!!!!!!!!!!!
rngBereichFormat.Borders(xlEdgeBottom).Weight = xlMedium
End With
Vielen Dank.
VG
Eisi :-)
Anzeige
gelöst :-) ____AW: .Range(lastrow, 2)
04.10.2021 16:52:02
Eisi
Unfassbar, ich habe die Lösung gefunden :-)
'*** 5) Formatiere die Linie dick in der letzten Tabelle, der letzten Zeile
With PDF
Set rngBereichFormat = .Range("B1:C" & .Range("C" & Rows.Count).End(xlUp).Row)
rngBereichFormat.Borders(xlEdgeBottom).Weight = xlMedium
End With
Anzeige
gut gemacht! o.w.T.
05.10.2021 06:58:36
Klaus
.
;

Forumthreads zu verwandten Themen

Schnellster Weg gesucht: Rows löschen in Range
Holger,

Hallo an die Profis und Interessierten,
Wege gibt es viele, aber heute suche ich den wirklich schnellsten und elegantesten.
Ich habe einen Range definiert vz.b. on A19 bis J250 (im Project fast 300.000 Rows,
daher ist die Schnelligkeit wichtig)
Wenn hier in Spalte C, D oder E ei...
14.01.2011 10:17:30
Thread-ID: 1195592
8 Beiträge
Anzeige
Schleife For i = 2 to ?
Jonas

Hallo zusammen,
versuche gerade meine erste Schleife zu programmieren (s.u.). Eigentlich funktioniert sie super. Das einzige Problem ist mit "For i = 1 To 10". Habe schon gesucht. Die 10 muss eine Variable sein, sprich bis zur letzten gefüllten Zeile, soll der Befehl ausgeführt werden.
...
28.08.2012 12:12:54
Thread-ID: 1276674
10 Beiträge
VBA Pivot Lastrow für Tabledestination
Malte

Hallo,
ich habe ein Tabellenblatt auf dem vier Pivottabellen dargestellt werden sollen. Zwei nebeneinander und zwei darunter.
Zuerst werden die oberen beiden Pivottabellen eingefügt per Makro. Da die erstellten Pivots in der länge variieren können, möchte ich für die zwei darunter kein...
27.11.2013 15:24:14
Thread-ID: 1340254
9 Beiträge
IngRow / IngLast Anwendung VBA
Anne

Guten Abend, ich benötige mal Unterstützung:
mir ist die Anwendung von IngRow und IngLast in VBA nicht klar. Kann mir das jemand kurz an diesem Beispiel erklären?
Ich habe diesen Code, der bewirkt, dass Duplikate in Spalte C erkannt werden und je nach dem in welcher Zeile das jeweils a...
18.02.2019 19:30:12
Thread-ID: 1676374
8 Beiträge
Anzeige
FOR-Anweisung kombinieren i=1 To 20 AND i=22 To 30
Thorsten Becker
Hallo Experten,
gibt es eine Möglichkeit, wie im Betreff angedeutet, FOR-Anweisungen zu verbinden, und zwar in der folgenden Art und Weise:
FOR zeile=1 To 20 AND 30 To 40 AND 50 To 60
...
Next zeile
Wenn nicht, gibt es eine anderweitige Möglichkeit, diese Art von Anweisung zu erste...
04.03.2004 14:28:01
Thread-ID: 392608
8 Beiträge
for iCol=22To42......aber nur die geraden Spalten
Peter

Hallo und Guten Morgen,
mit untenstehendem Code möchte ich aus dem Spreadsheet heraus Werte in die Tabelle schreiben.....funktioniert auch einwandfrei....ich möchte jedoch bei den Spaltenangaben zwischen 22 und 42 nur die "geraden" Spalten ansprechen, in den "ungeraden" Spalten dürfen keine...
05.08.2004 08:22:38
Thread-ID: 465063
4 Beiträge
Aus Row&Column wieder ein Range Objekt machen?
Torsten

moin,
ich habe gerade ein Problem, ich benötige ein Range Objekt á la
Range("A1")
was habe ich zur verfügung?
Zeile = 1
Spalte = 1
meines erachtens geht es bei range nicht direkt per ...range(1,1) - also müsste ich doch die zahl zum buchstabben umwandeln und sie als str...
21.09.2006 13:12:51
Thread-ID: 804190
3 Beiträge
Anzeige
Change "EntireRow.Copy" in range
Johannes
Hallo zusammen
ich habe einen code gefunden, der mir genau das macht, was ich brauche und ihn angepasst.(fast)
Der code sucht in allen ws in den Zellen R8:R36 nach dem Text "good", und wenn er fündig wird, dann
kopiert er die ganze reihe auf die Seite "Best".
Ich hätte aber gerne nur...
07.07.2022 10:03:23
Thread-ID: 1890199
11 Beiträge
Aus 2 gefundenen Row eine Range machen
M@tt
Hallo,
ich finde mit dem CodeSet finden1 = Range("A1:A150").Find(what:="Berichtsdetails") Set finden2 = Range("A1:A150").Find(what:="Berichtsdatum")
2 Row's oder auch address, einmal z.B in Zeile 14 und einmal 21, wie mache ich daraus eine Range? Range("A14:A21") um diese Werte dann z.B. zu...
25.02.2023 14:07:00
Thread-ID: 1921718
2 Beiträge
.End(xlDown).Row - Eleganter möglich in einer def. Range?
Ralf
Hallo liebes Forum,

ich habe eine Frage bzw. benötige einen Hinweis für die Ermittlung der letzten Benutzenzeile in einer Range. Im Grunde ist das Ermitteln dieser Spalte durch die Funtkion der SpecialCells oder der .End(xlDown) Funktion relativ einfach. Dennoch habe ich mir im Kopf irgendw...
23.09.2023 13:36:23
Thread-ID: 1947122
5 Beiträge
Anzeige

Infobox / Tutorial

Dynamische Bereiche in Excel VBA: Mit der letzten Zeile arbeiten

Schritt-für-Schritt-Anleitung

Um dynamische Bereiche in Excel VBA zu erstellen und mit der letzten Zeile zu arbeiten, kannst du den folgenden Code verwenden. Dieser Code kopiert Daten aus einem Arbeitsblatt ("Leerzeilen_ausblenden") in ein anderes Arbeitsblatt ("PDF"), wobei die letzten befüllten Zellen berücksichtigt werden.

Sub PlattenKopieren()
    Application.ScreenUpdating = False
    Dim lngZeileMax As Long
    Dim rngBereich As Range
    Dim lastrow As Long

    ' Merke dir die ZEILE DER 2. Zelle nach der letzten befüllten Zelle in Spalte B
    With Sheets("PDF")
        lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row + 2
    End With

    ' Kopiere den Bereich aus "Leerzeilen ausblenden"
    With Sheets("Leerzeilen ausblenden")
        lngZeileMax = .Cells(.Rows.Count, 1).End(xlUp).Row
        Set rngBereich = .Range("A1:B" & lngZeileMax + 1)
        rngBereich.Copy
    End With

    ' Füge die Kopie (rngBereich) in das Sheet "PDF" ein
    Sheets("PDF").Cells(lastrow, 2).PasteSpecial
    Application.ScreenUpdating = True
End Sub

In diesem Code wird die letzte befüllte Zeile in Spalte B ermittelt, indem End(xlUp) verwendet wird. Dies ist besonders nützlich, wenn du mit einer ungewissen Anzahl von Daten arbeitest.

Häufige Fehler und Lösungen

  1. Fehlermeldung bei PasteSpecial:

    • Ursache: Wenn du .Range(lastrow, 2).PasteSpecial verwendest, kann es zu einer Fehlermeldung kommen.
    • Lösung: Verwende stattdessen .Cells(lastrow, 2).PasteSpecial, um sicherzustellen, dass du die Zelle korrekt referenzierst.

  2. Variable nicht dimensioniert:

    • Ursache: Wenn du eine Variable wie lngZeileMax nicht deklarierst.
    • Lösung: Stelle sicher, dass alle Variablen ordnungsgemäß deklariert sind.

Alternative Methoden

Eine alternative Methode zur Ermittlung der letzten Zeile in einem Arbeitsblatt ist die Verwendung von UsedRange. Hier ein Beispiel:

lastrow = Sheets("PDF").UsedRange.Rows.Count

Diese Methode ist schneller, wenn du sicher bist, dass keine leeren Zeilen in deinem Datensatz vorhanden sind.

Praktische Beispiele

Wenn du eine Schleife verwenden möchtest, um durch die Zeilen zu iterieren, kannst du dies wie folgt tun:

For i = 2 To lastrow
    ' Deine Logik hier
Next i

Dies wäre nützlich, wenn du mehrere Operationen auf den Zellen in den letzten Zeilen ausführen möchtest.

Tipps für Profis

  • Vermeide die Verwendung von .Select und .Activate, um den Code effizienter zu gestalten.
  • Nutze With...End With Blöcke, um den Code lesbarer und performanter zu machen.
  • Wenn du mit großen Datenmengen arbeitest, erwäge die Verwendung von Application.ScreenUpdating = False, um die Performance zu verbessern.

FAQ: Häufige Fragen

1. Wie finde ich die letzte befüllte Zelle in einer bestimmten Spalte? Du kannst die End(xlUp) Methode verwenden, um die letzte befüllte Zelle in einer Spalte zu finden. Beispiel: 

lastrow = Worksheets("Sheet1").Range("B2000").End(xlUp).Row

2. Was ist der Unterschied zwischen .Range und .Cells? .Range wird verwendet, um einen Bereich von Zellen zu definieren, während .Cells verwendet wird, um auf eine bestimmte Zelle zuzugreifen, basierend auf ihrer Zeilen- und Spaltennummer.

Durch das Befolgen dieser Anleitungen und Lösungen kannst du sicherstellen, dass du mit der letzten Zeile in Excel VBA effizient arbeitest und häufige Fehler vermeidest.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige