Tabelle in Liste

Forumthread: Tabelle in Liste

Tabelle in Liste

11.03.2022 17:33:00

Sammy

Hallo liebe Formelakrobaten,
ich möchte gern alle Werte einer Tabelle auslesen und unter Auslassung von Doppellungen sowie Nichtberücksichtigung von leeren Zellen in einer Spalte darstellen. Hat jemand einen Tipp wie das umzusetzen wäre? Beispiel:
Userbild

Viele Grüße

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: ein Lösung ganz ohne Formeln/VBA wäre ...

11.03.2022 18:47:13

neopa

Hallo Sammy,
... abhängig von der Excelversion in der Du dies realisieren willst. Welche ist das bei Dir?
Ab XL2016 könntest Du dies z.B. mit Power Query (PQ) realisieren, wozu man nur wenige Mausklicks benötigt (natürlich gewusst wo und wie). Dazu (in Kurzfassung) liest Du die Datentabelle ein, fügst in PQ eine INDEXSpalte hinzu und danach "entpivotiert" alle nach dieser. In der dadurch neu entstehenden Spalte "Wert" entfernt man die Duplikate, löscht noch die anderen Spalten und schließt PQ mit Speichern des Ergebnisses in dem von Dir zu bestimmten Tabellenzellbereich.
Mehr zu PQ sieh mal hier: https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/
Gruß Werner
.. , - ...

AW: ein Lösung ganz ohne Formeln/VBA wäre ...

12.03.2022 16:28:47

Sammy

Hallo Werner,
ich habe mich ein klein wenig mit den Schalflächen unter "Daten" beschäftigt. Die Umwandlung von Tabelle zu Liste sollte allerdings für eine größere Anzahl von Tabellenblättern und auch dynamisch erfolgen, so dass manuelles "Klicken" eher nicht in Frage kommt.
Sammy

AW: Tabelle in Liste

11.03.2022 18:50:19

Luschi

Hallo Sammy,
bei der Voraussetzung: Kaum Excel/VBA-Kenntnisse
könntest Du wenigstens mehr Einsatzfreude zeigen und die erforderliche Demodatei zum Testen selbst erstellen.
Gruß von Luschi
aus klein-Paris
PS: Freitag ab eins - macht jeder seins!
noch 1 PS: die Angabe: xlVersion: Ohne Relevanz ist sowas von Fehleinschätzung, denn die neuen Excel-365-Versionen haben was drauf, davon kann Excel 95. 97, ff. nur träumen!

AW: nach XL95 & vor XL365 gab/gibts auch noch ...

11.03.2022 19:24:55

neopa

Hallo Luschi.
... andere XL-Versionen, mit der man dies auch ohne VBA und PQ lösen könnte.
Aber meine folgende Formel für eine Version ab XL2010 und vor XL365 hab ich bewusst Sammy nicht (als erstes) vorsetzen wollen. Hier mal nur die, wo die Ergebnisdaten nur zufällig nach Alphabet sortiert gelistet werden.
Für eine korrekte alphabetische Sortierung bei beliebiger Datenanordnung wird die Formel noch länger.
In D6:
=WENNFEHLER(INDEX(A:C;KÜRZEN(AGGREGAT(14;6;(ZEILE(A$1:A$9)+SPALTE(A1:C1)%)/(ZÄHLENWENN(D$5:D5;$A$1:$C$9)=0)/(A$1:C$9"");1);0);REST(AGGREGAT(14;6;(ZEILE(A$1:A$9)+SPALTE(A1:C1)%)/(ZÄHLENWENN(D$5:D5;$A$1:$C$9)=0)/(A$1:C$9"");1);1)*100);"")
und weit genug nach unten kopieren.
IN XL365 sollte eine Formellösung mit EINDEUTIG() und SORTIEREN() einfacher sein.
Gruß Werner
.. , - ...

AW: nach XL95 & vor XL365 gab/gibts auch noch ...

12.03.2022 16:39:59

Sammy

Hallo Werner,
ich nutze Excel 2019 für MAC OS. Ich habe mich ein wenig mit den Schaltflächen und Möglichkeit unter "Daten" beschäftigt, allerdings soll die Wandlung von Tabelle zu Liste für mehrere Blätter und auch dynamisch passieren. Daher kommt die Variante "Klicken" eher nicht in Frage.
Die Formel hingehen liefert ein sehr sehr brauchbares Ergebnis. Allerdings ist es mir beim Übernehmen/Abwandeln der Formel nicht gelungen, den Tabellenbereich zu vergrößern und die Zielzelle für die Formel anzupassen. Die Liste soll in B10 beginnen, und der Tabellenbereich geht von B2:F7. Folgende Formel kommt zur Anwendung und liefert aber leider nicht das gewünschte Ergebnis.
=WENNFEHLER(INDEX(B:F;KÜRZEN(AGGREGAT(14;6;(ZEILE(B$2:B$7)+SPALTE(B2:F2)%)/(ZÄHLENWENN(B$9:B9; $B$2:$F$7)=0)/(B$2:F$7"");1);0);REST(AGGREGAT(14;6;(ZEILE(B$2:B$7)+SPALTE(B2:F2)%) /(ZÄHLENWENN(B$9:B9;$B$2:$F$7)=0)/(B$2:F$7"");1);1)*100);"")
angepasst aus:
=WENNFEHLER(INDEX(A:C;KÜRZEN(AGGREGAT(14;6;(ZEILE(A$1:A$9)+SPALTE(A1:C1)%)/(ZÄHLENWENN(D$5:D5; $A$1:$C$9)=0)/(A$1:C$9"");1);0);REST(AGGREGAT(14;6;(ZEILE(A$1:A$9)+SPALTE(A1:C1)%) /(ZÄHLENWENN(D$5:D5;$A$1:$C$9)=0)/(A$1:C$9"");1);1)*100);"")
Viele Grüße
Sammy

AW: für den nun auszuwertenden Datenbereich ...

12.03.2022 17:09:38

neopa

Hallo Sammy,
... sieht die angepasste Formel in B10 korrekt wie folgt aus:
=WENNFEHLER(INDEX(A:F;KÜRZEN(AGGREGAT(14;6;(ZEILE(B$2:B$7)+SPALTE(B2:F2)%)/(ZÄHLENWENN(B$9:B9;B$2:F$7)=0)/(B$2:F$7"");1);0);REST(AGGREGAT(14;6;(ZEILE(B$2:B$7)+SPALTE(B2:F2)%)/(ZÄHLENWENN(B$9:B9;B$2:$F$7)=0)/(B$2:F$7"");1);1)*100);"")
und diese weit nach unten kopieren.
Da Du nichts dazu geschrieben hast, ist das Ergebnis dieser Formel ein Listing ohne Duplikate aber noch nicht alphabetisch sortiert.
Noch zu Deiner Aussage: "... kommt die Variante "Klicken" eher nicht in Frage"
Wenn einmal der M-Code durch "Klicken" erstellt ist, muss standardmäßig bei veränderte Daten nur noch max einmal einen "Aktualisierungsbutton" klicken.
Gruß Werner
.. , - ...

AW: für den nun auszuwertenden Datenbereich ...

12.03.2022 19:16:20

Sammy

Hallo Werner,
Vielen Dank für die Formel ... man kann einem eben doch "kein B für ein A vormachen".... wenn es um Excel geht :-)
Mit "sehr sehr brauchbares Ergebnis" meinte ich zu insinuieren, dass die alphabetische Reihenfolge für meinen Anwendungsfall gar nicht mehr unbedingt notwendig ist. Die Formel ist mit schon komplex genug und wie du schriebst, wird sie mit dem Ordnen noch komplexer.
Einen schönen Abend
Sammy

AW: bitteschön und ja, ...

12.03.2022 20:30:03

neopa

Hallo Sammy,
... die Formelauswertung für eine alphabetisch sortierte Ausgabe ist in dieser XL-Version wesentlich komplexer als mit XL365. Ich dachte auch erst, es geht nur mit einer Hilfsspalte. Hab aber eine Lösungsformel gefunden, die ohne eine solche auskommt. Damit die Formel jedoch nicht völlig unübersichtlich lang wird, hab ich darin notwendige Teilformeln als sogenannte benannte Formeln im Namensmanager definiert. Und zwar dies bei aktivierter Zelle B10 (wichtig!).
Das Tabellenblatt heißt bei mir nur "Dat" und die Bezeichnung der 2 benannten Formeln ist willkürlich gewählt.
Die nachfolgende Zellformel in B10 muss dann lediglich weit genug nach unten kopiert werden.

Arbeitsblatt mit dem Namen 'Dat'
	B	C	D	E	F
2	Katze
3		Zobel		Kater	Maus
4	Hund	Hamster	Dino	Adler
5	Löwe	Dino
6				Maus
7	Kater				Löwe
8
9
10	Adler
11	Dino
12	Hamster
13	Hund
14	Kater
15	Katze
16	Löwe
17	Maus
18	Zobel
19

Name	Bezug
_VglMtx_1	=AGGREGAT(15;6;ZÄHLENWENN(Dat!$B$2:$F$7;"&lt="&Dat!$B$2:$F$7)/(Dat!$B$2:$F$7>"")/(ZÄHLENWENN(Dat!B$9:B1;Dat!$B$2:$F$7)=0);1)=ZÄHLENWENN(Dat!$B$2:$F$7;"&lt="&Dat!$B$2:$F$7)
_VglMtx_2	=(ZEILE(Dat!$B$2:$B$7)+SPALTE(Dat!$B20:$F2)%)/(ZÄHLENWENN(Dat!B$9:B1;Dat!$B$2:$F$7)=0)/(Dat!$B$2:$F$7>"")

Zelle	Formel
B10	=WENNFEHLER(INDEX(A:F;KÜRZEN(AGGREGAT(15;6;_VglMtx_2/_VglMtx_1;1);0);REST(AGGREGAT(15;6;_VglMtx_2/_VglMtx_1;1);1)*100);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

AW: Tabelle in Liste

11.03.2022 19:15:10

Daniel

Hi
Ungetestet für 365
=Eindeutig(XmlFilter("<a><b>"&Textverketten("</b><b>";wahr;A1:C3)&"</b> </a>";"//a/b"))
Gruß Daniel

AW: Tabelle in Liste

12.03.2022 16:42:03

Sammy

Hallo Daniel,
danke für den Vorschlag. Da ich leider Excel for MAC OS nutze, kann ich leider nicht auf FILTERXML zurückgreifen.
Grüße
Sammy

AW: Tabelle in Liste

14.03.2022 23:55:49

Daniel

Sorry, verstehe dein Problem nicht.
Du hattest doch angegeben, dass die Excelversion ohne Relevanz ist.

Beliebteste Forumthreads (12 Monate)

Forumthread: Tabelle in Liste

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Tabelle in Liste

Forumthread: Tabelle in Liste

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread