Excel Formatieren und Sortieren

Forumthread: Excel Formatieren und Sortieren

05.06.2024 16:27:28

grubi28

Hallo,
vielen Dank schonmal für die Hilfe.

Ich habe über 50.000 Zeilen... Zeile 1 Adresse, Zeile 2 Ort und Zeile 3 qm. Jedoch rutscht manchmal (alle 100 Zeilen) die Adresszeile mit in die qm Zeile. Wie kann ich dies Lösen, dass immer Zeile 1 Adresse, Zeile 2 Ort, Zeile 3 qm und Zeile 4 dann wieder Adresse.... (fortlaufend sortiert):

An der Rennbahn 12
Borsdorf, Sachsen
271 m²
An der Rennbahn 13
Borsdorf, Sachsen
270 m²
An der Rennbahn 16
Borsdorf, Sachsen
269 m²An der Rennbahn 4
Borsdorf, Sachsen
277 m²
An der Rennbahn 5
Borsdorf, Sachsen
276 m²
An der Rennbahn 6
Borsdorf, Sachsen
275 m²

Wie kann ich dies lösen?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Excel Formatieren und Sortieren

05.06.2024 16:39:14

Onur

Du sollst nicht aufschreiben, wie deine Datei aussieht, sondern einfach die Datei mal posten.

AW: Excel Formatieren und Sortieren

05.06.2024 18:30:43

{Boris}

Hi,

Einträge stehen in Spalte A ab A1.

B1:
=WENN(ISTZAHL(SUCHEN("m²";A1))*(RECHTS(A1;2)>"m²");TEXTVOR(A1;"m²")&"m²";A1)

C1:
=WENN(B1>A1;TEIL(A1;LÄNGE(B1)+1;999);"")

Beide Formeln runterkopieren.

Ergebnis in E1:
=LET(x;ZUSPALTE(B1:C100);FILTER(x;x>""))

VG, Boris

AW: Excel Formatieren und Sortieren

05.06.2024 18:36:14

daniel

Hi

1. ersetze mit der Menüfunktin ERSETZEN die ² durch ²| (also noch ein Trennzeichen hinzufügen)
2. mit der Spalte die Funktion DATEN - DATENTOOLS - TEXT IN SPALTEN ausführen mit dem | als Trennzeichen
3. füge vor der ersten Spalte noch eine Spalte ein und fülle sie mit der Formel =Zeile()
4. füge vor der andern Spalte auch wieder eine Spalte ein und fülle sie mit der Formel: =Wenn(D1="";"";Zeile())
5. kopiere alle 4 Spalten und füge sie an gleicher Stelle als Wert ein
6. kopiere die Spalten C:D und füge sie unterhalb der Spalten A:B ein
7. Sortiere das ganze nach Spalte A
8. Lösche die Spalten A, C und D

Gruß Daniel

AW: Excel Formatieren und Sortieren

05.06.2024 19:14:56

daniel

Hi
geht in Excel 365 auch mit einer Formel in einer Zelle.
die Formel führt die von mir in der anderen Antwort beschriebenen manuellen Schritte aus:

=LET(

a;FILTER(A:A;A:A>"");

x;SEQUENZ(ZEILEN(a));

b;WENN(ISTZAHL(FINDEN("²";a));TEXTVOR(a;"²")&"²";a);

c;WECHSELN(a;b;"");

d;VSTAPELN(HSTAPELN(x;b);HSTAPELN(x;c));

e;SPALTENWAHL(SORTIEREN(d;1);2);

FILTER(e;e>""))

Gruß Daniel

AW: Excel Formatieren und Sortieren

05.06.2024 19:56:02

Onur

Guckst du hier:
https://www.herber.de/bbs/user/169873.xlsx

AW: mE bestens geeignet wäre hier die PQ-Funktionalität ...

06.06.2024 09:42:16

neopa C

Hallo grubi28.

... da es damit 1. einfach interaktiv, 2. auch in älteren XL-Versionen realisierbar ist (ich hab selbst nur XL2016 und kann somit nicht die hier bereits vorgeschlagenen Formellösungen verwenden) und 3. es auch für noch viel größere Datenmengen als die von Dir angegebene effektiv nutzbar ist.

Mehr zu PQ (Power Query) sieh z.B. mal hier: https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/

Ausreichend sind dazu nur folgende Schritte (Aktivitäten).
1. Einlesen Deiner Datenliste mit der Funktion [Aus Tabelle] im Menü unter [Abrufen und transformieren] indem Du zuvor eine Zelle der Datenliste aktiviert hast.
2. Dann mit der Funktion [Werte ersetzen] zu finden im PQ-Editor-Menü [Start] : "m²" durch z.B. "m²!" ersetzen lassen (anstelle "!" kann natürlich auch jedes andere eineindeutiges Zeichen - welches ansonsten nicht in Deinen Daten vorkommt- eingesetzt werden).
3. Danach im PQ-Menü [Transformieren] die Funktion [Spalte teilen] aktivieren und dort als Trennzeichen "benutzerdefiniert" das"!" eingeben und (wichtig!) dazu die erweiterte Option "Aufteilen in Zeilen" aktivieren,
4. in der so erzeugte Datenspalte dann einfach mit "Leere entfernen" im Filter der Spalte die erzeugten leeren Zellen ausfiltern lassen
5. Das nun in PQ-Editor vorliegende Ergebnis mit der Funktion [Schließen & laden in] im Menü [Datei] betätigen und dieses an eine gewünschte Position in Deiner Datei/Tabellenblatt ausgeben lassen.

Bei geänderter/erweiterter Datenliste einfach die Excel-Funktion [Alle aktualisieren] betätigen.

Gruß Werner
.. , - ...

AW: Excel Formatieren und Sortieren

05.06.2024 20:22:23

daniel

die Formel ist super und gefällt mir.
du hast hier nur leider das Problem, dass der Fragesteller von 50.000 Zeilen sprach, die er bearbeiten muss, und damit funktioniert deine Formel dann nicht mehr.

das Problem ist, dass du die kompletten Texte zu einem verkettest und bei Formeln gilt leider auch das Limit für die Maximale Länge von Texten für Zellen von c.a. 32.000 Zeichen, dh während der Berechnung darf ein Text nie länger werden.

Gruß Daniel

ps: was mir nicht gefällt ist, dass du die Formel nicht schon im Beitrag zeigst, so muss man immer die Datei runterladen, um zu sehen was du gemacht hast.
Hier ist ja nur eine Formel, die man gut im Forum zeigen kann.

AW: Excel Formatieren und Sortieren

06.06.2024 04:48:44

Onur

So besser?

=LET(rn;Z1S1:Z17S1;rngg;WECHSELN(rn;"²";"²*")&"*";rna;TEXTVOR(rngg;"*");rnb;TEXTNACH(rngg;"*");zu;ZUSPALTE(HSTAPELN(rna;rnb));FILTER(zu;(zu>"")*(zu>"*")))

https://www.herber.de/bbs/user/169875.xlsx

AW: Excel Formatieren und Sortieren

06.06.2024 04:54:45

Onur

Da war noch ein "*" zuviel drin:

=LET(rn;Z1S1:Z17S1;rngg;WECHSELN(rn;"²";"²*")&"*";rna;TEXTVOR(rngg;"*");rnb;TEXTNACH(rngg;"*");zu;WECHSELN(ZUSPALTE(HSTAPELN(rna;rnb));"*";"");FILTER(zu;(zu>"")*(zu>"*")))

AW: Excel Formatieren und Sortieren

06.06.2024 08:11:30

daniel

ja.
das ZuSpalte spart das Sortieren, weils schichtet, muss ich mir merken

Beliebteste Forumthreads (12 Monate)

Forumthread: Excel Formatieren und Sortieren

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread