WENN, DANN - Email Versand durch Bedingung aus Excel heraus

Ben · 2024-02-08T19:29:12+00:00

Hallo an Alle, Ich habe ein relativ einfaches Anliegen, aber ich bin mir nicht sicher, ob man mein Anliegen mit VBA umsetzen kann. Leider konnte ich über die Suche auch nichts dazu finden. Ich habe meine Beispieldatei https://www.herber.de/bbs/user/166921.xlsm angefügt und versuche mein Anliegen so gut es geht, zu beschreiben. Ich möchte dass excel, auch wenn es geschlossen ist, eine Email über Outlook versendet, wenn das Datum in Spalte F, dem heutigen entspricht. Dabei sollte aber auch nur einmal eine Email verschickt werden und nicht dauerhaft/endlos. Wenn die Datumseinträge wieder aktualisiert werden z.B. bei neuen Bewohnern die natürlich auch neue Fristen haben, sollte es aber wieder mit dem Versand einer neuen Email funktionieren. Richtig gut wäre es, wenn es so funktionieren würde: Angenommen in Spalte F würde das heutige Datum stehen, dann soll eine Email erstellt werden und der "Name" aus der selben Zeile, aus Spalte B als "Betreff" in der Email hinterlegt werden, damit man genau Bescheid weiß, bei welcher Person die Frist eingehalten werden muss. Wenn das mit dem Namen nicht klappen sollte wäre es nicht so tragisch. Ich habe bereits ein Modul angelegt, damit sollte der Versand über VBA funktionieren, nur fehlt jetzt die exakte Bedingung. Ich hoffe ihr könnt mir diesbezüglich weiterhelfen.

Moin Ben,

ich hab mir deine Datei + deine "Wünsche" mal genauer angesehen - unnnnnd....habe noch Fragen...so einige.

1. Du schreibst immer wieder "...Es soll einfach nur eine Email verschickt werden, wenn das Datum dem heutigen entspricht..."
Aber in deinem letzten Beitrag schreibst du - das erste Mal: "...So, wie die "Benachrichtigung" in G3 und G4. Nur halt per Mail..."

In Spalte G steht aber die Formel: WENN DATUM KLEINER ODER GLEICH HEUTE!
Es soll in Spalte G also AUCH DANN der Text "Bitte bearbeiten" erscheinen, wenn das Datum in Spalte F KLEINER ist als "nur" Heute.

Frage:
Sollen Mails also wirklich NUR versendet werden, wenn Datum wirklich genau heute ist, oder sollen Mails auch genau dann versendet werden, wenn Datum älter ist als heute?

2. So...und bitte an wen sollen Mails versendet werden?
In deinem Code steht für .To nur "meine mail"!

Aber es macht ja keinen Sinn, bei Erreichen oder Überschreiten von Datum in Spalte F Mails nur an dich selbst zu versenden - denn bei Öffnen der Datei siehst du selbst ja schon, welcher Bewohner in 14 Tagen seine Frist überschritten hat.

Frage:
a) Ist das wirklich so gewollt, dass DU per Mail informiert wirst?
b) Oder sollen die Bewohner per Mail informiert werden? WO stehen dann die Mailadressen von den Bewohnern?

----------------------

So, noch n paar Antworten zu deinen Fragen:

1. Dabei sollte aber auch nur einmal eine Email verschickt werden und nicht dauerhaft/endlos.
Ja, das ist ohne Probleme möglich. Ich würde einfach z Bsp in Spalte D den Text "Mail versendet" eintragen - und genau immer erst in D prüfen, ob dieser Eintrag vorhanden ist oder nicht. Nur wenn in D nicht "Mail versendet" steht, würde eine Mail versendet werden

2. Kann man den Namen aus B3 in den Betreff einfügen?
Jep, problemlos!
Du kannst, wenn du willst, jeden Wert aus jeder Zelle (in der jeweiligen Zeile) in die automatisierte Mail übernehmen.

So...jetzt hätte ich aber bitte Antworten zu allen meinen Fragen.

Ciao
Thorsten

Hallöchen,

@Thorsten, so unterschiedlich wird die Programmierung direkt in Outlook auch nicht. Da muss man von Excel aus vielleicht sogar etwas mehr aufpassen, z.B. beim Objekthandling. Ich habe hier mal einen Code programmiert, wie er in Outlook verwendet werden kann.
Excel würde ich aber auch bevorzugen, zum einen bezüglich der Kenntnisse das TE und zum anderen wg. dem Makrohandling in Outlook.

Voraussetzung bei meiner Lösung:
In einer Datei C:\Test\Termine.xlsx stehen in Spalte A Termine, in B Adressen und in C Betreffs. Spalte D ist die Zusatzspalte für einen Logeintrag "x" für versendet.
Der Code wird im VBA-Editor in Outlook in ein neues Modul eingefügt - und erst mal per F5 oder "Ausführen" ausgeführt.
Beachte den Kommentar am Anfang des Makros bezüglich des Verweises.

Was so alles passiert, ist zum einen im Makro ausführlich kommentiert bzw. sieht man beim Ausführen. Nicht berücksichtigt sind bislang nicht gesendete EMails an vergangenen Tagen. Nicht berücksichtigt sind auch diverse weitere Fehlermöglichkeiten wie z.B. fehlende Exceldatei ...

Public Sub AufZu_Excel()

'Verweis auf Microsoft Excel ... setzen!

'Variablendeklarationen

'Objekte von Excel

Dim xlApp As Object, objWB As Object, objWS As Object

'Daten fuer EMail

Dim arrZeile

'Schleifenzaehler (Long)

Dim iCnt&

'Objekte von Outlook

Dim MyEmail As MailItem



'Bei Fehler Zeile ueberspringen (falls App holen nicht klappt)

On Error Resume Next

'Excel App holen

Set xlApp = GetObject(, "excel.application")

'Ende Bei Fehler Zeile ueberspringen

On Error GoTo 0

'Wenn App holen nicht geklappt hat, dann so. Excel sollte aber schon installiert sein ...

If xlApp Is Nothing Then Set xlApp = New Excel.Application

'Datei in Excel oeffnen

Set objWB = xlApp.Workbooks.Open("C:\Test\Termine.xlsx")

'Blatt mit Terminen zuweisen und aktivieren

Set objWS = objWB.Sheets("Tabelle1")

objWS.Activate

'Schleifenzaehler auf Startzeilennummr setzen

iCnt = 1

'auf dem Blatt Tabelle1 was tun

With objWS

  'Schleife, solange irgendwas in der zelle steht

  Do While .Cells(iCnt, 1).Value > ""

    'Mit der Zelle was tun

    With .Cells(iCnt, 1)

      'Wenn das Datum dort heute ist, dann

      If .Value = Date Then

        'Wenn 4 Zellen daneben kein x steht (Mailwurde schon gesendet)

        If Not(.Offset(0, 4).Value = "x") Then

          'Daten  der Zeile uebernehmen

          arrzeile = .Resize(1, 5).Value

          'Emailerstellung beginnen

          Set MyEmail = Application.CreateItem(olMailItem)

          'Mit der neuen EMail

          With MyEmail

            'Addressat

            .To = arrzeile(1, 2)

            'Wichtigkeit hoch

            .Importance = olImportanceHigh

            'Betreff

            .Subject = arrzeile(1, 3)

            'EMailtext

            .Body = arrzeile(1, 4)

            'EMailformat

            .BodyFormat = olFormatHTML

            'EMail anzeigen

            .Display

          'Ende Mit der neuen EMail

          End With

          'EMail senden

          'MyEmail.Send

          '4 Zellen daneben ein x schreiben

          .Offset(0, 4).Value = "x"

        'Ende Wenn das Datum dort heute ist, dann

        End If

        'Ende Wenn 4 Zellen daneben kein x steht

      End If

    'Ende Mit der Zelle was tun

    End With

    iCnt = iCnt + 1

  'Ende Schleife, solange irgendwas in der zelle steht

  Loop

'Ende auf dem Blatt Tabelle1 was tun

End With

'Exceldate speichern

objWB.Close savechanges:=True

'Excel beenden

xlApp.Quit

End Sub

WENN, DANN - Email Versand durch Bedingung aus Excel heraus

Forumthread: WENN, DANN - Email Versand durch Bedingung aus Excel heraus

19
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

WENN, DANN - Email Versand durch Bedingung aus Excel heraus

Forumthread: WENN, DANN - Email Versand durch Bedingung aus Excel heraus

19 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

19
Beiträge zum Forumthread

Beiträge zu diesem Forumthread