Von exceltabelle in word per steuerelement temarker

Ritchi788 · 2024-04-16T19:22:16+00:00

Guten Tag, ich habe folgendes Problem: Ich habe eine Excel-Tabelle, die ich automatisch per Steuerelement in Textmarken einer Word-Datei einfügen möchte. Jedoch erhalte ich jedes Mal eine Fehlermeldung, und es werden die folgenden Zeilen markiert: Sub DatenInWordEinfügen() ws As Worksheet Und hier der ganze Code: Private Sub Suchfeld_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer) If KeyCode = vbKeyReturn Then DatenInWordEinfügen End If End Sub Sub DatenInWordEinfügen() Dim ws As Worksheet Dim excelData As Variant Dim zeilenNummer As Integer Dim aktenzeichen As String ' Arbeitsblatt mit den Excel-Daten festlegen (passen Sie den Namen des Arbeitsblatts an) Set ws = ThisWorkbook.Sheets("Wild") If ws Is Nothing Then MsgBox "Das Arbeitsblatt konnte nicht gefunden werden.", vbExclamation Exit Sub End If ' Das Aktenzeichen aus dem Suchfeld abrufen aktenzeichen = ActiveDocument.FormFields("Suchfeld").Result ' Zeilennummer aus dem Suchfeld in Word lesen zeilenNummer = Val(aktenzeichen) ' Excel-Daten in eine Variable lesen (passen Sie die Zellenkoordinaten an) excelData = ws.Rows(zeilenNummer).Value ' Daten in das Word-Dokument einfügen With ThisDocument .Bookmarks("Datum").Range.Text = excelData(1, 3) .Bookmarks("Uhrzeit").Range.Text = excelData(1, 4) .Bookmarks("Ort").Range.Text = excelData(1, 5) .Bookmarks("Vorname").Range.Text = excelData(1, 7) .Bookmarks("Name").Range.Text = excelData(1, 8) .Bookmarks("Geburtsdatum").Range.Text = excelData(1, 9) .Bookmarks("Adresse").Range.Text = excelData(1, 10) .Bookmarks("Postleitzahl").Range.Text = excelData(1, 11) .Bookmarks("Konsummittel").Range.Text = excelData(1, 12) ' Hier weitere Datenfelder entsprechend der Spalten in Excel einfügen End With End Sub Wäre schön wenn mir jemand helfen kann, weil bin mittlerweile am verzweifeln.

Ich würde gerne die Daten hier hochladen, damit ihr euch das Problem anschauen könnt, aber leider erlaubt es mein Handy nicht, die Daten hochzuladen. Ich habe ein Dropdown-Feld erstellt, um mich auf verschiedene Aktenzeichen zu beziehen, und eine Schaltfläche hinzugefügt, um das Skript auszuführen, das dann automatisch die Daten aus der Excel-Tabelle in die entsprechenden Textmarken einfügen soll. Obwohl die Codes die Word-Datei öffnen, wenn ich sie manuell ausführe, beziehen sie sich trotzdem nicht auf die entsprechenden Zeilen. Ich dachte, der Lösungsweg wäre einfacher, aber auch hier funktioniert irgendwie etwas nicht. Ich hänge hier mal noch 2 Codes an, vielleicht hat ja jemand eine Idee.

Das steht im Modul 1

Sub DatenInWordEinfügen()
    Dim wordApp As Object
    Dim wordDoc As Object
    Dim ws As Worksheet
    Dim excelData As Variant
    Dim excelTime As Date
    Dim zeile As Long

    ' Word-Anwendung starten
    On Error Resume Next
    Set wordApp = GetObject(, "Word.Application")
    If wordApp Is Nothing Then
        Set wordApp = CreateObject("Word.Application")
    End If
    On Error GoTo 0

    wordApp.Visible = True ' Word sichtbar machen

    ' Word-Dokument öffnen
    On Error Resume Next
    Set wordDoc = wordApp.Documents.Open("C:\Users\Rahmeln\Desktop\Test\Test Macro.docm")
    If wordDoc Is Nothing Then
        MsgBox "Das Word-Dokument konnte nicht geöffnet werden.", vbExclamation
        wordApp.Quit
        Exit Sub
    End If
    On Error GoTo 0

    ' Arbeitsblatt mit den Excel-Daten festlegen (passen Sie den Namen des Arbeitsblatts an)
    Set ws = ThisWorkbook.Sheets("Test Excel")
    If ws Is Nothing Then
        MsgBox "Das Arbeitsblatt konnte nicht gefunden werden.", vbExclamation
        wordDoc.Close
        wordApp.Quit
        Exit Sub
    End If

    ' Excel-Daten in eine Variable lesen (passen Sie die Zellenkoordinaten an)
    For zeile = 4 To 253 ' Annahme: 250 Zeilen für die Daten
        excelData = ws.Cells(zeile, 2).Resize(1, 15).Value ' Annahme: 15 Spalten für die Daten

        ' Zeitwert aus Excel in ein korrektes Zeitformat konvertieren
        excelTime = TimeSerial(Hour(excelData(1, 4)), Minute(excelData(1, 4)), Second(excelData(1, 4)))

        ' Daten in das Word-Dokument einfügen
        With wordDoc
            .Bookmarks("Datum").Range.Text = excelData(1, 3) ' Annahme: Spalte 1 enthält das Datum
            .Bookmarks("Uhrzeit").Range.Text = Format(excelTime, "hh:mm:ss") ' Formatierung der Uhrzeit
            .Bookmarks("Ort").Range.Text = excelData(1, 3) ' Annahme: Spalte 3 enthält den Ort
            .Bookmarks("Vorname").Range.Text = excelData(1, 7) ' Annahme: Spalte 7 enthält den Vornamen
            .Bookmarks("Name").Range.Text = excelData(1, 8) ' Annahme: Spalte 8 enthält den Nachnamen
            .Bookmarks("Geburtsdatum").Range.Text = excelData(1, 9) ' Annahme: Spalte 9 enthält das Geburtsdatum
            .Bookmarks("Adresse").Range.Text = excelData(1, 10) ' Annahme: Spalte 10 enthält die Adresse
            .Bookmarks("Postleitzahl").Range.Text = excelData(1, 11) ' Annahme: Spalte 11 enthält die Postleitzahl
            .Bookmarks("Konsummittel").Range.Text = excelData(1, 12) ' Annahme: Spalte 12 enthält das Konsummittel
        End With
    Next zeile

    ' Word-Dokument speichern (optional)
    ' wordDoc.Save

    ' Word-Dokument nicht schließen
    ' wordDoc.Close

    ' Word beenden (optional)
    ' wordApp.Quit
End Sub

Und das im Reiter 1 (Test Excel)

Sub DatenInWordEinfügen()
    Dim wordApp As Object
    Dim wordDoc As Object
    Dim aktenzeichen As String

    ' Word-Anwendung starten
    On Error Resume Next
    Set wordApp = GetObject(, "Word.Application")
    If wordApp Is Nothing Then
        Set wordApp = CreateObject("Word.Application")
    End If
    On Error GoTo 0

    wordApp.Visible = True ' Word sichtbar machen

    ' Word-Dokument öffnen
    On Error Resume Next
    Set wordDoc = wordApp.Documents.Open("C:\Pfad\zum\Word\Dokument.docx") ' Passe den Pfad zu deinem Word-Dokument an
    If wordDoc Is Nothing Then
        MsgBox "Das Word-Dokument konnte nicht geöffnet werden.", vbExclamation
        wordApp.Quit
        Exit Sub
    End If
    On Error GoTo 0

    ' Aktenzeichen aus dem Dropdown-Menü lesen
    aktenzeichen = ThisWorkbook.Sheets("Test Word").Shapes("DeinDropDown").ControlFormat.List(DeinDropDown.ListIndex)

    ' Daten in das Word-Dokument einfügen (hier kannst du deine Logik hinzufügen)
    ' Zum Beispiel: wordDoc.Bookmarks("Aktenzeichen").Range.Text = aktenzeichen

    ' Optional: Word-Dokument speichern
    ' wordDoc.Save

    ' Optional: Word-Dokument nicht schließen
    ' wordDoc.Close

    ' Optional: Word beenden
    ' wordApp.Quit
End Sub

Private Sub ComboBox1_Change()
Dim selectedAktenzeichen As String
selectedAktenzeichen = ComboBox1.Value
End Sub

Private Sub CommandButton1_Click()
'Code zum Abrufen der Daten aus Excel
'Code zum Einfügen der Dateien in die Word-Datei
End Sub

Ritchi,
schau Dir das an:
Userbild

und die Speicherplatzumgebung (Pfad und Dateien, wobei die Arbeitsmappe nicht unbedingt 'Ritchi_5.xlsm' heißen muss):
Userbild

und noch der Makro-Code für das gezeigte Konstrukt:

Option Explicit



Private Sub Suchfeld_Click()

  

  'einige Variablen und Objekte definiern

  Dim Az As String          'Aktenzeichen

  Dim zeNr As Long          'Zeilennummer

  Dim ws As Worksheet       'die Excel-Tabelle mit den Daten

  Dim myPath As String      'Der Pfad der Word-Vorlagendateien

  Dim Importdatei As String 'Die zu nutzende Word-Vorlagendatei

  

  'der Pfad zu den Word-Vorlagendateienwird wird definiert

  myPath = "C:\Users\Rahmeln\Desktop\Jugendschutz78\"

  

  ' Word-Application wird initialisiert mit 'Late Binding'

  ' daher ist kein Verweis mehr erforderlich

  Dim wdApp As Object

  Dim wdDoc As Object

  

  'die Word-Textmarken und -Textmarken Ranges initialisieren

  Dim objBkm As Object

  Dim rngBkm As Object

  

  ' den Ablauf verzögernde Events abschalten

  Application.ScreenUpdating = False

  Application.EnableEvents = False

  

  ' die Excel-Tabelle 'Tabelle1' wird zum Objekt 'ws' erhoben

  Set ws = ThisWorkbook.Sheets("Wild")

  

  ' Aktenzeichen und die entsprechende Zeilennummer anhand der

  ' angeklickten Zeile in der DropDown-Liste in die Variablen 'Az' und 'zeNr' schreiben

  Az = Me.Suchfeld.List(Me.Suchfeld.ListIndex)

  zeNr = Me.Suchfeld.ListIndex + 5

  

  ' definieren des zu nutzenden Word-Dokumentes,

  Importdatei = myPath & ws.Cells(zeNr, 2)

  

  'es ginge aber auch so wenn Du lieber 'A' oder 'B' benutzen möchtest:

  'If UCase(ws.Cells(zeNr, 2)) = "A" Then Importdatei = myPath & "Test1.docx"

  'If UCase(ws.Cells(zeNr, 2)) = "B" Then Importdatei = myPath & "Test2.docx"

  

  ' die Auswahl im Dropdown ist jetzt nicht mehr erforderlich, also aufheben

  Me.Suchfeld.ListIndex = -1



  ' Word starten

  Set wdApp = CreateObject("Word.Application")

  

  ' und sichtbar machen

  wdApp.Visible = True

  

  'die ausgewählte Word-Datei öffnen

  On Error GoTo Fehler_FileAuswahl

  Set wdDoc = wdApp.Documents.Open(Importdatei)

  

  ' Daten aus dem Objekt 'ws' in das Word-Dokument einfügen

  ' dabei werden die Textmarken zerstört, besetzt und sofort neu mit Inhalt gesetzt

  With wdDoc

    Set objBkm = .Bookmarks("Aktenzeichen")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 1).Value

    Set objBkm = .Bookmarks("Datum")

    Set rngBkm = objBkm.Range

    rngBkm.Text = Format(ws.Cells(zeNr, 3), "DD.MM.YYYY")

    Set objBkm = .Bookmarks("Uhrzeit")

    Set rngBkm = objBkm.Range

    rngBkm.Text = Format(ws.Cells(zeNr, 4), "hh:mm")

    Set objBkm = .Bookmarks("Ort")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 5)

    Set objBkm = .Bookmarks("Vorname")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 7)

    Set objBkm = .Bookmarks("Name")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 8)

    Set objBkm = .Bookmarks("Geburtsdatum")

    Set rngBkm = objBkm.Range

    rngBkm.Text = Format(ws.Cells(zeNr, 9), "DD.MM.YYYY")

    Set objBkm = .Bookmarks("Adresse")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 10)

    Set objBkm = .Bookmarks("Postleitzahl")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 11)

    Set objBkm = .Bookmarks("Stadt")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 12)

    Set objBkm = .Bookmarks("Konsummittel")

    Set rngBkm = objBkm.Range

    rngBkm.Text = ws.Cells(zeNr, 13)

    ' Hier weitere Datenfelder entsprechend der Spalten in Excel einfügen

  End With

  

  ' Word in den Vordergund holen

  wdApp.Activate

  

  ' die mit 'Set" definierten Objekte aus dem Speicher löschen

  Set wdDoc = Nothing

  Set wdApp = Nothing

  

  ' die für den normalen Ablauf deaktivierten Events wieder aktivieren

  Application.ScreenUpdating = True

  Application.EnableEvents = True

  

  ' Cursor auf A1 setzen

  Range("A1").Select



  ' hier ist bei fehlerfreiem Prozess-Verlauf Makro-Ende

  Exit Sub

  

' hier beginnt bei einer Fehlersituation die Fehlerbehandlung

Fehler_FileAuswahl:

  

  MsgBox "Sie haben keine Word-Vorlagendatei ausgewählt!" & vbCr & _

  "Der Prozess kann neu gestartet werden!", vbCritical + vbOKOnly

  

  ' die für den normalen Ablauf deaktivierten Events wieder aktivieren

  Application.ScreenUpdating = True

  Application.EnableEvents = True

  

  ' Word beenden

  wdApp.Quit

  

  ' die mit 'Set" definierten Objekte aus dem Speicher löschen

  Set wdDoc = Nothing

  Set wdApp = Nothing



  ' Cursor auf A1 setzen

  Range("A1").Select

  

End Sub

So, nun ist's aber auch wirklich genug, Alles weitere ohne mich, ok?!
Auch Dir eine schöne Woche.
Gruß
Jochen

Von exceltabelle in word per steuerelement temarker

Forumthread: Von exceltabelle in word per steuerelement temarker

72
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Von exceltabelle in word per steuerelement temarker

Forumthread: Von exceltabelle in word per steuerelement temarker

72 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

72
Beiträge zum Forumthread

Beiträge zu diesem Forumthread