Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1928to1932
1928to1932
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Inhalt zwischen files\ und \ auslesen

Forumthread: Inhalt zwischen files\ und \ auslesen

Inhalt zwischen files\ und \ auslesen
16.05.2023 19:54:31
Hana

Hallo Leute,

wie kann ich bitte per Formel den Inhalt zwischen files\ und nächstem \ auslesen?

P:\Daten\2023\Projekte\2500870\files\808357\BHD_Liste.txt

Ergebnis: 808357

Besten Dank im Voraus!

Gruß
Hana

Anzeige

20
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Inhalt zwischen files\ und \ auslesen
16.05.2023 20:09:27
HeritzP
Hallo,

so wenn flexibel.
=TEIL(WECHSELN(A1;"\";"#";6);FINDEN("#";WECHSELN(A1;"\";"#";6);1)+1;6)

und fest.

=TEIL(WECHSELN(A1;"\";"#";6);38;6)


=TEIL(A1;38;6) owt
16.05.2023 20:19:49
HeritzP


AW: Inhalt zwischen files\ und \ auslesen
16.05.2023 20:42:26
Hana
Hallo,

es sieht schön mal gut aus :-)

Ganz flexibel ist es nicht, wenn der Inhalt zwischen files\ und nächstem \ nicht gleichen Anzahl der Zeichen hat.

Beste Grüße,
Hana


Anzeige
AW: Inhalt zwischen files\ und \ auslesen
16.05.2023 21:08:59
ralf_b 
=TEIL(A1;FINDEN("files\";A1)+LÄNGE("files\");FINDEN("|";WECHSELN(A1;"\";"|";LÄNGE(A1) -LÄNGE(WECHSELN(A1;"\";""))))-(FINDEN("files\";A1)+LÄNGE("files\")))


AW: Inhalt zwischen files\ und \ auslesen
16.05.2023 22:17:53
onur
Wenn der Pfad in A1 steht:
=LINKS(TEIL(A1;SUCHEN("files";A1)+7;999);SUCHEN("\";TEIL(A1;SUCHEN("files";A1)+7;999))-1)


Anzeige
AW: Inhalt zwischen files\ und \ auslesen
16.05.2023 22:38:49
onur
Sorry, kleiner Fehler.
=LINKS(TEIL(A1;SUCHEN("files";A1)+6;999);SUCHEN("\";TEIL(A1;SUCHEN("files";A1)+6;999))-1)


Außer Konkurrenz
17.05.2023 06:01:41
RPP63
Moin!
In einem aktuellen Excel (auch Excel Online) geht das so:
=TEXTVOR(TEXTNACH(A1;"files\");"\")
Gruß Ralf


Anzeige
AW: Außer Konkurrenz
17.05.2023 10:43:28
Luschi
Hallo Ralf,

'Außer Konkurrenz' wird M$ aber gar nicht gerne hören wollen, denn für diese Firma ist doch E-365 die Gegenwart, für Deutschland aber wohl immer noch die Zukunft!

Gruß von Luschi
aus klein-Paris


RPP63 meint damit XL365 statt XL2016
17.05.2023 12:27:38
lupo1
... sonst nix. Für Hana ist es nur unter XLWeb umsetzbar.


Anzeige
AW: Inhalt zwischen files\ und \ auslesen
17.05.2023 13:15:42
Daniel
Hi
noch ne Variante, allerdings ist der Matrixformelabschluss erforderlich (STRG+SHIFT+ENTER)

=INDEX(XMLFILTERN(""&WECHSELN(A1;"\";"")&"";"//x/y");VERGLEICH("files"; XMLFILTERN(""&WECHSELN(A1;"\";"")&"";"//x/y");0)+1)
mit Excel 365 oder Web dann etwas einfacher, weils da Textteilen gibt, welches man in Excel 2016 noch über das sperrige xmlfiltern nachbilden muss. Außerdem erlaubt Excel 365, dass man mehrfach vorkommende Teilformeln in Variabeln auslagert, so dass man sie nur einmal hinschreiben muss.

=LET(x;TEXTTEILEN(A1;"\");INDEX(x;VERGLEICH("files";x;0)+1))
Gruß Daniel


Anzeige
AW: Inhalt zwischen files\ und \ auslesen
17.05.2023 13:18:21
Daniel
ohne Formel könnte man für eine Massenverarbeigung in einer Spalte auch erst *\files\ durch nichts ersetzen und danach \* durch nichts.
Gruß Daniel


AW: Inhalt zwischen files\ und \ auslesen
17.05.2023 13:38:39
Hana
Vielen Dank an Alle. Es hat super funktioniert!


AW: Inhalt zwischen files\ und \ auslesen
17.05.2023 15:55:55
Pappawinni
Eigentlich würde man da gerne die Zeichenkette umkehren, um dann einfach nach den erste beiden \ zu suchen..
Mit der 2016er Version von Excel geht da mit Formeln aber wenig....
Ich hab jetzt auch mal eine Formel gebaut für Pfad mit \ in Pfad in Zelle A1 aber naja..... : )

=LINKS(RECHTS(WECHSELN(WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";"")));"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1);LÄNGE(A1)-FINDEN("|";WECHSELN(WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";"")));"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1)));FINDEN("|";RECHTS(WECHSELN(WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";"")));"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1);LÄNGE(A1)-FINDEN("|";WECHSELN(WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";"")));"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1))))-1)


Anzeige
AW: Inhalt zwischen files\ und \ auslesen
17.05.2023 16:19:52
Pappawinni
das geht sogar etwas kürzer..
wie schon in dem Post von vorhin, darf der Pfad kein | enthalten, aber sonst müsste das zuverlässig den Teil zwischen den letzten beiden \ rausholen, wenn denn da welche drin sind.


=LINKS(RECHTS(A1;LÄNGE(A1)-FINDEN("|";WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1)));FINDEN("\";RECHTS(A1;LÄNGE(A1)-FINDEN("|";WECHSELN(A1;"\";"|";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1))))-1)


Anzeige
Falls Office 365 : TEXTVOR/TEXTNACH
17.05.2023 16:13:22
NoNet
Hallo Hanna

Wenn in A1 Dein Pfad steht : P:\Daten\2023\Projekte\2500870\files\808357\BHD_Liste.txt

Unter Excel 2016 würde ich das so lösen :
=TEIL(A1;FINDEN("\files\";A1)+7;FINDEN("\";TEIL(A1;A5;99))-1)

Unter Excel 365 würde es mit den neuen Funktionen auch so funktionieren :
=TEXTVOR(TEXTNACH(A1;"\files\");"\")

Salut, NoNet


Anzeige
AW: Falls Office 365 : TEXTVOR/TEXTNACH
17.05.2023 20:48:00
Pappawinni
Auch unter 365 würd ich das wohl ein bisschen Old School machen, so dass die Formel für verschiedene Pfade den untersten Folder liefert.
Das ist auch nicht viel komplexer..


=TEXTVOR(TEXTNACH(A1;"\";LÄNGE(A1)-LÄNGE(WECHSELN(A1;"\";""))-1);"\")


Anzeige
AW: Falls Office 365 : TEXTVOR/TEXTNACH
18.05.2023 06:01:46
Luschi
Hallo Excel-Fan's,

die letzte Pfadangabe klappt in E_365 auch so: =TEXTVOR(TEXTNACH(A1;"\";-2);"\";-1)

Gruß von Luschi
aus klein-Paris


AW: Falls Office 365 : TEXTVOR/TEXTNACH
18.05.2023 11:09:22
Pappawinni
ich benutze xl2016, insofern sind mir die 365er Formeln noch nicht so geläufig, aber ich meine dann hätte es
=TEXTVOR(TEXTNACH(A1;"\";-2);"\")
auch getan.
Dann setzt man einfach -3, statt -2 für den vorletzten Unterordner, oder ?

Damit dann aber wieder Wechseln ins Spiel kommt könnte man dann das ganze noch so

TEXTVOR(TEXTNACH(Wechseln(A1;"/";"\");"\";-2);"\")
ändern, damit bei Pfaden mit / oder \ der letzte Unterordner geliefert wird.


Anzeige
AW: Falls Office 365 : TEXTVOR/TEXTNACH
19.05.2023 13:01:12
Daniel
Allerdings war die Aufgabenstellung: der Ordner nach Files
Und nicht der x. Ordner

Gruß Daniel


AW: Falls Office 365 : TEXTVOR/TEXTNACH
19.05.2023 15:43:02
Pappawinni
Ok, da könntest du vielleicht recht haben,
wobei das halt in dem Beispiel der letzte Unterordner war.
Ich hab das halt so interpretiert.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige