Sortieren zweier Tabellenblätter mittels Makro

Lutz Mergen · 2024-07-01T17:58:05+00:00

Guten Tag, ich führe 2 Anwesenheitslisten auf getrennten Tabellenblättern in einer Arbeitsmappe für 2 Wochentage, aber für die gleichen Teilnehmer. Diese möchte ich z. B. nach Vornamen oder nach Familienname sortieren, aber immer ausgehend von der ersten der beiden Listen, die zweite Liste sollte automatisch mitsortiert werden. Dazu verwende ich Befehlsschaltflächen (ActivX-Steuerelemente) in der ersten Anwesenheitsliste. Soweit zu den Rahmenbedingungen. Leider funktioniert das Wechseln der Seiten mittels VBA per Makrorecorder-Aufzeichnung nicht. Wie kann ich beide Tabellenblätter mit dem "Klick" gleichzeitig so ansprechen, dass sie nach den gleichen Kriterien sortiert sind? Genereller Ablauf der Makros: - Tabellenschutz aufheben (ohne Kennwort) - Bereich markieren - Sortieren - Markierung aufheben - Tabellenschutz aktivieren (ohne Kennwort). Abschließend soll nur das Tabellenblatt aktiviert sein, das die Befehlsschaltflächen enthält. Vielen Dank! Gruß, Lutz

So, hier der mittels dem Makrorekorder erzeugte Code.

Private Sub CommandButton3_Click()

    ActiveSheet.Unprotect

    Range("B6:AF40").Select

    ActiveWorkbook.Worksheets("TN-LIste Donnerstag").Sort.SortFields.Clear

    ActiveWorkbook.Worksheets("TN-LIste Donnerstag").Sort.SortFields.Add2 Key:= _

        Range("B6:B40"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _

        xlSortNormal

    ActiveWorkbook.Worksheets("TN-LIste Donnerstag").Sort.SortFields.Add2 Key:= _

        Range("C6:C40"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _

        xlSortNormal

    With ActiveWorkbook.Worksheets("TN-LIste Donnerstag").Sort

        .SetRange Range("B6:AF40")

        .Header = xlGuess

        .MatchCase = False

        .Orientation = xlTopToBottom

        .SortMethod = xlPinYin

        .Apply

    End With

    Range("B6").Select

    Sheets("TN-LIste Sonntag").Select

    ActiveSheet.Unprotect

    Range("B6:AF40").Select

    ActiveWorkbook.Worksheets("TN-LIste Sonntag").Sort.SortFields.Clear

    ActiveWorkbook.Worksheets("TN-LIste Sonntag").Sort.SortFields.Add2 Key:=Range _

        ("B6:B40"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _

        xlSortNormal

    ActiveWorkbook.Worksheets("TN-LIste Sonntag").Sort.SortFields.Add2 Key:=Range _

        ("C6:C40"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _

        xlSortNormal

    With ActiveWorkbook.Worksheets("TN-LIste Sonntag").Sort

        .SetRange Range("B6:AF40")

        .Header = xlGuess

        .MatchCase = False

        .Orientation = xlTopToBottom

        .SortMethod = xlPinYin

        .Apply

    End With

    Range("B6").Select

    ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:= _

        False

    Sheets("TN-LIste Donnerstag").Select

    ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:= _

        False

End Sub

Hi

besser als Gosub fände ich hier eine Schleife über die beiden Tabellenblätter, in welcher du sortierst.

also im prinzip so:

dim ShtName 

for each ShtName in Array("TN-LIste Donnerstag", "TN-LIste Sonntag")

    With ActiveWorkbook.Worksheets(ShtName)

    .Unprotect   'benötigt??

    .sort.SortFields.Clear

    .sort.SortFields.Add2 Key:=Range("B6:B40"), SortOn:=xlSortOnValues, _

       Order:=xlAscending, DataOption:=xlSortNormal

    .sort.SortFields.Add2 Key:=.Range("C6:C40"), SortOn:=xlSortOnValues, _

       Order:=xlAscending, DataOption:=xlSortNormal

    With .sort

        .SetRange .Range("B6:AF40")

        .Header = xlGuess

        .MatchCase = False

        .Orientation = xlTopToBottom

        .SortMethod = xlPinYin

        .Apply

    End With

    .Protect DrawingObjects:=False, Contents:=True, Scenarios:=False

End With

Next

beachte, dass du bei mehreren Tabellenblättern die Tabellenblattreferenz vor jedem Range oder Cells mit angeben musst, sonst referenzieren diese immer auf das gerade aktive Blatt.
gerade beim Sortieren übersieht man gerne die beiden Ranges.
Die Recorderaufzeichnung ist hier auch nicht optimal.

beim sortieren bevorzuge ich auch die alte Codierung aus den Zeiten bis Excel 2003, die kommt nämlich mit einer Zeile aus und ist daher viel übersichtlicher, wenn man nicht mehr als drei Sortierkriterien hat:
hier also das Sortieren für 2 Tabellenblätter mit gleichem Aufbau

for each ShtName in Array("TN-LIste Donnerstag", "TN-LIste Sonntag")

    With ActiveWorkbook.Worksheets(ShtName)

       .unprotect

       .Range("B6:AF40").Sort Key1:=.Range("B6"), Order1:=xlascending, Key2:=.Range("C6"), order2:=xlascending, header:=xlguess

       .Protect DrawingObjects:=False, Contents:=True, Scenarios:=False

    end with

next

Gruß Daniel

Sortieren zweier Tabellenblätter mittels Makro

Forumthread: Sortieren zweier Tabellenblätter mittels Makro

24
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Sortieren zweier Tabellenblätter mittels Makro

Forumthread: Sortieren zweier Tabellenblätter mittels Makro

24 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

24
Beiträge zum Forumthread

Beiträge zu diesem Forumthread