Autofilter mit ListBox verknüpfen

Thomas · 2023-12-28T12:00:23+00:00

Guten Tag zusammen... Gerne würde ich einen Autofilter einsetzen. Der Autofilter soll über eine Userform (ListBox) die darin ausgewählten Werte erhalten die er dann sucht. ----------------------------------------------------------------------------------------------------------------------------------------------------------------- ActiveSheet.Range(Range).AutoFilter 2, Criteria1:=Array(.Range("B7")), Operator:=xlFilterValues, VisibleDropDown:=False ------------------------------------------------------------------------------------------------------------------------------------------------------------------ Der Code ist als Beispiel zu nennen. (habe diesen in der UserForm). Meine Annahme ist es dass im Criterial1 ein Array mit dieser ListBox gefüllt werden muss. Hat irgend wer ein Musterbeispiel das ev. verwendet werden darf? Ein Autofilter einzubauen ist nicht das Problem. Aber die ListBox, die in der Userform ist, das Array füllen soll ist mir zu hoch. Besten Dank und Gruss Thomas

Hallo Thomas,

wenn es nur um das Füllen einer Listbox mit gefilterten Zeilen aus einem Listobject geht, kann man das nebst Filter so machen:



Option Explicit



Private Sub TextBox1_Change()

    Dim i&, j&, arrWerte(), arr As Variant, objCell As Range

    If ComboBox1.ListIndex > -1 Then

        arr = Split(TextBox1, ",")

        With Tabelle1

            .ListObjects(1).ShowAutoFilterDropDown = True

            .ListObjects(1).Range.AutoFilter Field:=ComboBox1.ListIndex + 1

            If TextBox1 > "" Then

                .ListObjects(1).Range.AutoFilter Field:=ComboBox1.ListIndex + 1, Criteria1:=arr, Operator:= _

                xlFilterValues

                If .ListObjects(1).AutoFilter.Range.Columns(ComboBox1.ListIndex + 1).SpecialCells(xlCellTypeVisible).Cells.Count > 1 Then

                    With .ListObjects(1).DataBodyRange.SpecialCells(Type:=xlCellTypeVisible)

                        ReDim arrWerte(1 To .Areas.Count, 1 To 6)

                        For i = 1 To .Areas.Count

                            For Each objCell In .Areas(i).Cells

                                j = j + 1

                                arrWerte(i, j) = objCell.Value

                            Next

                            j = 0

                        Next

                    End With

                    ListBox1.List = arrWerte

                End If

            Else

                .ListObjects(1).Range.AutoFilter Field:=ComboBox1.ListIndex + 1

                ListBox1.Clear

            End If

            .ListObjects(1).ShowAutoFilterDropDown = False

        End With

    End If

End Sub



Private Sub UserForm_Initialize()

    With Tabelle1.ListObjects(1).HeaderRowRange

        ComboBox1.List = WorksheetFunction.Transpose(.Rows(1).Value)

    End With

End Sub



Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)

    If ComboBox1.ListIndex = -1 Then Exit Sub

        Tabelle1.ListObjects(1).Range.AutoFilter Field:=ComboBox1.ListIndex + 1

End Sub

Dazu brauchst du im Userform eine ComboBox, eine TextBox und eine Listbox.
Der Filter funktioniert mittels Auswahl der zu filterenden Spalte.
In die Textbox kann einer bzw. mehrere Suchbegriffe, welche jeweils mit Komma zu trennen sind eingegeben werden.
Das Filtrat (sichtbare Zellen) im Listobject wird dann in die Listbox via Array übergeben.
Den ursprünglichen Filterweg hatte ich vor einiger Zeit mal im anderen Forum gepostet.

Gruß Uwe

mit Multiselect der Listbox den Filter steuern so:



Option Explicit



Private Sub Suchen()

    Dim i&, j&, arr()

    If ComboBox1.ListIndex > -1 Then

        With ListBox1

            For i = 0 To .ListCount - 1

                If .Selected(i) = True Then

                    ReDim Preserve arr(0 To j)

                    arr(j) = .List(i, 0)

                    j = j + 1

                End If

            Next i

        End With

        With Tabelle1

            .ListObjects("Tbl_Liste").ShowAutoFilterDropDown = True

            .ListObjects("Tbl_Liste").Range.AutoFilter Field:=ComboBox1.ListIndex + 1

            If j > 0 Then

                .ListObjects("Tbl_Liste").Range.AutoFilter Field:=ComboBox1.ListIndex + 1, Criteria1:=arr, Operator:= _

                xlFilterValues

            Else

                .ListObjects("Tbl_Liste").Range.AutoFilter Field:=ComboBox1.ListIndex + 1

            End If

            .ListObjects("Tbl_Liste").ShowAutoFilterDropDown = False

        End With

    End If

End Sub



Private Sub ComboBox1_Change()

    Dim objDic As Object

    Dim i&

    Set objDic = CreateObject("Scripting.Dictionary")

    If ComboBox1.ListIndex > -1 Then

        With Tabelle1.ListObjects(1).DataBodyRange

            For i = 2 To .Rows.Count

                objDic(.Cells(i, ComboBox1.ListIndex + 1).text) = 0

            Next

            ListBox1.List = objDic.keys

        End With

    Else

        ListBox1.Clear

    End If

End Sub



Private Sub ListBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)

    Suchen

End Sub



Private Sub UserForm_Initialize()

    With Tabelle1.ListObjects(1).HeaderRowRange

        ComboBox1.List = WorksheetFunction.Transpose(.Rows(1).Value)

    End With

End Sub



Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)

    If ComboBox1.ListIndex = -1 Then Exit Sub

    Tabelle1.ListObjects("Tbl_Liste").Range.AutoFilter Field:=ComboBox1.ListIndex + 1

End Sub

https://www.herber.de/bbs/user/165512.xlsm

Gruß Uwe

Autofilter mit ListBox verknüpfen

Forumthread: Autofilter mit ListBox verknüpfen

27
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Autofilter mit ListBox verknüpfen

Forumthread: Autofilter mit ListBox verknüpfen

27 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

27
Beiträge zum Forumthread

Beiträge zu diesem Forumthread